I_CustomerReturnItemEnhanced

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Returns Order Item Enhanced'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations: [ '_CreatedByUser', '_Address', '_DfltAddrRprstn' ]
}
@AbapCatalog: {
  sqlViewName: 'ISDCRITMENHANCED',
  preserveKey: true,
  compiler.compareFilter: true
}
@ObjectModel: {
  representativeKey: 'CustomerReturnItem',
  modelingPattern: #ANALYTICAL_DIMENSION,
  supportedCapabilities: [#ANALYTICAL_DIMENSION, 
                          #CDS_MODELING_ASSOCIATION_TARGET, 
                          #CDS_MODELING_DATA_SOURCE,
                          #SQL_DATA_SOURCE],
  usageType: {
    dataClass:      #TRANSACTIONAL,
    serviceQuality: #D,
    sizeCategory:   #XL
   }
}
@Analytics.dataCategory: #DIMENSION
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions: true 

define view I_CustomerReturnItemEnhanced
  as select from I_CustomerReturnItem              as Item
  left outer join I_AdvncdReturnsMgmtProcessItem   as AdvncdRetsMgmtProcessItem  on  AdvncdRetsMgmtProcessItem.RetsMgmtProcess     = Item.RetsMgmtProcess
                                                                                and  AdvncdRetsMgmtProcessItem.RetsMgmtProcessItem = Item.CustomerReturnItem
  
  left outer join I_AdvncdReturnsMgmtProcessStep   as AdvncdRetsMgmtProcessStep  on  AdvncdRetsMgmtProcessStep.RetsMgmtProcess          = Item.RetsMgmtProcess
                                                                                and  AdvncdRetsMgmtProcessStep.RetsMgmtProcessItem      = Item.CustomerReturnItem
                                                                                and  AdvncdRetsMgmtProcessStep.RetsMgmtProcItmQtySplit  = '000'
                                                                                and  AdvncdRetsMgmtProcessStep.RetsMgmtProcessStep      = '0001'
                                                                                and  AdvncdRetsMgmtProcessStep.ReturnsDocumentType      = '00'                                                                            //  

      
//Association   

association [1..1] to I_CustomerReturnEnhanced     as _CustomerReturn            on  _CustomerReturn.CustomerReturn = $projection.CustomerReturn   
{
      @Consumption.valueHelpDefinition: [ 
        { entity: { name:    'I_CustomerReturnStdVH',
                   element: 'CustomerReturn' }
        }]      
      @ObjectModel.foreignKey.association: '_CustomerReturn'
 key  Item.CustomerReturn,
 key  Item.CustomerReturnItem,

      Item.CustomerReturnItemUUID,

      //Category

      Item.CustomerReturnItemCategory,
      Item.CustomerReturnItemType,
      Item.IsReturnsItem,

      //Admin

      Item.CreatedByUser,
      Item.CreationDate,
      Item.CreationTime,
      Item.LastChangeDate,

      //Org

      Item.Division,

      //Product

      @Consumption.valueHelpDefinition: [ 
        { entity: { name:    'I_MaterialStdVH',
                    element: 'Material' }
        }]
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'Product'
      Item.Material,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_Product'
      Item._Material,
      
      @Analytics.internalName: #LOCAL
      Item.Product,
      Item._Product,
      
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'ProductGroup'
      Item.MaterialGroup,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_ProductGroup'
      Item._MaterialGroup,
      
      @Analytics.internalName: #LOCAL
      Item.ProductGroup,
      Item._ProductGroup,
                      
      @Consumption.valueHelpDefinition: [ 
        { entity: { name:    'I_MaterialStdVH',
                    element: 'Material' }
        }]
      Item.OriginallyRequestedMaterial,
      Item.MaterialByCustomer,
      Item.InternationalArticleNumber,
      Item.Batch,
      Item.ProductHierarchyNode,
      Item.ProductCatalog,
      Item.AdditionalMaterialGroup1,
      Item.AdditionalMaterialGroup2,
      Item.AdditionalMaterialGroup3,
      Item.AdditionalMaterialGroup4,
      Item.AdditionalMaterialGroup5,
      Item.Plant,
      Item.StorageLocation,
      Item.ProductConfiguration,
      Item.BillOfMaterial,
      Item.BOMExplosionDate,

      //Sales

      Item.CustomerReturnItemText,
      Item.PurchaseOrderByCustomer,
      
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      Item.OrderQuantity,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      Item.ConfdDelivQtyInOrderQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      Item.TargetDelivQtyInOrderQtyUnit,
      @Semantics.unitOfMeasure: true
      Item.OrderQuantityUnit,
      
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      Item.ConfdDeliveryQtyInBaseUnit,
      //@Semantics.unitOfMeasure: true

      Item.BaseUnit,
      
      Item.OrderToBaseQuantityDnmntr,
      Item.OrderToBaseQuantityNmrtr,
      
      @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
      Item.RequestedQuantity,
      //@Semantics.unitOfMeasure: true

      Item.RequestedQuantityUnit,
      
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      Item.RequestedQuantityInBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      Item.ItemGrossWeight,
      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      Item.ItemNetWeight,
      //@Semantics.unitOfMeasure: true

      Item.ItemWeightUnit,
      
      @Semantics.quantity.unitOfMeasure: 'ItemVolumeUnit'
      Item.ItemVolume,
      //@Semantics.unitOfMeasure: true

      Item.ItemVolumeUnit,
      Item.ServicesRenderedDate,
      Item.SalesDistrict,
      @Consumption.valueHelpDefinition: [ 
        { entity: { name:    'I_SalesDealStdVH',
                    element: 'SalesDeal' }
        }]
      Item.SalesDeal,
      Item.CustomerGroup,
      Item.SalesDocumentRjcnReason,

      //Pricing

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      Item.NetAmount,
      Item.PricingDate,
      @Semantics.currencyCode: true
      Item.TransactionCurrency,
      Item.ExchangeRateDate,
      Item.PriceDetnExchangeRate,
      
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      Item.NetPriceAmount,
      
      @Semantics.quantity.unitOfMeasure: 'NetPriceQuantityUnit'
      Item.NetPriceQuantity,
      //@Semantics.unitOfMeasure: true

      Item.NetPriceQuantityUnit,
      
      Item.StatisticalValueControl,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      Item.TaxAmount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      Item.CostAmount,
      
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      Item.Subtotal1Amount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      Item.Subtotal2Amount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      Item.Subtotal3Amount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      Item.Subtotal4Amount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      Item.Subtotal5Amount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      Item.Subtotal6Amount,

      //Shipping

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_ShippingPointStdVH',
                     element: 'ShippingPoint' }
        }]
      Item.ShippingPoint,
      Item.ShippingType,
      Item.InventorySpecialStockType,
      Item.DeliveryPriority,
      Item.Route,
      Item.DeliveryDateQuantityIsFixed,
      Item.PartialDeliveryIsAllowed,
      Item.MaxNmbrOfPartialDelivery,
      Item.UnlimitedOverdeliveryIsAllowed,
      Item.OverdelivTolrtdLmtRatioInPct,
      Item.UnderdelivTolrtdLmtRatioInPct,
      
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      Item.MinDeliveryQtyInBaseUnit,
      Item.IncotermsClassification,
      Item.IncotermsTransferLocation,
      Item.IncotermsLocation1,
      Item.IncotermsLocation2,
      Item.IncotermsVersion,
      Item.ItemIsDeliveryRelevant,

      //Billing

      Item.BillingDocumentDate,
      Item.ItemIsBillingRelevant,
      Item.ItemBillingBlockReason,

      //Payment

      Item.CustomerPaymentTerms,
      Item.PaymentMethod,

      //Tax Classfication

      Item.ProductTaxClassification1,
      Item.ProductTaxClassification2,
      Item.ProductTaxClassification3,
      Item.ProductTaxClassification4,
      Item.ProductTaxClassification5,
      Item.ProductTaxClassification6,
      Item.ProductTaxClassification7,
      Item.ProductTaxClassification8,
      Item.ProductTaxClassification9,

      //Accounting

      Item.FiscalYear,
      Item.FiscalPeriod,
      Item.CustomerAccountAssignmentGroup,
      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_BusinessAreaStdVH',
                     element: 'BusinessArea' }
        }]
      Item.BusinessArea,
      Item.ProfitCenter,
      Item.WBSElementInternalID,
      Item.OrderID,
      Item.ControllingObject,
      @API.element.releaseState: #DECOMMISSIONED
      @API.element.successor: 'ProfitabilitySegment_2'      
      Item.ProfitabilitySegment,
      Item.ProfitabilitySegment_2,
      Item.OriginSDDocument,
      Item.OriginSDDocumentItem,

      //Reference

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_SalesDocumentStdVH',
                     element: 'SalesDocument' }
        }]
      Item.ReferenceSDDocument,
      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_SalesDocumentItemStdVH',
                     element: 'SalesDocumentItem' },
          additionalBinding: [{ localElement: 'ReferenceSDDocument',
                                element: 'SalesDocument' }]
        }]
      Item.ReferenceSDDocumentItem,
      Item.ReferenceSDDocumentCategory,
      Item.HigherLevelItem,

      //Advanced Returns Management Process 

      Item.RetsMgmtProcess,
      
      //Advanced Returns Management Process Item

      AdvncdRetsMgmtProcessItem.RetsMgmtProcessItem,
      Item.ReturnReason,
      Item.ReturnsRefundExtent,
      Item.RetsMgmtProcessingBlock,
  
      AdvncdRetsMgmtProcessItem.ReturnsRefundRjcnReason,   
      AdvncdRetsMgmtProcessItem.CustRetMatlAuthzn,   
      AdvncdRetsMgmtProcessItem.CustomerRetMatlInspResultCode,
      AdvncdRetsMgmtProcessItem.NextFllwUpActivityForMatlInsp,
     
      AdvncdRetsMgmtProcessItem.RetsMgmtItmLogProcgStatus,
      AdvncdRetsMgmtProcessItem.RetsMgmtItmCompnProcgStatus,
      AdvncdRetsMgmtProcessItem.RetsMgmtItmProcgStatus,
 
      AdvncdRetsMgmtProcessItem.CRMLogicalSystem,
      AdvncdRetsMgmtProcessItem.CRMObjectUUID,
      AdvncdRetsMgmtProcessItem.CRMObjectID,
      AdvncdRetsMgmtProcessItem.CRMObjectType,
      
      //Advanced Returns Management Process Step (Return Order)

      AdvncdRetsMgmtProcessStep.RetsMgmtProcItmQtySplit,
      AdvncdRetsMgmtProcessStep.RetsMgmtProcessStep, 
  
      AdvncdRetsMgmtProcessStep.ReturnsDocumentType,
      AdvncdRetsMgmtProcessStep.ReturnsDocument as ReturnsDocument,
      AdvncdRetsMgmtProcessStep.ReturnsDocumentItem,
  
      AdvncdRetsMgmtProcessStep.ReturnsReferenceDocumentType,
      AdvncdRetsMgmtProcessStep.ReturnsReferenceDocument,
      AdvncdRetsMgmtProcessStep.ReturnsReferenceDocumentItem,
     
      AdvncdRetsMgmtProcessStep.ReturnsDocumentStatus,
      AdvncdRetsMgmtProcessStep.ReturnsDocumentApprovalStatus,
      
      AdvncdRetsMgmtProcessStep.RetsMgmtProcItmExectdSequence,
      AdvncdRetsMgmtProcessStep.CustRetItmChainID,  
          
      AdvncdRetsMgmtProcessStep.CustRetItmFollowUpActivity,
      AdvncdRetsMgmtProcessStep.ReturnsMaterialHasBeenReceived, 
      AdvncdRetsMgmtProcessStep.NextPlantForFollowUpActivity,
      AdvncdRetsMgmtProcessStep.ReturnsTransshipmentPlant,
   
      AdvncdRetsMgmtProcessStep.ReturnsRefundType,
      AdvncdRetsMgmtProcessStep.ReturnsRefundProcgMode,
      @Semantics.booleanIndicator:true
      AdvncdRetsMgmtProcessItem.RetsProdValnIsSuspended,
      AdvncdRetsMgmtProcessStep.PrelimRefundIsDetermined,
  
      AdvncdRetsMgmtProcessStep.ReplacementMaterial,
      @Semantics.quantity.unitOfMeasure: 'ReplacementMaterialQtyUnit'
      AdvncdRetsMgmtProcessStep.ReplacementMaterialQuantity,
      //@Semantics.unitOfMeasure: true

      AdvncdRetsMgmtProcessStep.ReplacementMaterialQtyUnit,
      AdvncdRetsMgmtProcessStep.ReplacementMaterialIsRequested,
      AdvncdRetsMgmtProcessStep.ReplacementMatlSupplyingPlant,
  
      AdvncdRetsMgmtProcessStep.Supplier,
      AdvncdRetsMgmtProcessStep.AddressID,
      AdvncdRetsMgmtProcessStep.SupplierRetMatlAuthzn,
      AdvncdRetsMgmtProcessStep.SuplrRetMatlAuthznIsRequired,
      
      AdvncdRetsMgmtProcessStep.RetMatlInspResultCode,
      AdvncdRetsMgmtProcessStep.ProductIsInspectedAtCustSite,
      
      //Status

      Item.SDProcessStatus,
      Item.TotalDeliveryStatus,
      Item.DeliveryStatus,
      Item.DeliveryBlockStatus,
      Item.OrderRelatedBillingStatus,
      Item.BillingBlockStatus,
      Item.ItemGeneralIncompletionStatus,
      Item.ItemBillingIncompletionStatus,
      Item.PricingIncompletionStatus,
      Item.ItemDeliveryIncompletionStatus,
      Item.SDDocumentRejectionStatus,
      Item.TotalSDDocReferenceStatus,

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT,
                                     #TO_COMPOSITION_ROOT]
      _CustomerReturn,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      Item._ScheduleLine,
      Item._Partner,

      Item._ItemCategory,
      Item._CreatedByUser,
      Item._Division,

      Item._OriginallyRequestedMaterial,
      Item._ProductHierarchyNode,
      Item._AdditionalMaterialGroup1,
      Item._AdditionalMaterialGroup2,
      Item._AdditionalMaterialGroup3,
      Item._AdditionalMaterialGroup4,
      Item._AdditionalMaterialGroup5,
      Item._Plant,
      Item._StorageLocation,

      Item._OrderQuantityUnit,
      Item._BaseUnit,
      Item._RequestedQuantityUnit,
      Item._ItemWeightUnit,
      Item._ItemVolumeUnit,
      Item._SalesDistrict,
      Item._SalesDeal,
      Item._CustomerGroup,
      Item._SalesDocumentRjcnReason,
      
      Item._NetPriceQuantityUnit,
      Item._TransactionCurrency,
      Item._StatisticalValueControl,
      Item._ShippingPoint,
      Item._DeliveryPriority,
      Item._IncotermsClassification,
      Item._IncotermsVersion,
      Item._ItemBillingBlockReason,
      Item._ItemIsBillingRelevant,
      Item._CustomerPaymentTerms,
      // _PaymentMethod,

      Item._CustomerAccountAssgmtGroup,
      Item._BusinessArea,
      Item._WBSElementBasicData_2,

      Item._ReferenceSDDocument,
      Item._ReferenceSDDocumentItem,
      Item._ReferenceSDDocumentCategory,
      
      Item._ReturnReason,
      Item._ReturnsRefundExtent,
      AdvncdRetsMgmtProcessStep._ReturnsReferenceDocumentType,
      AdvncdRetsMgmtProcessItem._ReturnsRefundRjcnReason, 
      AdvncdRetsMgmtProcessItem._RetsMgmtItmLogProcgStatus,
      AdvncdRetsMgmtProcessItem._RetsMgmtItmCompnProcgStatus,
      AdvncdRetsMgmtProcessItem._RetsMgmtItmProcgStatus,      
      AdvncdRetsMgmtProcessStep._ReturnsRefundType,
      AdvncdRetsMgmtProcessStep._ReturnsRefundProcgMode,
      AdvncdRetsMgmtProcessStep._ReplacementMaterialQtyUnit,
      AdvncdRetsMgmtProcessStep._Supplier,
      AdvncdRetsMgmtProcessStep._Address,
      AdvncdRetsMgmtProcessStep._DfltAddrRprstn,
      AdvncdRetsMgmtProcessStep._RetMatlInspResultCode,

      Item._SDProcessStatus,
      Item._TotalDeliveryStatus,
      Item._DeliveryStatus,
      Item._DeliveryBlockStatus,
      Item._OrderRelatedBillingStatus,
      Item._BillingBlockStatus,
      Item._ItemGeneralIncompletionStatus,
      Item._ItemBillingIncompletionStatus,
      Item._PricingIncompletionStatus,
      Item._ItemDelivIncompletionSts,
      Item._SDDocumentRejectionStatus,
      Item._TotalSDDocReferenceStatus
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADVNCDRETURNSMGMTPROCESSITEM",
"I_ADVNCDRETURNSMGMTPROCESSSTEP",
"I_CUSTOMERRETURNITEM"
],
"ASSOCIATED":
[
"I_ADDITIONALMATERIALGROUP1",
"I_ADDITIONALMATERIALGROUP2",
"I_ADDITIONALMATERIALGROUP3",
"I_ADDITIONALMATERIALGROUP4",
"I_ADDITIONALMATERIALGROUP5",
"I_ADDRESS",
"I_ADDRESS_2",
"I_BILLINGBLOCKREASON",
"I_BILLINGBLOCKSTATUS",
"I_BILLINGRELEVANCECODE",
"I_BUSINESSAREA",
"I_CURRENCY",
"I_CUSTOMERACCOUNTASSGMTGROUP",
"I_CUSTOMERGROUP",
"I_CUSTOMERPAYMENTTERMS",
"I_CUSTOMERRETURNENHANCED",
"I_CUSTOMERRETURNSCHEDULELINE",
"I_DELIVERYBLOCKSTATUS",
"I_DELIVERYPRIORITY",
"I_DELIVERYSTATUS",
"I_DIVISION",
"I_INCOTERMSCLASSIFICATION",
"I_INCOTERMSVERSION",
"I_ITEMBILLINGINCOMPLETIONSTS",
"I_ITEMDELIVINCOMPLETIONSTS",
"I_ITEMGENINCOMPLETIONSTATUS",
"I_MATERIAL",
"I_MATERIALGROUP",
"I_ORDERRELATEDBILLINGSTATUS",
"I_PLANT",
"I_PRICINGINCOMPLETIONSTATUS",
"I_PRODUCT",
"I_PRODUCTGROUP_2",
"I_PRODUCTHIERARCHYNODE",
"I_RETMATLINSPRESULTCODE",
"I_RETSMGMTCOMPNPROCGSTATUS",
"I_RETSMGMTPROCGSTATUS",
"I_RETURNREASON",
"I_RETURNSDOCUMENTTYPE",
"I_RETURNSREFUNDEXTENT",
"I_RETURNSREFUNDPROCGMODEACTIVE",
"I_RETURNSREFUNDTYPE",
"I_SALESDEAL",
"I_SALESDISTRICT",
"I_SALESDOCUMENT",
"I_SALESDOCUMENTITEM",
"I_SALESDOCUMENTITEMCATEGORY",
"I_SALESDOCUMENTITEMPARTNER",
"I_SALESDOCUMENTRJCNREASON",
"I_SDDOCUMENTCATEGORY",
"I_SDDOCUMENTREJECTIONSTATUS",
"I_SDPROCESSSTATUS",
"I_SHIPPINGPOINT",
"I_STATISTICALVALUECONTROL",
"I_STORAGELOCATION",
"I_SUPPLIER",
"I_TOTALDELIVERYSTATUS",
"I_TOTALSDDOCREFERENCESTATUS",
"I_UNITOFMEASURE",
"I_USER",
"I_WBSELEMENTBASICDATA"
],
"BASE":
[
"I_ADVNCDRETURNSMGMTPROCESSITEM",
"I_ADVNCDRETURNSMGMTPROCESSSTEP",
"I_CUSTOMERRETURNITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/