R_CustomerReturnItemTP

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@ObjectModel: {
  semanticKey: ['CustomerReturn', 'CustomerReturnItem'],
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #L
  }
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@EndUserText.label: 'Returns Order Item - TP'
@Metadata.ignorePropagatedAnnotations: true
 
define view entity R_CustomerReturnItemTP 
  as select from I_CustomerReturnItemEnhanced          as CustomerReturnItem
  
  composition [0..*] of R_CustomerReturnItemPartnerTP  as _ItemPartner
  composition [0..*] of R_CustomerReturnItemTextTP     as _ItemText
  composition [0..*] of R_CustRetItemPricingElementTP  as _ItemPricingElement
  
  association [0..*] to I_CustomerReturnProcessStep    as _ReturnProcessStep           on  $projection.RetsMgmtProcessItem = CustomerReturnItem.CustomerReturnItem
                                                                                       and $projection.RetsMgmtProcess     = CustomerReturnItem.RetsMgmtProcess
  association [0..1] to I_WBSElementByExternalID       as _WBSElementExternalID        on $projection.WBSElementExternalID = _WBSElementExternalID.WBSElementExternalID
  association [0..1] to P_CustReturnSubsqntProcg       as _CustReturnSubsqntProcg       on  $projection.CustomerReturn     = _CustReturnSubsqntProcg.CustomerReturn
                                                                                       and $projection.CustomerReturnItem  = _CustReturnSubsqntProcg.CustomerReturnItem
                                             
  association to parent R_CustomerReturnTP             as _CustomerReturn              on $projection.CustomerReturn       = _CustomerReturn.CustomerReturn
  //Extension Association

  association [1]    to E_SalesDocumentItemBasic       as _Extension                   on  $projection.CustomerReturn      = _Extension.SalesDocument
                                                                                       and $projection.CustomerReturnItem  = _Extension.SalesDocumentItem
{
  key CustomerReturnItem.CustomerReturn,
  key CustomerReturnItem.CustomerReturnItem,
      
      CustomerReturnItem.HigherLevelItem,
      CustomerReturnItem.CustomerReturnItemCategory,
      @Semantics.text: true
      CustomerReturnItem.CustomerReturnItemText,
      
      CustomerReturnItem.PurchaseOrderByCustomer,
      CustomerReturnItem.Product,
      CustomerReturnItem.Material,
      CustomerReturnItem.MaterialByCustomer,
      
      @ObjectModel.foreignKey.association: '_ProductGroup'
      CustomerReturnItem.ProductGroup, 
      CustomerReturnItem.Batch,
      
      @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
      CustomerReturnItem.RequestedQuantity,
      CustomerReturnItem.RequestedQuantityUnit,

      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      CustomerReturnItem.ItemGrossWeight,
      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      CustomerReturnItem.ItemNetWeight,
      CustomerReturnItem.ItemWeightUnit,
      
      @Semantics.quantity.unitOfMeasure: 'ItemVolumeUnit'
      CustomerReturnItem.ItemVolume,
      CustomerReturnItem.ItemVolumeUnit,
      
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CustomerReturnItem.NetAmount,
      CustomerReturnItem.TransactionCurrency, 
      CustomerReturnItem.PricingDate,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CustomerReturnItem.TaxAmount,
      
      @ObjectModel.foreignKey.association: '_SDPricingProcedure'
      _CustomerReturn.SDPricingProcedure,
      
      CustomerReturnItem.Plant       as   ProductionPlant,
      CustomerReturnItem.StorageLocation,
      CustomerReturnItem.ShippingPoint,
      CustomerReturnItem.DeliveryPriority,
  
      @ObjectModel.foreignKey.association: '_SalesDocumentRjcnReason'
      CustomerReturnItem.SalesDocumentRjcnReason,
      CustomerReturnItem.ItemBillingBlockReason,
      CustomerReturnItem.ProfitCenter,
      CustomerReturnItem.WBSElementInternalID,
      @ObjectModel.foreignKey.association: '_WBSElementExternalID'
      CustomerReturnItem._WBSElementBasicData_2.WBSElementExternalID as WBSElementExternalID,

      
      CustomerReturnItem.IncotermsClassification,
      CustomerReturnItem.IncotermsTransferLocation,
      CustomerReturnItem.IncotermsLocation1,
      CustomerReturnItem.IncotermsLocation2,
      CustomerReturnItem.CustomerPaymentTerms,
      
      //ARM Fields

      CustomerReturnItem.RetsMgmtProcess,
      CustomerReturnItem.RetsMgmtProcessItem,
      CustomerReturnItem.ReturnReason,
      CustomerReturnItem.RetsMgmtProcessingBlock,
      CustomerReturnItem.CustRetItmFollowUpActivity,
      @Semantics.booleanIndicator:true
      CustomerReturnItem.ReturnsMaterialHasBeenReceived,
      cast ( '' as msr_cust_insp_comment )                          as CustRetItmCustomerText, 
      cast ( '' as msr_insp_comment )                               as CustRetItmInspectionText,         
      CustomerReturnItem.ReturnsRefundType,
//      CustomerReturnItem.ReturnsRefundProcgMode,

      cast(CustomerReturnItem.ReturnsRefundProcgMode as msr_refund_control preserving type) as ReturnsRefundProcgMode,
      @Semantics.booleanIndicator:true
      CustomerReturnItem.RetsProdValnIsSuspended,
      CustomerReturnItem.ReturnsRefundExtent,
      @Semantics.booleanIndicator:true
      CustomerReturnItem.PrelimRefundIsDetermined,
      CustomerReturnItem.ReturnsRefundRjcnReason,
      
      CustomerReturnItem.ReplacementMaterial,
      @Semantics.quantity.unitOfMeasure: 'ReplacementMaterialQtyUnit'
      CustomerReturnItem.ReplacementMaterialQuantity,
      CustomerReturnItem.ReplacementMaterialQtyUnit,
      @Semantics.booleanIndicator:true
      CustomerReturnItem.ReplacementMaterialIsRequested,
      CustomerReturnItem.ReplacementMatlSupplyingPlant,
      
      CustomerReturnItem.NextPlantForFollowUpActivity,
      CustomerReturnItem.ReturnsTransshipmentPlant,
      @ObjectModel.text.element: ['SupplierName']
      CustomerReturnItem.Supplier,
      @Semantics.text:true
      CustomerReturnItem._Supplier.SupplierName,
      CustomerReturnItem.SupplierRetMatlAuthzn,
      CustomerReturnItem.AddressID as ReturnToAddressID,
      @Semantics.booleanIndicator:true
      CustomerReturnItem.SuplrRetMatlAuthznIsRequired,
      CustomerReturnItem.CustomerRetMatlInspResultCode,
      CustomerReturnItem.NextFllwUpActivityForMatlInsp,
      CustomerReturnItem.RetMatlInspResultCode,
      @Semantics.booleanIndicator:true
      CustomerReturnItem.ProductIsInspectedAtCustSite,
      CustomerReturnItem.CustRetMatlAuthzn,
      CustomerReturnItem._SalesDocumentRjcnReason,
      
      CustomerReturnItem.CRMLogicalSystem,
      @Semantics.uuid
      CustomerReturnItem.CRMObjectUUID,
      CustomerReturnItem.CRMObjectID,
      CustomerReturnItem.CRMObjectType,
      
      CustomerReturnItem.RetsMgmtItmLogProcgStatus,
      CustomerReturnItem.RetsMgmtItmCompnProcgStatus,
      CustomerReturnItem.RetsMgmtItmProcgStatus,
      CustomerReturnItem.ReturnsDocumentStatus,
      CustomerReturnItem.ReturnsDocumentApprovalStatus,
      
      //Reference

      CustomerReturnItem.ReferenceSDDocument,
      CustomerReturnItem.ReferenceSDDocumentItem,
      CustomerReturnItem.ReferenceSDDocumentCategory,
      
      //Status

      CustomerReturnItem.SDProcessStatus,
      CustomerReturnItem.SDDocumentRejectionStatus, 
      
      cast( _CustReturnSubsqntProcg.CustRetReleaseStatus as cust_ret_rel_status preserving type ) as CustRetReleaseStatus,
      
      // For Access control

      @Consumption.hidden: true
      _CustomerReturn.CustomerReturnType,
      @Consumption.hidden: true
      _CustomerReturn.OrganizationDivision,
      @Consumption.hidden: true
      _CustomerReturn.SalesOrganization,
      @Consumption.hidden: true
      _CustomerReturn.DistributionChannel,      
      
      //Compositions

      _ItemPartner,
      _ItemText,
      _ItemPricingElement,
      _ReturnProcessStep,
      
      //Association

      _CustomerReturn._SDPricingProcedure,
      _CustomerReturn,
      CustomerReturnItem._ProductGroup,
      CustomerReturnItem._WBSElementBasicData_2,
      _WBSElementExternalID
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMERRETURNITEMENHANCED",
"I_SUPPLIER",
"I_WBSELEMENTBASICDATA",
"P_CUSTRETURNSUBSQNTPROCG",
"R_CUSTOMERRETURNTP"
],
"ASSOCIATED":
[
"I_CUSTOMERRETURNPROCESSSTEP",
"I_PRODUCTGROUP_2",
"I_SALESDOCUMENTRJCNREASON",
"I_SLSPRICINGPROCEDURE",
"I_WBSELEMENTBASICDATA",
"I_WBSELEMENTBYEXTERNALID",
"R_CUSTOMERRETURNITEMPARTNERTP",
"R_CUSTOMERRETURNITEMTEXTTP",
"R_CUSTOMERRETURNTP",
"R_CUSTRETITEMPRICINGELEMENTTP"
],
"BASE":
[
"I_CUSTOMERRETURNITEMENHANCED",
"R_CUSTOMERRETURNTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/