I_QltyNotifKeyFigCube

@AbapCatalog : {
  buffering.status: #NOT_ALLOWED,
  compiler.compareFilter: true,
  sqlViewName: 'IQLTYNOTIFKFCUBE',
  preserveKey: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #REQUIRED
}
@Analytics: {
  dataCategory: #CUBE
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Key Figure view - Notification Analytics'
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions:true
@ObjectModel: {
    representativeKey: 'QualityNotification',
    semanticKey:  [ 'QualityNotification' ],
    usageType: {
        dataClass: #MIXED,
        sizeCategory: #L,
        serviceQuality: #C }
}
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define view I_QltyNotifKeyFigCube
  with parameters
    P_StartDate : mm_a_delivery_date,
    P_EndDate   : mm_a_delivery_date
  as select from I_QltyNotification
  association [0..1] to I_WorkCenterBySemanticKey as _WorkCenterBySemanticKey on  $projection.MainWorkCenterInternalID = _WorkCenterBySemanticKey.WorkCenterInternalID
                                                                              and $projection.MainWorkCenterPlant      = _WorkCenterBySemanticKey.Plant
                                                                              and $projection.WorkCenterTypeCode       = _WorkCenterBySemanticKey.WorkCenterTypeCode
{
  key QualityNotification,
      NotificationType,
      IsBusinessPurposeCompleted,
      IsDeleted,
      CreationDate,
      MainWorkCenterInternalID,
      MainWorkCenterPlant,
      WorkCenterTypeCode,
      _WorkCenterBySemanticKey.WorkCenter,
      _WorkCenterBySemanticKey._WorkCenterTextBySemanticKey[1:Language=$session.system_language].WorkCenterText,

      case
            when(I_QltyNotification.Supplier = '')
                then
                     _InspectionLot.Supplier
                else
                     I_QltyNotification.Supplier
            end                 as               Supplier,
      case
            when(I_QltyNotification.Customer = '')
                then
                     _InspectionLot.Customer
                else
                     I_QltyNotification.Customer
            end                 as               Customer,
      case
            when(I_QltyNotification.Material = '')
                then
                     _InspectionLot.Material
                else
                     I_QltyNotification.Material
            end                 as               Material,
      case
            when(I_QltyNotification.Plant = '')
                then
                     cast( _InspectionLot.Plant as werks_d )
                else
                     cast( I_QltyNotification.Plant as werks_d )
            end                 as               Plant,

      case
            when(I_QltyNotification.MainWorkCenterPlant = '')
                then
                    cast( _InspectionLot.Plant as vdm_poplatzwrk )
                else
                     cast( I_QltyNotification.MainWorkCenterPlant as vdm_poplatzwrk )
            end                 as               WorkCenterPlant,

      NotificationCompletionDate,
      NotificationRequiredStartDate,
      NotificationRequiredEndDate,

      cast( 1 as vdm_notifcnt ) as               QualityNotificationCount,

      case
            when( NotificationCompletionDate !='00000000' and NotificationRequiredStartDate !='00000000' )
                then
                     DATS_DAYS_BETWEEN( NotificationRequiredStartDate, NotificationCompletionDate )
                else
                     cast ( 0 as vdm_notifprocgperd )
            end                 as               QltyNotifProcessPeriod,

      case
            when( (NotificationCompletionDate !='00000000' and NotificationRequiredEndDate !='00000000') and NotificationCompletionDate > NotificationRequiredEndDate )
                then
                     cast ( 1 as vdm_notifovrdcnt )
                else
                     cast ( 0 as vdm_notifovrdcnt )
            end                 as               CntOfQltyNotifOverdue,

      _NotificationType
}
where
      CreationDate >= $parameters.P_StartDate
  and CreationDate <= $parameters.P_EndDate
  and IsDeleted != 'X'
  and NotifProcessingPhase != '5'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSPECTIONLOT",
"I_QLTYNOTIFICATION",
"I_WORKCENTERBYSEMANTICKEY",
"I_WORKCENTERTEXTBYSEMANTICKEY"
],
"ASSOCIATED":
[
"I_NOTIFICATIONTYPE",
"I_WORKCENTERBYSEMANTICKEY"
],
"BASE":
[
"I_QLTYNOTIFICATION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/