I_ADVNCDRETURNSMGMTPROCESSSTEP

@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Advanced Returns Management Process Step'

@VDM.viewType: #COMPOSITE
@Analytics.dataExtraction.enabled: false

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations: [ '_Address', '_DfltAddrRprstn' ]
}

@AbapCatalog: {
  sqlViewName: 'IARMPROCSTEP',
  preserveKey: true,
  compiler.compareFilter: true
}

@ObjectModel: {
  representativeKey: 'RetsMgmtProcessStep',
  usageType: {
    dataClass:      #MIXED,
    serviceQuality: #C,
    sizeCategory:   #L
  }
}

define view I_AdvncdReturnsMgmtProcessStep
  as select from           I_AdvncdRetsMgmtProcExecuted   as Executed
  
    left outer to one join I_AdvncdReturnsMgmtProcChain   as Chain       on Executed.CustRetItmChainID = Chain.CustRetItmChainID
    
    left outer join        I_AdvncdRetsMgmtProcNextPlants as NextPlants  on  Executed.RetsMgmtProcess         = NextPlants.RetsMgmtProcess
                                                                         and Executed.RetsMgmtProcessItem     = NextPlants.RetsMgmtProcessItem
                                                                         and Executed.RetsMgmtProcItmQtySplit = NextPlants.RetsMgmtProcItmQtySplit
                                                                         and Executed.RetsMgmtProcessStep     = NextPlants.RetsMgmtProcessStep

    left outer join        I_AdvncdRetsMgmtProcExecStatus as ProcgStatus on  Executed.RetsMgmtProcess                     = ProcgStatus.RetsMgmtProcess
                                                                         and Executed.RetsMgmtProcessItem                 = ProcgStatus.RetsMgmtProcessItem
                                                                         and Executed.RetsMgmtProcItmQtySplit             = ProcgStatus.RetsMgmtProcItmQtySplit
                                                                         and Executed.RetsMgmtProcessStep                 = ProcgStatus.RetsMgmtProcessStep
                                                                         and Executed.ReturnsDocumentStatus               = ''
                                                                         and ( ( ProcgStatus.ReturnsReferenceDocument     = Executed.ReturnsDocument
                                                                             and ProcgStatus.ReturnsReferenceDocumentItem = Executed.ReturnsDocumentItem )
                                                                             or ProcgStatus.ReturnsReferenceDocument      = ''
                                                                             )

{
      //Key

  key Executed.RetsMgmtProcess,
  key Executed.RetsMgmtProcessItem,

  key Executed.RetsMgmtProcItmQtySplit,
  key Executed.RetsMgmtProcessStep,

  key Executed.ReturnsDocumentType,
  key Executed.ReturnsDocument,
  key Executed.ReturnsDocumentItem,


      //Reference Document

      Executed.ReturnsReferenceDocumentType,
      Executed.ReturnsReferenceDocument,
      Executed.ReturnsReferenceDocumentItem,

      //Returns Document Status

      Executed.ReturnsDocumentStatus,
      Executed.ReturnsDocumentApprovalStatus,

      Executed.RetsMgmtProcItmExectdSequence,
      Executed.CustRetItmChainID,

      Chain.CustRetItmFollowUpActivity,
      Chain.ReturnsMaterialHasBeenReceived,

      NextPlants.NextPlantForFollowUpActivity,
      NextPlants.ReturnsTransshipmentPlant,

      //Refunding

      Executed.ReturnsRefundType,
      Executed.ReturnsRefundProcgMode,
      Executed.PrelimRefundIsDetermined,

      //Replacement

      Executed.ReplacementMaterial,
      Executed.ReplacementMaterialQuantity,
      Executed.ReplacementMaterialQtyUnit,
      Executed.ReplacementMaterialIsRequested,
      Executed.ReplacementMatlSupplyingPlant,

      Executed.Supplier,
      Executed.AddressID,
      Executed.SupplierRetMatlAuthzn,
      Executed.SuplrRetMatlAuthznIsRequired,

      //Inspection

      Executed.RetMatlInspResultCode,

      cast (case when Executed.ReturnsDocumentType = '00' and Executed.RetMatlInspResultCode <> ''
        then
          'X' --  ->'Product is inspected at customer site'
      // else

      // ''  --  ->'Product is not inspected at customer site'

       end as abap.char(1))        as ProductIsInspectedAtCustSite,

      //Processing Status

      cast ( case when  ProcgStatus.RetsMgmtProcessStep <> ''
        then
          case when ProcgStatus.RetsMgmtProcStepExecStatus = '2'
            then
              '2' -- ->'with errors'
            else
              '0' -- ->'open'
          end
        else
          '1' -- ->'complete'
      end as msr_exec_step_status) as RetsMgmtProcStepExecStatus,

      //Associations

      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]
      Executed._AdvncdRetsMgmtProcess,
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT]
      Executed._AdvncdRetsMgmtProcessItem,
      Executed._ReturnsReferenceDocumentType,
      Executed._ReturnsRefundType,
      Executed._ReturnsRefundProcgMode,
      Executed._ReplacementMaterialQtyUnit,
      Executed._Supplier,
      Executed._Address,
      Executed._DfltAddrRprstn,
      Executed._RetMatlInspResultCode
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADVNCDRETSMGMTPROCEXECSTATUS",
"I_ADVNCDRETSMGMTPROCEXECUTED",
"I_ADVNCDRETSMGMTPROCNEXTPLANTS",
"I_ADVNCDRETURNSMGMTPROCCHAIN"
],
"ASSOCIATED":
[
"I_ADDRESS",
"I_ADDRESS_2",
"I_ADVNCDRETURNSMGMTPROCESS",
"I_ADVNCDRETURNSMGMTPROCESSITEM",
"I_RETMATLINSPRESULTCODE",
"I_RETURNSDOCUMENTTYPE",
"I_RETURNSREFUNDPROCGMODEACTIVE",
"I_RETURNSREFUNDTYPE",
"I_SUPPLIER",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_ADVNCDRETSMGMTPROCEXECUTED"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/