C_GrantWorkflowEmail

@AbapCatalog.sqlViewName: 'IGMWFEMAIL'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Grant Details for Workflow Deadline Email'

@VDM.viewType : #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType : {
  serviceQuality: #D,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
@ObjectModel.supportedCapabilities: [ #OUTPUT_EMAIL_DATA_PROVIDER ]
@Metadata.ignorePropagatedAnnotations:true
define view C_GrantWorkflowEmail
  as select from            I_WorkflowTask           as _Workflowtask
    left outer to many join I_WorkflowTaskApplObject as _WorkflowTaskApplObject on  _WorkflowTaskApplObject.WorkflowTaskInternalID = _Workflowtask.WorkflowTaskInternalID
                                                                                and _WorkflowTaskApplObject.WorkflowObjectRole     = '99'
    left outer to one join  I_GrantCoreTP            as _Grant                  on _Grant.GrantID = _WorkflowTaskApplObject.TechnicalWrkflwObject
    left outer to one join  I_User                   as _User                   on _User.UserID = _Grant.CreatedByUser
{
  key _Workflowtask.WorkflowTaskInternalID,
      cast(substring(_WorkflowTaskApplObject.TechnicalWrkflwObject, 1 , 20 ) as gm_grant_nbr )                        as GrantID,
      _Grant._Text.GrantDescription                                                                                   as GrantDescription,
      _Grant.CompanyCode                                                                                              as CompanyCode,
      @Semantics.currencyCode: true
      _Grant.GrantCurrency,
      @Semantics.amount.currencyCode: 'GrantCurrency'
      _Grant.GrantTotalAmountInGrantCrcy                                                                              as GrantTotalAmountInGrantCrcy,
      _Grant.CostCenter                                                                                               as CostCenter,
      _Grant.GrantValidityPeriod                                                                                      as GrantValidityPeriod,
      case _Workflowtask._WorkflowTaskResult.WorkflowTaskResult
      when 'requestApproved' then 'Approved'
      when 'requestRejected' then 'Rejected'
      else _Workflowtask._WorkflowTaskResult.WorkflowTaskResult end                                                   as WorkflowTaskResult,
//      cast(tstmp_to_dats( _Workflowtask.WrkflwTskCreationUTCDateTime, 'UTC', $session.client, 'NULL' ) as sww_lsd )   as GrantWrkflwTskCreationUTCDate,

//      cast(tstmp_to_tims( _Workflowtask.WrkflwTskCreationUTCDateTime, 'UTC', $session.client, 'NULL' ) as sww_lst )   as GrantWrkflwTskCreationUTCTime,

//      cast(tstmp_to_dats( _Workflowtask.WrkflwTskCompletionUTCDateTime, 'UTC', $session.client, 'NULL' ) as sww_led ) as GrantWrkflwTaskEndUTCDate,

//      cast(tstmp_to_tims( _Workflowtask.WrkflwTskCompletionUTCDateTime, 'UTC', $session.client, 'NULL' ) as sww_let ) as GrantWrkflwTaskEndUTCTime,

      cast(_User.UserDescription as mm_oa_user_fullname )                                                             as CreatedByUserName,
      _Workflowtask._WorkflowTaskResult._WorkflowTaskResultReason._WorkflowTaskResultReasonText[1:Language=$session.system_language].WorkflowTaskResultReasonText
}