C_EarmarkWorkflowEmail

DDL: C_EARMARKWORKFLOWEMAIL SQL: IFMEFEMAIL Type: view CONSUMPTION Package: PSM_S4CO_ODATA_EF_WF

EarmarkedFund for Workflow ApprovalEmail

C_EarmarkWorkflowEmail is a Consumption CDS View that provides data about "EarmarkedFund for Workflow ApprovalEmail" in SAP S/4HANA. It reads from 1 data source (I_WorkflowTask) and exposes 5 fields with key field WorkflowTaskInternalID. Part of development package PSM_S4CO_ODATA_EF_WF.

1 data source(s) 5 fields

Data Sources (1)

SourceAliasJoin Type
I_WorkflowTask _Workflowtask from

Annotations (12)

NameValueLevelField
AbapCatalog.sqlViewName IFMEFEMAIL view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #NOT_REQUIRED view
AccessControl.personalData.blocking #NOT_REQUIRED view
EndUserText.label EarmarkedFund for Workflow ApprovalEmail view
VDM.viewType #CONSUMPTION view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
Metadata.ignorePropagatedAnnotations true view

Fields (5)

KeyFieldSource TableSource FieldDescription
KEY WorkflowTaskInternalID I_WorkflowTask WorkflowTaskInternalID
EarmarkedFundsDocument
UserDescription
WorkflowTaskResultReasonText
WorkflowTaskCurrentUser _WorkflowtaskDecision WorkflowTaskCurrentUser 
@AbapCatalog.sqlViewName: 'IFMEFEMAIL'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'EarmarkedFund for Workflow ApprovalEmail'

@VDM.viewType : #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType : {
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
@ObjectModel.supportedCapabilities: [ #OUTPUT_EMAIL_DATA_PROVIDER ]
@Metadata.ignorePropagatedAnnotations:true

define view C_EarmarkWorkflowEmail
  as select from            I_WorkflowTask           as _Workflowtask
    left outer to many join I_WorkflowTaskApplObject as _WorkflowTaskApplObject     on  _WorkflowTaskApplObject.WorkflowTaskInternalID = _Workflowtask.WorkflowTaskInternalID
                                                                                    and _WorkflowTaskApplObject.WorkflowObjectRole     = '01'
    left outer to one join  I_EarmarkedFundsDocument as _EarmarkedFundsDocument     on _EarmarkedFundsDocument.EarmarkedFundsDocument = _EarmarkedFundsDocument.EarmarkedFundsDocument
    left outer to one join  I_WorkflowTaskApplObject as _WorkflowTaskApplObDecision on  _WorkflowTaskApplObDecision.WorkflowTaskInternalID = _Workflowtask.WorkflowTaskInternalID
                                                                                    and _WorkflowTaskApplObDecision.WorkflowObjectRole     = '99'
    left outer to one join  I_WorkflowTask           as _WorkflowtaskDecision       on  _WorkflowtaskDecision.WorkflowTaskInternalID = _WorkflowTaskApplObDecision.TechnicalWrkflwObject
                                                                                    and _WorkflowtaskDecision.WorkflowTaskStatus     = 'COMPLETED'
    left outer to one join  I_User                   as _User                       on _User.UserID = _WorkflowtaskDecision.WorkflowTaskCurrentUser
    left outer to one join  I_WorkflowTaskResult     as _WorkflowTaskResult         on _WorkflowTaskResult.WorkflowInternalID   = _Workflowtask.WorkflowTaskInternalID
                                                                                    and(
                                                                                      _WorkflowTaskResult.WorkflowTaskResult    = 'APPROVED'
                                                                                      or _WorkflowTaskResult.WorkflowTaskResult = 'REJECTED'
                                                                                    )

{
  key _Workflowtask.WorkflowTaskInternalID,
      cast(substring(_WorkflowTaskApplObject.TechnicalWrkflwObject, 1 , 20 ) as fmis_earmarkedfundsdoc  ) as EarmarkedFundsDocument,
      case _Workflowtask._WorkflowTaskResult.WorkflowTaskResult
      when 'requestApproved' then 'Approved'
      when 'requestRejected' then 'Rejected'
      else _Workflowtask._WorkflowTaskResult.WorkflowTaskResult end                                       as WorkflowTaskResult,
      cast(_User.UserDescription as mm_oa_user_fullname )                                                 as UserDescription,
      _Workflowtask._WorkflowTaskResult._WorkflowTaskResultReason._WorkflowTaskResultReasonText[1:Language=$session.system_language].WorkflowTaskResultReasonText,
      _WorkflowtaskDecision.WorkflowTaskCurrentUser                                                       as WorkflowTaskCurrentUser
}
where
  _Workflowtask.WorkflowTaskType = 'F'

Learn More