C_CustomerReturnItmWrkflwInbox

@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Customer Return Item Workflow Inbox'
@AbapCatalog: {
  preserveKey: true,
  sqlViewName: 'CSDCUSRETITMWFIN',
  compiler.compareFilter: true
}
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel: {
   semanticKey: ['CustomerReturn', 'CustomerReturnItem'],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@VDM.viewType: #CONSUMPTION
@Metadata.ignorePropagatedAnnotations: true

define view C_CustomerReturnItmWrkflwInbox
as select from I_CustomerReturnItemEnhanced             as CustomerReturnItem
 
//Associations

association [1..1] to C_CustomerReturnWrkflwInbox       as _CustomerReturn                on  $projection.CustomerReturn = _CustomerReturn.CustomerReturn

//Text Associations

association [0..*] to I_FollowUpActivityText            as _FollowUpActivityText          on  $projection.CustRetItmFollowUpActivity = _FollowUpActivityText.CustRetItmFollowUpActivity

{
      @UI.hidden: true
  key CustomerReturn,
      @UI.lineItem: [{ position: 10, importance: #HIGH, label: 'Item' }]
      @UI.identification: { position: 10, importance: #HIGH, label: 'Item' }
      @ObjectModel.readOnly: true
  key CustomerReturnItem,

      @ObjectModel.text.element: [ 'ProductName' ]
      @UI.lineItem: [{ position: 20, importance: #HIGH, label: 'Product' }]
      @UI.identification: { position: 10, importance: #HIGH }
      @ObjectModel.readOnly: true
      Product,
      @Semantics.text: true
      _Product._Text[1: Language=$session.system_language ].ProductName as ProductName,
      
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      @UI.lineItem: [{ position: 30, importance: #HIGH, label: 'Order Quantity' }]
      @ObjectModel.readOnly: true
      OrderQuantity,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_OrderQuantityUnit'
      OrderQuantityUnit,
      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      @UI.lineItem: [{ position: 40, importance: #HIGH, label: 'Net Value' }]
      @ObjectModel.readOnly: true
      NetAmount,
      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      TransactionCurrency,
      
      ReturnReason,
      @UI: {
        lineItem: [{ position: 50, importance: #HIGH, label: 'Return Reason' }]
      }
      _ReturnReason._Text[1: Language=$session.system_language ].ReturnReasonName,
                  
      CustRetItmFollowUpActivity,
      @UI: {
        lineItem: [{ position: 51, importance: #HIGH, label: 'Follow-Up Activity' }]
      }
      _FollowUpActivityText[1: Language=$session.system_language ].CustRetItmFollowUpActivityDesc,
      
      ReturnsRefundType,
      @UI: {
        lineItem: [{ position: 52, importance: #HIGH, label: 'Refund Type' }]
      }
      _ReturnsRefundType._Text[1: Language=$session.system_language ].ReturnsRefundTypeName,

      ReturnsRefundExtent,
      @UI: {
        lineItem: [{ position: 53, importance: #HIGH, label: 'Refund Code' }]
      }
      _ReturnsRefundExtent._Text[1: Language=$session.system_language ].ReturnsRefundExtentDesc,
   
      ReturnsRefundProcgMode,
      @UI: {
          lineItem: [{ position: 54, importance: #HIGH, label: 'Refund Control' }],
          textArrangement: #TEXT_ONLY
        }
      _ReturnsRefundProcgMode.ReturnsRefundProcgModeDesc,
      
      //Associations

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT,
                                     #TO_COMPOSITION_ROOT]
      _CustomerReturn,
      _TransactionCurrency,
      _OrderQuantityUnit
}
where SalesDocumentRjcnReason = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMERRETURNITEMENHANCED",
"I_FOLLOWUPACTIVITYTEXT",
"I_PRODUCT",
"I_PRODUCTTEXT",
"I_RETURNREASON",
"I_RETURNREASONTEXT",
"I_RETURNSREFUNDEXTENT",
"I_RETURNSREFUNDEXTENTTEXT",
"I_RETURNSREFUNDPROCGMODEACTIVE",
"I_RETURNSREFUNDTYPE",
"I_RETURNSREFUNDTYPETEXT"
],
"ASSOCIATED":
[
"C_CUSTOMERRETURNWRKFLWINBOX",
"I_CURRENCY",
"I_FOLLOWUPACTIVITYTEXT",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_CUSTOMERRETURNITEMENHANCED"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/