I_ADVNCDRETURNSMGMTPROCESSITEM

CDS View

Advanced Returns Management Process Item

I_ADVNCDRETURNSMGMTPROCESSITEM is a CDS View in S/4HANA. Advanced Returns Management Process Item. It contains 17 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 17 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_CustomerReturnItemEnhanced view left_outer COMPOSITE Returns Order Item Enhanced

Fields (17)

KeyField CDS FieldsUsed in Views
_RetsMgmtItmCompnProcgStatus _RetsMgmtItmCompnProcgStatus 1
_RetsMgmtItmLogProcgStatus _RetsMgmtItmLogProcgStatus 1
_RetsMgmtItmProcgStatus _RetsMgmtItmProcgStatus 1
_ReturnsRefundRjcnReason _ReturnsRefundRjcnReason 1
CRMLogicalSystem CRMLogicalSystem 1
CRMObjectID CRMObjectID 1
CRMObjectType CRMObjectType 1
CRMObjectUUID CRMObjectUUID 1
CustomerRetMatlInspResultCode CustomerRetMatlInspResultCode 1
CustRetMatlAuthzn CustRetMatlAuthzn 1
NextFllwUpActivityForMatlInsp NextFllwUpActivityForMatlInsp 1
RetsMgmtItmCompnProcgStatus RetsMgmtItmCompnProcgStatus 1
RetsMgmtItmLogProcgStatus RetsMgmtItmLogProcgStatus 1
RetsMgmtItmProcgStatus RetsMgmtItmProcgStatus 1
RetsMgmtProcessItem RetsMgmtProcessItem 1
RetsProdValnIsSuspended RetsProdValnIsSuspended 1
ReturnsRefundRjcnReason ReturnsRefundRjcnReason 1 
@AbapCatalog.sqlViewName: 'IARMPROCESSITM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
@Analytics:{ dataExtraction.enabled:false }
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Advanced Returns Management Process Item'

@ObjectModel.representativeKey: 'RetsMgmtProcessItem'
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@VDM.viewType: #COMPOSITE

define view I_AdvncdReturnsMgmtProcessItem
  as select from           I_AdvncdRetsMgmtProcItemBasic as Item
    left outer to one join I_RetsMgmtProcItmWthProcgSts  as ItemProcessingStatus on  Item.RetsMgmtProcess     = ItemProcessingStatus.RetsMgmtProcess
                                                                                 and Item.RetsMgmtProcessItem = ItemProcessingStatus.RetsMgmtProcessItem


  association [1..1] to I_AdvncdReturnsMgmtProcess     as _AdvncdRetsMgmtProcess  on  $projection.RetsMgmtProcess = _AdvncdRetsMgmtProcess.RetsMgmtProcess

  association [0..*] to I_AdvncdReturnsMgmtProcessStep as _AdvncdRetsMgmtProcStep on  $projection.RetsMgmtProcess     = _AdvncdRetsMgmtProcStep.RetsMgmtProcess
                                                                                  and $projection.RetsMgmtProcessItem = _AdvncdRetsMgmtProcStep.RetsMgmtProcessItem

{
      //Key

      @ObjectModel.foreignKey.association: '_AdvncdRetsMgmtProcess'
  key Item.RetsMgmtProcess,
  key Item.RetsMgmtProcessItem,

      ReturnsRefundRjcnReason,
      CustRetMatlAuthzn,
      CustomerRetMatlInspResultCode,
      NextFllwUpActivityForMatlInsp,
      
      Item.RetsProdValnIsSuspended,
      
      //Status fields

      RetsMgmtItmLogProcgStatus,
      ItemProcessingStatus._RetsMgmtItmLogProcgStatus._Text[1: Language=$session.system_language].RetsMgmtProcessingStatusDesc          as RetsMgmtItmLogProcgStatusDesc,
      RetsMgmtItmCompnProcgStatus,
      ItemProcessingStatus._RetsMgmtItmCompnProcgStatus._Text[1: Language=$session.system_language].RetsMgmtCompnProcgStatusDesc        as RetsMgmtCompnProcgStatusDesc,
      RetsMgmtItmProcgStatus,
      ItemProcessingStatus._RetsMgmtItmProcgStatus._Text[1: Language=$session.system_language].RetsMgmtProcessingStatusDesc             as RetsMgmtProcessingStatusDesc,

      //CRM Reference

      CRMLogicalSystem,
      CRMObjectUUID,
      CRMObjectID,
      CRMObjectType,

      //Associations

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT,
                                      #TO_COMPOSITION_ROOT]
      _AdvncdRetsMgmtProcess,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _AdvncdRetsMgmtProcStep,
      _ReturnsRefundRjcnReason,
      _RetsMgmtItmLogProcgStatus,
      _RetsMgmtItmCompnProcgStatus,
      _RetsMgmtItmProcgStatus

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADVNCDRETSMGMTPROCITEMBASIC",
"I_RETSMGMTCOMPNPROCGSTATUS",
"I_RETSMGMTCOMPNPROCGSTATUSTEXT",
"I_RETSMGMTPROCGSTATUS",
"I_RETSMGMTPROCGSTATUSTEXT",
"I_RETSMGMTPROCITMWTHPROCGSTS"
],
"ASSOCIATED":
[
"I_ADVNCDRETURNSMGMTPROCESS",
"I_ADVNCDRETURNSMGMTPROCESSSTEP",
"I_RETSMGMTCOMPNPROCGSTATUS",
"I_RETSMGMTPROCGSTATUS",
"I_SALESDOCUMENTRJCNREASON"
],
"BASE":
[
"I_ADVNCDRETSMGMTPROCITEMBASIC",
"I_RETSMGMTPROCITMWTHPROCGSTS"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More