I_QltyNotificationActivity

@AbapCatalog.sqlViewName: 'IQNOTIFACT'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations: ['_CreatedByUserContactCard', '_LastChangedByUserContactCard']

@VDM.viewType: #COMPOSITE

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
    representativeKey: 'NotificationActivity',
    supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ],
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #L,
        serviceQuality: #A }
}
@EndUserText.label: 'Quality Notification Activity'
@Metadata.ignorePropagatedAnnotations: true
define view I_QltyNotificationActivity
  as select from I_NotificationActivity
    inner join   I_QltyNotification on I_NotificationActivity.Notification = I_QltyNotification.QualityNotification

  association [0..1] to I_QltyNotification          as _Notification              on  $projection.QualityNotification = _Notification.QualityNotification

  association [0..*] to I_QltyNotifActivityLongText as _QltyNotifActivityLongText on  $projection.QualityNotification  = _QltyNotifActivityLongText.QualityNotification
                                                                                  and $projection.NotificationActivity = _QltyNotifActivityLongText.NotificationActivity

{
                          //=== Key Fields

                          @ObjectModel.foreignKey.association: '_Notification'
  key                     I_NotificationActivity.Notification as QualityNotification,
  key                     I_NotificationActivity.NotificationActivity,
                          I_NotificationActivity.NotificationItem,
                          //=== Common Fields

                          I_NotificationActivity.NotificationActivitySortNumber,
                          @Semantics.booleanIndicator: true
                          I_NotificationActivity.IsDeleted,
                          I_NotificationActivity.MasterLanguage,
                          @ObjectModel.foreignKey.association: '_NotifActivityCatalog'
                          I_NotificationActivity.NotifActivityCatalog,
                          @ObjectModel.foreignKey.association: '_NotifActivityCodeGroup'
                          I_NotificationActivity.NotifActivityCodeGroup,
                          @ObjectModel.foreignKey.association: '_NotifActivityCode'
                          I_NotificationActivity.NotifActivityCode,

                          I_NotificationActivity.NotifActivityText,
                          I_NotificationActivity.NotifActivityStartDate,
                          I_NotificationActivity.NotifActivityStartTime,
                          I_NotificationActivity.NotifActivityEndDate,
                          I_NotificationActivity.NotifActivityEndTime,
                          I_QltyNotification.NotifProcessingPhase,

                          //=== Administrative Data

                          I_NotificationActivity.ChangedDateTime,
                          @ObjectModel.foreignKey.association: '_CreatedByUserContactCard'
                          I_NotificationActivity.CreatedByUser,
                          @Semantics.systemDate.createdAt: true
                          I_NotificationActivity.CreationDate,
                          I_NotificationActivity.CreationTime,
                          @ObjectModel.foreignKey.association: '_LastChangedByUserContactCard'
                          I_NotificationActivity.LastChangedByUser,
                          @Semantics.systemDate.lastChangedAt: true
                          I_NotificationActivity.LastChangeDate,
                          I_NotificationActivity.LastChangeTime,
                          @Consumption.hidden: true
                          @Semantics.booleanIndicator: true
                          I_QltyNotification.IsBusinessPurposeCompleted,

                          /* Associations */
                          _Notification,
                          I_NotificationActivity._CreatedByUserContactCard,
                          I_NotificationActivity._LastChangedByUserContactCard,
                          I_NotificationActivity._Language,
                          I_NotificationActivity._NotifActivityCatalog,
                          I_NotificationActivity._NotifActivityCodeGroup,
                          I_NotificationActivity._NotifActivityCode,
                          _QltyNotifActivityLongText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_NOTIFICATIONACTIVITY",
"I_QLTYNOTIFICATION"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_NOTIFACTIVITYCATALOG",
"I_NOTIFACTIVITYCODE",
"I_NOTIFACTIVITYCODEGROUP",
"I_QLTYNOTIFACTIVITYLONGTEXT",
"I_QLTYNOTIFICATION",
"I_USERCONTACTCARD"
],
"BASE":
[
"I_NOTIFICATIONACTIVITY"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/