C_BudgetWorkflowDeadlineEmail

DDL: C_BUDGETWORKFLOWDEADLINEEMAIL SQL: IFMBDDEMAIL Type: view CONSUMPTION Package: PSM_S4CO_ODATA_BDGT_FM_WF

Budget Document fr Wrkflw DeadlineEmail

C_BudgetWorkflowDeadlineEmail is a Consumption CDS View that provides data about "Budget Document fr Wrkflw DeadlineEmail" in SAP S/4HANA. It reads from 1 data source (I_WorkflowTask) and exposes 6 fields with key field WorkflowTaskInternalID. Part of development package PSM_S4CO_ODATA_BDGT_FM_WF.

1 data source(s) 6 fields

Data Sources (1)

SourceAliasJoin Type
I_WorkflowTask Workflowtask from

Annotations (11)

NameValueLevelField
AbapCatalog.sqlViewName IFMBDDEMAIL view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #REQUIRED view
EndUserText.label Budget Document fr Wrkflw DeadlineEmail view
VDM.viewType #CONSUMPTION view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
Metadata.ignorePropagatedAnnotations true view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY WorkflowTaskInternalID I_WorkflowTask WorkflowTaskInternalID
BudgetDocument _BudgetDocument BudgetDocument
PlanningCategory _BudgetDocument PlanningCategory
BudgetDocumentType _BudgetDocument BudgetDocumentType
CreatedByUserName
WorkflowTaskResultReasonText 
@AbapCatalog.sqlViewName: 'IFMBDDEMAIL'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Budget Document fr Wrkflw DeadlineEmail'
@VDM.viewType : #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType : { serviceQuality: #C,
                           sizeCategory: #L,
                           dataClass: #TRANSACTIONAL }
@ObjectModel.supportedCapabilities: [ #OUTPUT_EMAIL_DATA_PROVIDER ]
@Metadata.ignorePropagatedAnnotations:true

define view C_BudgetWorkflowDeadlineEmail
  as select from            I_WorkflowTask           as Workflowtask
    left outer to many join I_WorkflowTaskApplObject as _WorkflowTaskApplObject on  _WorkflowTaskApplObject.WorkflowTaskInternalID = Workflowtask.WorkflowTaskInternalID
                                                                                and _WorkflowTaskApplObject.WorkflowObjectRole     = '99'
    left outer to one join  I_BudgetDocument         as _BudgetDocument         on  _BudgetDocument.ControllingArea    = substring( _WorkflowTaskApplObject.TechnicalWrkflwObject, 1, 4 )
                                                                                and _BudgetDocument.BudgetDocumentYear = substring( _WorkflowTaskApplObject.TechnicalWrkflwObject, 5, 4 )
                                                                                and _BudgetDocument.BudgetDocument     = substring( _WorkflowTaskApplObject.TechnicalWrkflwObject, 9, 10 )
    left outer to one join  I_User                   as _User                   on _User.UserID = _BudgetDocument.CreatedByUser

{
  key Workflowtask.WorkflowTaskInternalID,

      _BudgetDocument.BudgetDocument                                      as BudgetDocument,
      _BudgetDocument.PlanningCategory                                    as PlanningCategory,
      _BudgetDocument.BudgetDocumentType                                  as BudgetDocumentType,

      //      cast(substring(_WorkflowTaskApplObject.TechnicalWrkflwObject, 8 , 10 ) as bdgt_docnr preserving type ) as BudgetDocument,


      case Workflowtask.WorkflowTaskResult
        when 'requestApproved'
          then 'Approved'
        when 'requestRejected'
          then 'Rejected'
      else Workflowtask.WorkflowTaskResult end                            as WorkflowTaskResult,

      cast(_User.UserDescription as vdm_userdescription preserving type ) as CreatedByUserName,

      Workflowtask._WorkflowTaskResult._WorkflowTaskResultReason._WorkflowTaskResultReasonText[1:Language=$session.system_language].WorkflowTaskResultReasonText
}

Learn More