R_QltyNotificationTP

@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Quality Notification'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.semanticKey: ['QualityNotification']
@ObjectModel.representativeKey: 'QualityNotification'
@ObjectModel.usageType:{                 
  serviceQuality: #A,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
@ObjectModel.sapObjectNodeType.name: 'QualityNotification'
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL

define root view entity R_QltyNotificationTP
  as select from I_QltyNotification as Notification

//Compositions to child nodes

  composition [0..*] of R_QltyNotificationLongTextTP   as _QltyNotificationLongText
  composition [0..*] of R_QualityNotificationPartnerTP as _QltyNotificationPartner 
  composition [0..*] of R_QualityNotificationItemTP    as _QualityNotificationItem
  composition [0..*] of R_QltyNotificationTaskTP       as _QltyNotificationTask

  //Extension

  association [1..1] to E_QualityNotification as _Extension on $projection.QualityNotification = _Extension.QualityNotification
{
      @ObjectModel.sapObjectNodeTypeReference: 'QualityNotification'
  key QualityNotification,
      MasterLanguage,
      NotificationOrigin,
      NotificationType,
      NotifProcessingPhase,
      NotificationText,
      NotificationPriorityType,
      NotificationPriority,
      NotificationStatusObject,
      @Semantics.booleanIndicator
      IsBusinessPurposeCompleted,
      @Semantics.booleanIndicator
      IsDeleted,
      NotificationCatalog,
      NotificationCodeGroup,
      NotificationCodeID,

      // Quantities

      @Semantics.quantity.unitOfMeasure: 'NotificationQuantityUnit'
      NotificationComplaintQuantity,
      @Semantics.quantity.unitOfMeasure: 'NotificationQuantityUnit'
      NotificationExternalQty,
      NotificationQuantityUnit,
      
      // Dates

      NotificationReportingDate,
      NotificationCompletionDate,
      NotificationRequiredStartDate,
      @Semantics.time: true
      NotificationRequiredStartTime,
      NotificationRequiredEndDate,
      @Semantics.time: true
      NotificationRequiredEndTime,
      NotificationTimeZone,

      Supplier,
      Customer,
      Material,
      MaterialGroup,
      Plant,
      PurchasingDocument,
      PurchasingDocumentItem,
      PurchasingOrganization,
      PurchasingGroup,
      ActiveDivision,
      SalesOrganization,
      DistributionChannel,
      WBSElementInternalID,
      WorkCenterTypeCode,
      MainWorkCenterInternalID,
      MainWorkCenterPlant,
      InspectionLot,
      Batch,
      MaterialDocumentYear,
      MaterialDocument,
      MaterialDocumentItem,

      // Admin Data

      @Semantics.user.createdBy: true
      CreatedByUser,
      @Semantics.systemDate.createdAt: true
      CreationDate,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser,
      @Semantics.systemDate.lastChangedAt: true
      LastChangedDate,
      // etag

      ChangedDateTime,

      /* Associations */
      _QltyNotificationLongText,
      _QltyNotificationPartner,
      _QualityNotificationItem,
      _QltyNotificationTask


      /*_CreatedByUserContactCard,
      _InspectionLot,
      _LastChangedByUserContactCard,
      _NotificationCatalog,
      _NotificationCode,
      _NotificationCodeGroup,
      _NotificationItem,
      _NotificationPriority,
      _NotificationQuantityUnit,
      _NotificationType,
      _NotifProcessingPhase,
      _Plant,
      _Product,
      _ProductGroup,
      _ProductGroup_2,
      _PurchasingDocument,
      _QltyNotificationActivity,
      _QltyNotificationLongText,
      _QltyNotificationTask,
      _QualityNotificationItem,
      _QualityNotificationPartner,
      _Supplier,
      _WBSElement*/
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_QLTYNOTIFICATION"
],
"ASSOCIATED":
[
"R_QLTYNOTIFICATIONLONGTEXTTP",
"R_QLTYNOTIFICATIONTASKTP",
"R_QUALITYNOTIFICATIONITEMTP",
"R_QUALITYNOTIFICATIONPARTNERTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/