C_SettlmtDocWorkItem

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED,
  privilegedAssociations: ['_CreatedByUser']
} 
@ObjectModel:{
   usageType: {
       serviceQuality: #D,
       dataClass: #MIXED,
       sizeCategory:  #XXL
   },
   semanticKey: [ 'WorkflowTaskInternalID' ],
   representativeKey: 'WorkflowTaskInternalID'
}
@Analytics.technicalName: 'CWLFSMTDOCWI'
@VDM.viewType: #CONSUMPTION
@Consumption.semanticObject: 'WorkflowTaskInternalID'
@EndUserText.label: 'Settlement Document Work Item'
define view entity C_SettlmtDocWorkItem
  as select from I_WorkflowTask           as _WorkflowTask
    inner join   I_WorkflowTaskApplObject as _WorkflowTaskApplObject on  _WorkflowTaskApplObject.WorkflowTaskInternalID        = _WorkflowTask.WorkflowTaskInternalID
                                                                     and _WorkflowTaskApplObject.WorkflowObjectRole            = '01'
                                                                     and _WorkflowTaskApplObject.TechnicalWrkflwObjectCategory = 'CL'
                                                                     and _WorkflowTaskApplObject.SAPObjectNodeRepresentation   = 'SettlementDocument'
    inner join   C_SettlmtDocWrkflwDet    as _SettlmtDocWrkflwDet    on _SettlmtDocWrkflwDet.SettlmtDoc = _WorkflowTaskApplObject.TechnicalWrkflwObject
{
  key _WorkflowTask.WorkflowTaskInternalID,
      _SettlmtDocWrkflwDet.SettlmtDoc,
      _SettlmtDocWrkflwDet.SettlmtDocCurrency,
      @ObjectModel.text.element:  [ 'UserFullName' ]
      @Semantics.user.createdBy: true
      _SettlmtDocWrkflwDet.CreatedByUser,
      @Semantics.text: true
      _SettlmtDocWrkflwDet.UserFullName,
      @ObjectModel.text.element:  [ 'ConditionContract' ]
      @Semantics.text: true
      _SettlmtDocWrkflwDet.ConditionContract,
      _SettlmtDocWrkflwDet.DocumentTitle,
      _SettlmtDocWrkflwDet.CustSettlmtCompanyCode,
      _SettlmtDocWrkflwDet.PayerParty,
      _SettlmtDocWrkflwDet.InvoicingParty,
      _SettlmtDocWrkflwDet.SuplrSettlmtCompanyCode,
      _SettlmtDocWrkflwDet.PayeeParty,
      _SettlmtDocWrkflwDet.AlternativeInvoicingParty,
      _SettlmtDocWrkflwDet.BillToParty,
      _SettlmtDocWrkflwDet.Division,
      _SettlmtDocWrkflwDet.SettlmtDocType,
      _SettlmtDocWrkflwDet.PurchasingOrganization,
      _SettlmtDocWrkflwDet.PurchasingGroup,
      _SettlmtDocWrkflwDet.SalesOrganization,
      _SettlmtDocWrkflwDet.DistributionChannel,
      _SettlmtDocWrkflwDet.SettlmtReltdCndnContr,
      _SettlmtDocWrkflwDet.SalesOffice,
      _SettlmtDocWrkflwDet.SalesGroup,
//      Required for DCL

      @Consumption.hidden: true
      _SettlmtDocWrkflwDet.SettlmtDocAuthznCat,

      //Associations

      _SettlmtDocWrkflwDet._BillToParty,
      _SettlmtDocWrkflwDet._Division,
      _SettlmtDocWrkflwDet._DistributionChannel,
      _SettlmtDocWrkflwDet._PurchasingOrganization,
      _SettlmtDocWrkflwDet._SalesOrganization,
      _SettlmtDocWrkflwDet._CreatedByUser,
      _SettlmtDocWrkflwDet._PayerPartyCompany,
      _SettlmtDocWrkflwDet._BillToPartyCompany,
      _SettlmtDocWrkflwDet._PayerParty,
      _SettlmtDocWrkflwDet._InvoicingParty,
      _SettlmtDocWrkflwDet._InvoicingPartyCompany,
      _SettlmtDocWrkflwDet._PayeeParty,
      _SettlmtDocWrkflwDet._PayeePartyCompany,
      _SettlmtDocWrkflwDet._AlternativeInvoicingParty,
      _SettlmtDocWrkflwDet._AltvInvoicingPartyCompany,
      _SettlmtDocWrkflwDet._CustSettlmtCompanyCode,
      _SettlmtDocWrkflwDet._SuplrSettlmtCompanyCode,
      _SettlmtDocWrkflwDet._SettlmtDocType,
      _SettlmtDocWrkflwDet._PurchasingGroup,
      _SettlmtDocWrkflwDet._SettlmtReltdCndnContr,
      _SettlmtDocWrkflwDet._ConditionContract,
      _SettlmtDocWrkflwDet._SettlmtDocCurrency,
      _SettlmtDocWrkflwDet._SalesOffice,
      _SettlmtDocWrkflwDet._SalesGroup

}