I_WORKFLOWTASK

@AbapCatalog : {
  sqlViewName: 'IWORKFLOWTASK',
  buffering.type: #NONE
}
@EndUserText.label: 'Workflow work items'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AbapCatalog.dbHints.hint: 'USE_HEX_PLAN'
define view I_WorkflowTask
  as select from    swwwihead            as head
  association [0..1] to I_WorkflowTaskResult          as _WorkflowTaskResult           on  $projection.TopLevelWorkflowTask = _WorkflowTaskResult.WorkflowInternalID
                                                                                       and $projection.WorkflowTaskInternalID = _WorkflowTaskResult.WorkflowTaskInternalID
  association [0..*] to I_WorkflowTaskTitle           as _TaskTitle                    on  $projection.WorkflowTaskInternalID = _TaskTitle.WorkflowTaskInternalID
  association [1..1] to I_WorkflowTaskType            as _TaskType                     on  $projection.WorkflowTaskType = _TaskType.WorkflowTaskType
  association [1..1] to I_WorkflowTaskPriority        as _TaskPriority                 on  $projection.WorkflowTaskPriority = _TaskPriority.WorkflowTaskPriority
  association [1..1] to I_WorkflowTaskStatus          as _TaskStatus                   on  $projection.WorkflowTaskStatus = _TaskStatus.WorkflowTaskStatus
  association [0..*] to I_WorkflowTaskApplObject      as _TaskApplicationObject        on  $projection.WorkflowTaskInternalID = _TaskApplicationObject.WorkflowTaskInternalID
  association [0..1] to I_WorkflowTaskLeadingApplObj  as _TaskApplicationLeadingObject on  $projection.WorkflowTaskInternalID = _TaskApplicationLeadingObject.WorkflowTaskInternalID
  association [0..1] to I_WorkflowTaskStartEvent      as _TaskStartEvent               on  $projection.WorkflowTaskInternalID = _TaskStartEvent.WorkflowTaskInternalID
  association [0..1] to I_WorkflowTaskDueDate         as _TaskDueDate                  on  $projection.WorkflowTaskInternalID = _TaskDueDate.WorkflowTaskInternalID
  association [0..*] to I_WorkflowTaskRecipient       as _TaskRecipient                on  $projection.WorkflowTaskInternalID = _TaskRecipient.WorkflowTaskInternalID
  association [1..1] to I_WorkflowTaskDefinition      as _TaskDefinition               on  $projection.WorkflowTaskDefinitionObjType = _TaskDefinition.WorkflowTaskDefinitionObjType
                                                                                       and $projection.WorkflowTaskDefinitionObject  = _TaskDefinition.WorkflowTaskDefinitionObject
  association [1..1] to I_WorkflowTaskDefinition      as _TopLevelTaskDefinition       on  $projection.TopLevelWrkflwTskDefObjType = _TopLevelTaskDefinition.WorkflowTaskDefinitionObjType
                                                                                       and $projection.TopLevelWrkflwTskDefObject  = _TopLevelTaskDefinition.WorkflowTaskDefinitionObject
  association [0..1] to I_WorkflowStepType            as _WorkflowStepType             on  $projection.WorkflowTaskStepType           = _WorkflowStepType.WorkflowStepType
                                                                                       and $projection.TopLevelWorkflowTaskDefinition = _WorkflowStepType.WrkflwScen
                                                                                       and $projection.WorkflowTaskDefinitionVersion  = _WorkflowStepType.WrkflwScenVers
  association [0..1] to I_WorkflowStepResult          as _WorkflowTaskStepResult       on  $projection.TopLevelWorkflowTaskDefinition = _WorkflowTaskStepResult.WorkflowScenarioDefinition
                                                                                       and $projection.WorkflowTaskDefinitionVersion  = _WorkflowTaskStepResult.WorkflowScenarioDefinitionVers
                                                                                       and $projection.WorkflowTaskStepType           = _WorkflowTaskStepResult.WorkflowStepType
                                                                                       and $projection.workflowtaskresult             = _WorkflowTaskStepResult.WorkflowStepResult
  association [0..1] to I_WorkflowTaskCustomAttribute as _WorkflowTaskCustomAttribute  on  $projection.WorkflowTaskInternalID = _WorkflowTaskCustomAttribute.WorkflowTaskInternalID
  association [0..1] to I_WorkflowTaskTitleFallback   as _WorkflowTaskTitleFallback    on  $projection.WorkflowTaskInternalID = _WorkflowTaskTitleFallback.WorkflowTaskInternalID
{
  key head.wi_id                                       as WorkflowTaskInternalID,
      wi_type                                          as WorkflowTaskType,
      wi_prio                                          as WorkflowTaskPriority,
      wi_stat                                          as WorkflowTaskStatus,
      crea_tmp                                         as WrkflwTskCreationUTCDateTime,
      wi_aed_timestamp                                 as WrkflwTskCompletionUTCDateTime,
      top_wi_id                                        as TopLevelWorkflowTask,
      wi_chckwi                                        as ParentWorkflowTask,
      wi_cruser                                        as WorkflowTaskCreatedByUser,
      wi_aagent                                        as WorkflowTaskCurrentUser,
      wi_rh_task                                       as WorkflowTaskDefinition,
      cast( substring(wi_rh_task, 1, 2) as hr_sotype ) as WorkflowTaskDefinitionObjType,
      cast( substring(wi_rh_task, 3, 8) as hr_sobjid ) as WorkflowTaskDefinitionObject,
      top_task                                         as TopLevelWorkflowTaskDefinition,
      cast( substring(top_task, 1, 2) as hr_sotype )   as TopLevelWrkflwTskDefObjType,
      cast( substring(top_task, 3, 8) as hr_sobjid )   as TopLevelWrkflwTskDefObject,
      step_id                                          as WorkflowTaskStepType,
      agent_rule_id                                    as WorkflowTaskProcessorRole,
      case
        when wi_chckwi is initial and wi_type <> 'F' then '0000'
        else cast( substring(def_guid, 25, 4) as swd_versio )
      end                                              as WorkflowTaskDefinitionVersion,
      case
        when wf_type = '1024' or wf_type = '1032' or wf_type = '1040' then cast( 'SCENARIO' as sww_definition_type )
        else cast( 'STANDARD' as sww_definition_type )
      end                                              as WorkflowTaskDefinitionType,
      _WorkflowTaskResult.WorkflowTaskResult,
      _TaskTitle,
      _TaskType,
      _TaskPriority,
      _TaskStatus,
      _TaskApplicationObject,
      _TaskApplicationLeadingObject,
      _TaskStartEvent,
      _TaskDueDate,
      _TaskRecipient,
      _TaskDefinition,
      _TopLevelTaskDefinition,
      _WorkflowStepType,
      _WorkflowTaskStepResult,
      _WorkflowTaskCustomAttribute,
      _WorkflowTaskTitleFallback,
      _WorkflowTaskResult
}
where
     wi_type = 'W'
  or wi_type = 'B'
  or wi_type = 'F'
  or wi_type = 'A'