I_QltyNotificationVH

@AbapCatalog.sqlViewName: 'IQLTYNOTIFVH'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@EndUserText.label: 'Search help for Quality Notification'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE

@ObjectModel.representativeKey: 'QualityNotification'
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #L,
        serviceQuality: #C
    },
    dataCategory: #VALUE_HELP
}
@Search.searchable: true
@Consumption.ranked: true

define view I_QltyNotificationVH as select from I_QltyNotification {

//=== Key Fields

        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #HIGH }
        @UI.lineItem: [{ importance: #HIGH }]
    key QualityNotification,
    
//=== Common Fields 

        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        NotificationOrigin,
        
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        @ObjectModel.text.element: ['NotificationTypeName']
        @UI.lineItem: [{ importance: #HIGH }]
        NotificationType,
        
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        @Consumption.filter.hidden: true
        @UI.lineItem: [{ importance: #HIGH }]
        _NotificationType._NotificationTypeName[1:Language = $session.system_language].NotificationTypeName,
        
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        @ObjectModel.text.element: ['NotifProcessingPhaseDesc']
        @UI.lineItem: [{ importance: #HIGH }]
        NotifProcessingPhase,
        
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        @Consumption.filter.hidden: true
        @UI.lineItem: [{ importance: #HIGH }]
        _NotifProcessingPhase._Text[1:Language = $session.system_language].NotifProcessingPhaseDesc,
        
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        @UI.lineItem: [{ importance: #HIGH }]
        NotificationText,
        
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        NotificationPriorityType,
        
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        @ObjectModel.text.element: ['NotificationPriorityText']
        NotificationPriority,
        
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        @Consumption.filter.hidden: true
        _NotificationPriority._NotificationPriorityText[1:Language = $session.system_language].NotificationPriorityText,
        
        @Consumption.hidden: true
        IsBusinessPurposeCompleted,
       
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        @Semantics.user.createdBy: true
        CreatedByUser,
        
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        @Semantics.user.lastChangedBy: true
        LastChangedByUser, 
 
//=== Date Fields

        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        @Semantics.systemDate.createdAt: true
        CreationDate,
        
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        @Semantics.systemDate.lastChangedAt: true
        LastChangedDate,
        
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        NotificationReportingDate,
        
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        NotificationCompletionDate,
        
//=== Partner Fields

        @ObjectModel.foreignKey.association: '_Supplier'
        @UI.lineItem: [{ importance: #HIGH }]
        Supplier,
        @UI.lineItem: [{ importance: #HIGH }]
        Customer,
         
//=== Reference Object Fields

        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        @ObjectModel.foreignKey.association: '_Product'
        @ObjectModel.text.element: ['ProductName']
        @UI.lineItem: [{ importance: #HIGH }]
        Material,
        
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        @Consumption.filter.hidden: true
        _Product._Text[1:Language = $session.system_language].ProductName,
        
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        @ObjectModel.foreignKey.association: '_Plant'
        @UI.lineItem: [{ importance: #HIGH }]
        Plant,
        
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        @ObjectModel.foreignKey.association: '_PurchasingDocument'
        PurchasingDocument,
        
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        PurchasingOrganization,
        
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        PurchasingGroup,
        
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        ActiveDivision, 
        
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        SalesOrganization, 
        
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        DistributionChannel, 
        
        @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8 , ranking: #LOW }
        _WBSElement.WBSElement,
        
        @Consumption.hidden: true
        _Supplier,
        @Consumption.hidden: true
        _Product,
        @Consumption.hidden: true
        _Plant,        
        @Consumption.hidden: true
        _PurchasingDocument     
        
  }
where IsDeleted = ' '
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_NOTIFICATIONPRIORITY",
"I_NOTIFICATIONPRIORITYTEXT",
"I_NOTIFICATIONTYPE",
"I_NOTIFICATIONTYPENAME",
"I_NOTIFPROCESSINGPHASE",
"I_NOTIFPROCESSINGPHASEDESC",
"I_PRODUCT",
"I_PRODUCTTEXT",
"I_QLTYNOTIFICATION",
"I_WBSELEMENT"
],
"ASSOCIATED":
[
"I_PLANT",
"I_PRODUCT",
"I_PURCHASINGDOCUMENT",
"I_SUPPLIER"
],
"BASE":
[
"I_QLTYNOTIFICATION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/