C_BankAccountReviewAreaInbox

DDL: C_BANKACCOUNTREVIEWAREAINBOX Type: view_entity CONSUMPTION Package: FCLM_BAR_IMPL

Bank Account Review Area

C_BankAccountReviewAreaInbox is a Consumption CDS View that provides data about "Bank Account Review Area" in SAP S/4HANA. It reads from 3 data sources (R_BankAccountReviewAreaTP, I_WorkflowTask, I_WorkflowTaskApplObject) and exposes 17 fields with key fields BankAccountReviewUUID, BankAccountReviewAreaUUID. It has 3 associations to related views. It is exposed through 1 OData service (UI_BKACCTREVAREAINBOX_DSP). Part of development package FCLM_BAR_IMPL.

3 data source(s) Exposed by 1 service(s) 17 fields

Data Sources (3)

SourceAliasJoin Type
R_BankAccountReviewAreaTP Area from
I_WorkflowTask Task inner
I_WorkflowTaskApplObject TaskApplicationObject inner

Associations (3)

CardinalityTargetAliasCondition
[0..*] I_WorkflowTaskRecipient _TaskRecipient TaskApplicationObject.WorkflowTaskInternalID = _TaskRecipient.WorkflowTaskInternalID and _TaskRecipient.WorkflowTaskIsVisibleInInbox = 'X'
[0..*] C_BkAccountReviewSnapshotInbox _BankAccountSnapshot $projection.BankAccountReviewAreaUUID = _BankAccountSnapshot.BankAccountReviewAreaUUID
[0..*] C_BkAcctReviewSelectionInbox _BankAccountSelection $projection.BankAccountReviewAreaUUID = _BankAccountSelection.BankAccountReviewAreaUUID

Annotations (8)

NameValueLevelField
EndUserText.label Bank Account Review Area view
AccessControl.authorizationCheck #MANDATORY view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
Metadata.allowExtensions true view
VDM.viewType #CONSUMPTION view
Metadata.ignorePropagatedAnnotations true view

OData Services (1)

ServiceBindingVersionContractRelease
UI_BKACCTREVAREAINBOX_DSP UI_BKACCTREVAREAINBOX_DSP V4 C1 NOT_RELEASED

Fields (17)

KeyFieldSource TableSource FieldDescription
KEY BankAccountReviewUUID R_BankAccountReviewAreaTP BankAccountReviewUUID
KEY BankAccountReviewAreaUUID R_BankAccountReviewAreaTP BankAccountReviewAreaUUID
WorkflowTaskInternalID I_WorkflowTaskApplObject WorkflowTaskInternalID
BankAccountReviewArea R_BankAccountReviewAreaTP BankAccountReviewArea
BankAccountReviewAreaName R_BankAccountReviewAreaTP BankAccountReviewAreaName
BankAccountReviewAreaStatus R_BankAccountReviewAreaTP BankAccountReviewAreaStatus Review Area Status
BkAccountReviewAreaStatusName
BkAcctRevAreaSnapshotDateTime R_BankAccountReviewAreaTP BkAcctRevAreaSnapshotDateTime
BankAccountReviewDate
CreatedByUser R_BankAccountReviewAreaTP CreatedByUser
CreationDateTime R_BankAccountReviewAreaTP CreationDateTime
LastChangedByUser R_BankAccountReviewAreaTP LastChangedByUser
LocalLastChangeDateTime R_BankAccountReviewAreaTP LocalLastChangeDateTime
_BankAccountSnapshot _BankAccountSnapshot
_BankAccountSelection _BankAccountSelection
_BankAccountReview R_BankAccountReviewAreaTP _BankAccountReview
_TaskRecipient _TaskRecipient 
@EndUserText.label: 'Bank Account Review Area'
@AccessControl.authorizationCheck: #MANDATORY
@ObjectModel.usageType:{ serviceQuality: #C,
                         sizeCategory:   #L,
                         dataClass:      #TRANSACTIONAL}
@Metadata.allowExtensions: true
@VDM : { viewType: #CONSUMPTION   }
@Metadata.ignorePropagatedAnnotations: true

define view entity C_BankAccountReviewAreaInbox
  as select from R_BankAccountReviewAreaTP as Area
    // joining WF views required for DCL

    inner join   I_WorkflowTaskApplObject  as TaskApplicationObject on  TaskApplicationObject.SAPBusinessObjectNodeKey1   = bintohex(
      Area.BankAccountReviewAreaUUID
    )
                                                                    and TaskApplicationObject.SAPObjectNodeRepresentation = 'BankAccountReviewArea'
                                                                    and TaskApplicationObject.WorkflowObjectRole          = '99'
    inner join   I_WorkflowTask            as Task                  on TaskApplicationObject.WorkflowTaskInternalID = Task.WorkflowTaskInternalID
                                                                    and(
                                                                      Task.WorkflowTaskStatus                       = 'READY'
                                                                      or Task.WorkflowTaskStatus                    = 'SELECTED'
                                                                      or Task.WorkflowTaskStatus                    = 'STARTED'
                                                                      or Task.WorkflowTaskStatus                    = 'COMMITTED'
                                                                    )
  association [0..*] to I_WorkflowTaskRecipient        as _TaskRecipient        on  TaskApplicationObject.WorkflowTaskInternalID = _TaskRecipient.WorkflowTaskInternalID
                                                                                and _TaskRecipient.WorkflowTaskIsVisibleInInbox  = 'X'
  association [0..*] to C_BkAccountReviewSnapshotInbox as _BankAccountSnapshot  on  $projection.BankAccountReviewAreaUUID = _BankAccountSnapshot.BankAccountReviewAreaUUID
  association [0..*] to C_BkAcctReviewSelectionInbox   as _BankAccountSelection on  $projection.BankAccountReviewAreaUUID = _BankAccountSelection.BankAccountReviewAreaUUID
{
  key Area.BankAccountReviewUUID,
  key Area.BankAccountReviewAreaUUID,
      TaskApplicationObject.WorkflowTaskInternalID,
      Area.BankAccountReviewArea,
      Area.BankAccountReviewAreaName,
      @EndUserText.label: 'Review Area Status'
      @ObjectModel.text.element: ['BkAccountReviewAreaStatusName']
      @Consumption.valueHelpDefinition: [{ entity.name: 'I_BankAccountReviewAreaStatus',
                                            entity.element: 'BankAccountReviewAreaStatus' }]
      @UI: {  textArrangement: #TEXT_ONLY }
      Area.BankAccountReviewAreaStatus,
      @Semantics.text:true
      Area._BkAcctReviewAreaStatusText[ Language = $session.system_language ].BkAccountReviewAreaStatusName,
      Area.BkAcctRevAreaSnapshotDateTime,
      Area._BankAccountReview.BankAccountReviewDate,
      @Semantics.user.createdBy: true
      Area.CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      Area.CreationDateTime,
      @Semantics.user.lastChangedBy: true
      Area.LastChangedByUser,
      @Semantics.systemDateTime.localInstanceLastChangedAt:true
      Area.LocalLastChangeDateTime,
      _BankAccountSnapshot,
      _BankAccountSelection,
      Area._BankAccountReview,
      _TaskRecipient
}

Learn More