I_QltyNotification

@AbapCatalog: {
  sqlViewName: 'IQLTYNOTIF',
  preserveKey: true,
  compiler.compareFilter: true
}
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #REQUIRED,
  privilegedAssociations: ['_CreatedByUserContactCard', '_LastChangedByUserContactCard', '_StsObjConcatActiveStsILL']
}
@EndUserText.label: 'Quality Notification'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
    viewType: #COMPOSITE,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel: {
  representativeKey: 'QualityNotification',
    supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ],
    modelingPattern: #NONE,
    usageType: {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #L,
    serviceQuality: #A
    }
}
@Metadata.ignorePropagatedAnnotations: true
define view I_QltyNotification
  as select from I_Notification

  association [0..*] to I_QualityNotificationPartner as _QualityNotificationPartner  on  $projection.NotificationStatusObject = _QualityNotificationPartner.NotificationPartnerObject
  association [0..*] to I_QualityNotificationItem    as _QualityNotificationItem     on  $projection.QualityNotification = _QualityNotificationItem.QualityNotification
  association [0..*] to I_QltyNotificationTask       as _QltyNotificationTask        on  $projection.QualityNotification = _QltyNotificationTask.QualityNotification
  association [0..*] to I_QltyNotificationActivity   as _QltyNotificationActivity    on  $projection.QualityNotification = _QltyNotificationActivity.QualityNotification
  association [0..*] to I_QltyNotificationTask       as _QltyNotificationHdrTask     on  $projection.QualityNotification           = _QltyNotificationHdrTask.QualityNotification
                                                                                     and _QltyNotificationHdrTask.NotificationItem is initial
  association [0..*] to I_QltyNotificationActivity   as _QltyNotificationHdrActivity on  $projection.QualityNotification = _QltyNotificationHdrActivity.QualityNotification
                                                                                     and _QltyNotificationHdrActivity.NotificationItem is initial
  association [0..*] to I_QltyNotificationLongText   as _QltyNotificationLongText    on  $projection.QualityNotification = _QltyNotificationLongText.QualityNotification
  
  //Extension

  association [1..1] to E_QualityNotification        as _Extension                   on $projection.QualityNotification = _Extension.QualityNotification

