C_ChmlCmplncInfoQuickView

@EndUserText.label: 'Chemical Compliance Quickinfo'

@AccessControl:
{
  authorizationCheck: #MANDATORY
}

@VDM.viewType: #CONSUMPTION

@ObjectModel: {
  representativeKey: 'Specification',
  usageType:
  {
    dataClass: #MIXED,
    sizeCategory: #L,
    serviceQuality: #C
  }
}

@Metadata.allowExtensions: true

/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ]  } */
define view entity C_ChmlCmplncInfoQuickView
  as select from I_ChmlCmplncInfo

  --Cardinality is okay as one PP has only one UP assigned
  association [0..1] to I_ChmlCmplncProdAssgmt as _ChmlCmplncProdAssgmt on  I_ChmlCmplncInfo.ChmlCmplncInfoUUID      = _ChmlCmplncProdAssgmt.ChmlCmplncInfoUUID
                                                                        and _ChmlCmplncProdAssgmt.ChmlCmplncInfoType = 'BU'

{
      --Specification
      @ObjectModel.text.element: [ 'ChmlCmplncInternalName' ]
  key cast( Specification as ehfnd_compliance_view preserving type )             as Specification,

      @ObjectModel.virtualElement:true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHFND_TYPE_IMAGE_CALC_EXT'
      cast( '' as /ui2/semantic_object )                                         as SemanticObject,

      @Semantics.text:true
      cast ( ChmlCmplncInternalName as ehfnd_cci_internal_name preserving type ) as ChmlCmplncInternalName,

      -- Product
      ChmlCmplncInfoUUID                                                         as ChmlCmplncInfoUUID,

      @ObjectModel.text.element: [ 'ChmlCmplncProdCatztnPhrs1Text' ]
      ChmlCmplncProdCatztnPhrsUUID                                               as ChmlCmplncProdCatztnPhrsUUID,

      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHFND_CCI_PRODCAT_PHRS_EXIT'
      @ObjectModel.readOnly: true
      cast('' as ehfnd_phrs_text )                                               as ChmlCmplncProdCatztnPhrs1Text,

      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHFND_CCI_QV_CALC_EXT'
      @ObjectModel.readOnly: true
      cast('' as ehfnd_boole preserving type )                                   as ChmlCmplncProdCatztnPhrsIsHidn,

      -----------------------------------------------------------------------------------------------------------------------------------------------------------------
      -- Cas Number
      -----------------------------------------------------------------------------------------------------------------------------------------------------------------
      --Concatenated list of CAS Number for world
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHFND_CCI_QV_CALC_EXT'
      @ObjectModel.readOnly: true
      cast( '' as  ehfnd_chm_cas_no_world )                                      as CASNumber,

      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHFND_CCI_QV_CALC_EXT'
      @ObjectModel.readOnly: true
      cast('' as ehfnd_boole preserving type )                                   as CASNumberIsHidden,

      -----------------------------------------------------------------------------------------------------------------------------------------------------------------
      -- CCI Type and Roles
      -----------------------------------------------------------------------------------------------------------------------------------------------------------------
      --Chemical Compliance Information Type
      @ObjectModel.text.element: [ 'ChmlCmplncInfoTypeName' ]
      ChmlCmplncInfoType                                                         as ChmlCmplncInfoType,

      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHFND_CCI_QV_CALC_EXT'
      @ObjectModel.readOnly: true
      cast( '' as  ehfnd_cci_type_name )                                         as ChmlCmplncInfoTypeName,

      -- Logistics Roles
      MaterialIsTransported                                                      as MaterialIsTransported,
      MaterialIsSold                                                             as MaterialIsSold,
      MaterialIsProduced                                                         as MaterialIsProduced,
      MaterialIsSourced                                                          as MaterialIsSourced,
      MaterialIsDisposed                                                         as MaterialIsDisposed,
      MaterialIsEmissionRelevant                                                 as MaterialIsEmissionRelevant,
      MatlIsMultiComponentProduct                                                as MatlIsMultiComponentProduct,

      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHFND_CCI_CHGROLE_CALC_EXIT'
      @ObjectModel.readOnly: true
      cast('' as ehfnd_cci_log_role_info)                                        as ChmlCmplncCurLogsRole,

      --R&D Indicator: Product is in research
      ChmlCmplncProdIsResearched                                                 as ChmlCmplncProdIsResearched,

      --R&D Indicator: Field is hidden in case it is false
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHFND_CCI_QV_CALC_EXT'
      @ObjectModel.readOnly: true
      cast('' as ehfnd_boole preserving type )                                   as MaterialIsResearchedIsHidden,


      -------------------------------------------------------------------------------------------------------
      -- Type Image URL
      -------------------------------------------------------------------------------------------------------
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHFND_TYPE_IMAGE_CALC_EXT'
      @ObjectModel.readOnly: true
      cast( '' as abap.char( 255 ) )                                             as ChmlCmplncTypeImageURL,

      -----------------------------------------------------------------------------------------------------------------------------------------------------------------
      -- UP
      -----------------------------------------------------------------------------------------------------------------------------------------------------------------
      _ChmlCmplncProdAssgmt.ChmlCmplncProdUUID                                   as ChmlCmplncProdUUID,

      _ChmlCmplncProdAssgmt.ChmlCmplncProdUUID                                   as ChmlCmplncInfoNavgnLink,

      -- Unpackaged Product -- Internal Number
      @ObjectModel.text.element: [ 'ChmlCmplncInfoUnpckgdProdName' ]
      cast( _ChmlCmplncProdAssgmt._ChmlCmplncInfoProduct.Specification
       as ehfnd_compliance_view_up       preserving type )                       as UnpckgdChemicalComplianceInfo,

      -- Unpackaged Product -- Internal Name
      @Semantics.text:true
      cast ( _ChmlCmplncProdAssgmt._ChmlCmplncInfoProduct.ChmlCmplncInternalName
      as ehfnd_cci_unpckgdprod_name preserving type )                            as ChmlCmplncInfoUnpckgdProdName,

      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHFND_CCI_QV_CALC_EXT'
      @ObjectModel.readOnly: true
      cast('' as ehfnd_boole preserving type )                                   as UnpckgdChmlCmplncInfoIsHidn,


      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHFND_CCI_QV_CALC_EXT'
      @ObjectModel.readOnly: true
      cast('' as ehfnd_boole preserving type )                                   as PckgdChmlCmplncInfoIsHidn,

      ProdStewardshipRespUnit

}