C_EDCWorkflowTask

DDL: C_EDCWORKFLOWTASK Type: view_entity CONSUMPTION Package: APPL_GLO_EDC_ODATA

EDC Workflow Task

C_EDCWorkflowTask is a Consumption CDS View that provides data about "EDC Workflow Task" in SAP S/4HANA. It reads from 4 data sources (I_WorkflowTask, I_WorkflowTaskApplObject, I_WorkflowTaskStatusText, I_WorkflowTaskTitle) and exposes 12 fields with key field WorkflowTaskInternalID. Part of development package APPL_GLO_EDC_ODATA.

4 data source(s) 12 fields

Data Sources (4)

SourceAliasJoin Type
I_WorkflowTask WorkflowTask from
I_WorkflowTaskApplObject WorkflowTaskApplObject inner
I_WorkflowTaskStatusText WorkflowTaskStatusText inner
I_WorkflowTaskTitle WorkflowTaskTitle inner

Annotations (7)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label EDC Workflow Task view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XXL view
ObjectModel.usageType.dataClass #MIXED view
VDM.viewType #CONSUMPTION view

Fields (12)

KeyFieldSource TableSource FieldDescription
KEY WorkflowTaskInternalID I_WorkflowTask WorkflowTaskInternalID
WorkflowTaskStatus I_WorkflowTask WorkflowTaskStatus
WorkflowTaskStatusDesc I_WorkflowTaskStatusText WorkflowTaskStatusDesc
WorkflowTaskDefinition I_WorkflowTask WorkflowTaskDefinition
WorkflowTaskName I_WorkflowTaskTitle WorkflowTaskName
TopLevelWorkflowTask I_WorkflowTask TopLevelWorkflowTask
TopLevelWorkflowTaskDefinition I_WorkflowTask TopLevelWorkflowTaskDefinition
TechnicalWrkflwObject I_WorkflowTaskApplObject TechnicalWrkflwObject
WrkflwTskCreationUTCDateTime I_WorkflowTask WrkflwTskCreationUTCDateTime
WrkflwTskCompletionUTCDateTime I_WorkflowTask WrkflwTskCompletionUTCDateTime
WorkflowTaskCreatedByUser I_WorkflowTask WorkflowTaskCreatedByUser
WorkflowTaskCurrentUser I_WorkflowTask WorkflowTaskCurrentUser 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'EDC Workflow Task'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XXL,
  dataClass: #MIXED
}
@VDM:{
  viewType:#CONSUMPTION
}
define root view entity C_EDCWorkflowTask
  as select from I_WorkflowTask           as WorkflowTask
    inner join   I_WorkflowTaskTitle      as WorkflowTaskTitle      on  WorkflowTask.WorkflowTaskInternalID = WorkflowTaskTitle.WorkflowTaskInternalID
                                                                    and WorkflowTaskTitle.Language          = $session.system_language
    inner join   I_WorkflowTaskApplObject as WorkflowTaskApplObject on WorkflowTaskApplObject.WorkflowTaskInternalID = WorkflowTask.WorkflowTaskInternalID
    inner join   I_WorkflowTaskStatusText as WorkflowTaskStatusText on  WorkflowTaskStatusText.WorkflowTaskStatus = WorkflowTask.WorkflowTaskStatus
                                                                    and WorkflowTaskStatusText.Language           = $session.system_language
{
  key WorkflowTask.WorkflowTaskInternalID           as WorkflowTaskInternalID,

      @ObjectModel.text.element: [ 'WorkflowTaskStatusDesc' ]
      WorkflowTask.WorkflowTaskStatus               as WorkflowTaskStatus,
      @Semantics.text: true
      WorkflowTaskStatusText.WorkflowTaskStatusDesc as WorkflowTaskStatusDesc,

      WorkflowTask.WorkflowTaskDefinition           as WorkflowTaskDefinition,
      
      WorkflowTaskTitle.WorkflowTaskName            as WorkflowTaskName,

      WorkflowTask.TopLevelWorkflowTask             as TopLevelWorkflowTask,
      WorkflowTask.TopLevelWorkflowTaskDefinition   as TopLevelWorkflowTaskDefinition,

      WorkflowTaskApplObject.TechnicalWrkflwObject  as TechnicalWrkflwObject,

      @Semantics.dateTime: true
      WorkflowTask.WrkflwTskCreationUTCDateTime     as WrkflwTskCreationUTCDateTime,
      @Semantics.dateTime: true
      WorkflowTask.WrkflwTskCompletionUTCDateTime   as WrkflwTskCompletionUTCDateTime,
      @Semantics.user.createdBy: true
      WorkflowTask.WorkflowTaskCreatedByUser        as WorkflowTaskCreatedByUser,
      @Semantics.user.lastChangedBy: true
      WorkflowTask.WorkflowTaskCurrentUser          as WorkflowTaskCurrentUser
}
where
  WorkflowTask.TopLevelWorkflowTaskDefinition = 'WS61000143'

Learn More