C_SuplrConfWorkflowDeadlineEDP

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Suppl Conf Details for Deadline Email'

@VDM.viewType : #CONSUMPTION

@ObjectModel.usageType : {
  serviceQuality: #D,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
@ObjectModel.supportedCapabilities:[ #OUTPUT_EMAIL_DATA_PROVIDER ]
@Metadata.ignorePropagatedAnnotations:true

define view entity C_SuplrConfWorkflowDeadlineEDP

  as select from           I_WorkflowTask           as _Workflowtask

    inner join             I_WorkflowTaskApplObject as _WorkflowTaskApplObject on  _WorkflowTaskApplObject.WorkflowTaskInternalID        = _Workflowtask.WorkflowTaskInternalID
                                                                               and _WorkflowTaskApplObject.WorkflowObjectRole            = '01'
                                                                               and _WorkflowTaskApplObject.SAPObjectNodeRepresentation   = 'SupplierConfirmation'
                                                                               and _WorkflowTaskApplObject.TechnicalWrkflwObjectCategory = 'CL'

    left outer to one join I_SupplierConfirmation   as _SupplierConfirmation   on _SupplierConfirmation.SupplierConfirmation = _WorkflowTaskApplObject.TechnicalWrkflwObject

    left outer join        I_PurchaseOrderAPI01     as _PurchaseOrder          on _PurchaseOrder.PurchaseOrder = _SupplierConfirmation.SuplrConfRefPurchaseOrder

    left outer join        I_PurchasingDocumentType as _PurDocType             on  _PurDocType.PurchasingDocumentType     = _PurchaseOrder.PurchaseOrderType
                                                                               and _PurDocType.PurchasingDocumentCategory = 'F'

    left outer join        I_PurchaseOrderNetAmount as _PurchaseOrderNetAmount on _PurchaseOrderNetAmount.PurchaseOrder = _PurchaseOrder.PurchaseOrder

    left outer to one join I_Supplier               as _Supplier               on _Supplier.Supplier = _SupplierConfirmation.Supplier

    left outer to one join I_User                   as _User                   on _User.UserID = _SupplierConfirmation.CreatedByUser

{
  key _Workflowtask.WorkflowTaskInternalID,

      _SupplierConfirmation.SupplierConfirmation,

      _SupplierConfirmation.CreationDate,

      _SupplierConfirmation.CreatedByUser,

      cast(_User.UserDescription as mm_oa_user_fullname )                                                                      as CreatedByUserName,

      _SupplierConfirmation.Supplier,
      _Supplier.SupplierName,

      _SupplierConfirmation.SuplrConfRefPurchaseOrder                                                                          as PurchaseOrder,

      _SupplierConfirmation.PurchasingDocumentType,
      _PurDocType._Text[1:Language=$session.system_language].PurchasingDocumentTypeName,

      _PurchaseOrder.DocumentCurrency,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      cast((_PurchaseOrderNetAmount.PurchaseOrderNetAmount) as mm_pur_order_tot_net_amount )                                   as PurchaseOrderNetAmount,

      //Creation Time

      cast(tstmp_to_dats( cast( _Workflowtask.WrkflwTskCreationUTCDateTime as  tzntstmps ), 'UTC', $session.client, 'NULL' ) as sww_lsd )            as SuplrConfWrkflwTskCrtnUTCDate,
      cast(tstmp_to_tims( cast( _Workflowtask.WrkflwTskCreationUTCDateTime as  tzntstmps ), 'UTC', $session.client, 'NULL' ) as sww_lst )            as SuplrConfWrkflwTskCrtnUTCTime,
      //Deadline Due Time

      cast(tstmp_to_dats( cast( _Workflowtask._TaskDueDate.WorkflowTaskDueUTCDateTime as  tzntstmps ), 'UTC', $session.client, 'NULL' ) as sww_led ) as SuplrConfWrkflwTskDueUTCDate,
      cast(tstmp_to_tims( cast( _Workflowtask._TaskDueDate.WorkflowTaskDueUTCDateTime as  tzntstmps ), 'UTC', $session.client, 'NULL' ) as sww_let ) as SuplrConfWrkflwTskDueUTCTime

}