I_QltyNotificationCube

@AbapCatalog.sqlViewName: 'IQLTYNOTIFC'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@EndUserText.label: 'Quality Notification Cube'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE

@ObjectModel.representativeKey: 'QualityNotification'
@ObjectModel.usageType: {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #L,
    serviceQuality: #D
}

@Analytics.dataCategory: #CUBE
@Metadata.allowExtensions: true

define view I_QltyNotificationCube as select from I_QltyNotification 
  
  //=== Association to status view

  association [1..1] to I_QltyNotificationWithStatus as _QltyNotificationWithStatus on $projection.QualityNotification = _QltyNotificationWithStatus.QualityNotification

{

//=== Key Fields

  key I_QltyNotification.QualityNotification,

//=== Common Fields

      I_QltyNotification.NotificationOrigin,
      I_QltyNotification.NotificationType,
      I_QltyNotification.NotificationPriority,
      I_QltyNotification.IsBusinessPurposeCompleted,

//=== Date Fields

      @Semantics.systemDate.createdAt: true
      I_QltyNotification.CreationDate,
      I_QltyNotification.NotificationReportingDate,
      I_QltyNotification.NotificationCompletionDate,

//=== Status Fields

      _QltyNotificationWithStatus.NotificationIsCompleted,
      _QltyNotificationWithStatus.NotificationIsDeleted,
      _QltyNotificationWithStatus.NotificationIsExtCaused,

//=== Partner Fields

      @ObjectModel.foreignKey.association: '_Supplier'
      I_QltyNotification.Supplier,
      
//=== Reference Object Fields

      @ObjectModel.foreignKey.association: '_Product'
      I_QltyNotification.Material,
      @ObjectModel.foreignKey.association: '_Plant'
      I_QltyNotification.Plant,
      @ObjectModel.foreignKey.association: '_PurchasingDocument'
      I_QltyNotification.PurchasingDocument,
      I_QltyNotification.PurchasingDocumentItem,
      I_QltyNotification.PurchasingOrganization,
     
//=== Aggregates

      @DefaultAggregation: #SUM
      cast ('1' as vdm_qltynotificationcount)                          as QualityNotificationCount,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'NotificationQuantityUnit'
      I_QltyNotification.NotificationExternalQty,
      @ObjectModel.foreignKey.association: '_NotificationQuantityUnit'
      @Semantics.unitOfMeasure:true
      I_QltyNotification.NotificationQuantityUnit,
    
//=== Associations

      I_QltyNotification._Product,
      I_QltyNotification._Plant,
      I_QltyNotification._Supplier,
      I_QltyNotification._PurchasingDocument,
      I_QltyNotification._NotificationQuantityUnit
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_QLTYNOTIFICATION",
"I_QLTYNOTIFICATIONWITHSTATUS"
],
"ASSOCIATED":
[
"I_PLANT",
"I_PRODUCT",
"I_PURCHASINGDOCUMENT",
"I_QLTYNOTIFICATIONWITHSTATUS",
"I_SUPPLIER",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_QLTYNOTIFICATION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/