{

      //=== Key Fields

  key I_Notification.Notification                                            as QualityNotification,

      //=== Common Fields

      I_Notification.MasterLanguage,
      I_Notification.NotificationOrigin,
      @ObjectModel.foreignKey.association: '_NotificationType'
      I_Notification.NotificationType,
      @ObjectModel.foreignKey.association: '_NotifProcessingPhase'
      I_Notification.NotifProcessingPhase,
      I_Notification.NotificationText,
      I_Notification.NotificationPriorityType,
      @ObjectModel.foreignKey.association: '_NotificationPriority'
      I_Notification.NotificationPriority,
      I_Notification.NotificationStatusObject,
      @Semantics.booleanIndicator: true
      I_Notification.IsBusinessPurposeCompleted,
      @Semantics.booleanIndicator: true
      I_Notification.IsDeleted,
      @Semantics.user.createdBy: true
      @ObjectModel.foreignKey.association: '_CreatedByUserContactCard'
      I_Notification.CreatedByUser,
      @Semantics.user.lastChangedBy: true
      @ObjectModel.foreignKey.association: '_LastChangedByUserContactCard'
      I_Notification.LastChangedByUser,
      @ObjectModel.foreignKey.association: '_NotificationCatalog'
      I_Notification.NotificationCatalog,
      @ObjectModel.foreignKey.association: '_NotificationCodeGroup'
      I_Notification.NotificationCodeGroup,
      @ObjectModel.foreignKey.association: '_NotificationCode'
      cast( I_Notification.NotificationCodeID as vdm_qmcod preserving type ) as NotificationCodeID,

      //=== Quantity Fields

      @Semantics.quantity.unitOfMeasure: 'NotificationQuantityUnit'
      I_Notification.NotificationComplaintQuantity,
      @Semantics.quantity.unitOfMeasure: 'NotificationQuantityUnit'
      I_Notification.NotificationInternalQuantity,
      @Semantics.quantity.unitOfMeasure: 'NotificationQuantityUnit'
      I_Notification.NotificationExternalQty,
      @ObjectModel.foreignKey.association: '_NotificationQuantityUnit'
      @Semantics.unitOfMeasure:true
      I_Notification.NotificationQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'NotificationQuantityUnit'
      I_Notification.NotificationReferenceQuantity,
      @Semantics.quantity.unitOfMeasure: 'NotificationQuantityUnit'
      I_Notification.NotifReturnDeliveryQuantity,

      //=== Date Fields

      @Semantics.systemDate.createdAt: true
      I_Notification.CreationDate,
      @Semantics.systemDate.lastChangedAt: true
      I_Notification.LastChangedDate,
      I_Notification.NotificationCreationTime,
      I_Notification.NotificationReportingDate,
      I_Notification.NotificationCompletionDate,
      I_Notification.NotificationRequiredStartDate,
      I_Notification.NotificationRequiredStartTime,
      I_Notification.NotificationRequiredEndDate,
      I_Notification.NotificationRequiredEndTime,
      I_Notification.CustomerPurchaseOrderDate,
      I_Notification.NotificationReturnDeliveryDate,

      cast ( I_Notification.NotificationTimeZone as vdm_qtzonso preserving type ) as NotificationTimeZone, 

      // etag field

      I_Notification.ChangedDateTime,

      //=== Partner Fields

      @ObjectModel.foreignKey.association: '_Supplier'
      I_Notification.Supplier,
      @ObjectModel.foreignKey.association: '_Customer'
      I_Notification.Customer,
      I_Notification.ReportedByUser,

      //=== Reference Object Fields

      @ObjectModel.foreignKey.association: '_Product'
      I_Notification.Material,
      @ObjectModel.foreignKey.association: '_ProductGroup'
      I_Notification.MaterialGroup,
      @ObjectModel.foreignKey.association: '_Plant'
      I_Notification.Plant,
      I_Notification.ProductionOrder,
      I_Notification.MfgOrderInternalID,
      I_Notification.ProductionVersion,
      @ObjectModel.foreignKey.association: '_PurchasingDocument'
      I_Notification.PurchasingDocument,
      I_Notification.PurchasingDocumentItem,
      I_Notification.PurchasingOrganization,
      I_Notification.PurchasingGroup,
      I_Notification.ActiveDivision,
      I_Notification.SalesOrganization,
      I_Notification.DistributionChannel,
      I_Notification.WBSElementInternalID,
      I_Notification.WorkCenterTypeCode,
      I_Notification.MainWorkCenterInternalID,
      I_Notification.MainWorkCenterPlant,
      @ObjectModel.foreignKey.association: '_InspectionLot'
      I_Notification.InspectionLot,
      I_Notification.OrderOperationInternalID,
      I_Notification.Batch,
      I_Notification.Manufacturer,
      I_Notification.MaterialDocumentYear,
      I_Notification.MaterialDocument,
      I_Notification.MaterialDocumentItem,
      I_Notification.AdditionalDeviceData,
      cast( I_Notification.NotificationLinkedNotification as vdm_qwrnum preserving type ) as NotificationLinkedNotification,
      cast( I_Notification.NotificationExtReferenceNumber as vdm_qmextnr preserving type ) as NotificationExtReferenceNumber,
      I_Notification.OrderDocument,
      I_Notification.DeliveryDocument,
      I_Notification.DeliveryDocumentItem,
      I_Notification.PurchaseOrderByCustomer,

      //=== Expose Associations

      _QualityNotificationItem,
      _QltyNotificationHdrTask,
      _QltyNotificationTask,
      _QltyNotificationHdrActivity,
      _QltyNotificationActivity,
      _QltyNotificationLongText,
      _Plant,
      _Product,
      _ProductGroup_2,
      @VDM.lifecycle.status:#DEPRECATED
      @VDM.lifecycle.successor: '_ProductGroup_2'
      _ProductGroup,
      _PurchasingDocument,
      _Supplier,
      _Customer,
      _NotificationQuantityUnit,
      _WBSElement,
      _InspectionLot,
      _InspectionOperation, 
      _OrderOperationBasic,      
      _NotificationType,
      _NotificationPriority,
      _NotificationCatalog,
      _NotificationCodeGroup,
      _NotificationCode,
      _NotifProcessingPhase,
      _StsObjConcatActiveStsILL,
      _CreatedByUserContactCard,
      _LastChangedByUserContactCard,
      _QualityNotificationPartner,
      _QualityNotificationItem                                               as _NotificationItem

}
where
     I_Notification.NotificationOrigin = 'Q1'
  or I_Notification.NotificationOrigin = 'Q2'
  or I_Notification.NotificationOrigin = 'Q3'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_NOTIFICATION"
],
"ASSOCIATED":
[
"E_QUALITYNOTIFICATION",
"I_CUSTOMER",
"I_INSPECTIONLOT",
"I_INSPECTIONOPERATION",
"I_NOTIFICATIONCATALOG",
"I_NOTIFICATIONCODE",
"I_NOTIFICATIONCODEGROUP",
"I_NOTIFICATIONPRIORITY",
"I_NOTIFICATIONTYPE",
"I_NOTIFPROCESSINGPHASE",
"I_ORDEROPERATIONBASIC",
"I_PLANT",
"I_PRODUCT",
"I_PRODUCTGROUP",
"I_PRODUCTGROUP_2",
"I_PURCHASINGDOCUMENT",
"I_QLTYNOTIFICATIONACTIVITY",
"I_QLTYNOTIFICATIONLONGTEXT",
"I_QLTYNOTIFICATIONTASK",
"I_QUALITYNOTIFICATIONITEM",
"I_QUALITYNOTIFICATIONPARTNER",
"I_STSOBJCONCATACTIVESTSILL",
"I_SUPPLIER",
"I_UNITOFMEASURE",
"I_USERCONTACTCARD",
"I_WBSELEMENT"
],
"BASE":
[
"I_NOTIFICATION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/