A_CustomerReturnItem

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Returns Order Item'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ACRITEM',
  compiler.compareFilter: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #D,
     sizeCategory:   #XL
   }
}
@Metadata.ignorePropagatedAnnotations: true
 
define view A_CustomerReturnItem
  as select from I_CustomerReturnItemEnhanced as Item


  association [1..1] to I_SalesDocumentBasic          as SalesDocumentBasic on  SalesDocumentBasic.SalesDocument = $projection.CustomerReturn

  association [1..1] to A_CustomerReturn              as _CustomerReturn    on  _CustomerReturn.CustomerReturn = $projection.CustomerReturn

  association [0..*] to A_CustomerReturnScheduleLine  as _ScheduleLine      on  _ScheduleLine.CustomerReturn     = $projection.CustomerReturn
                                                                            and _ScheduleLine.CustomerReturnItem = $projection.CustomerReturnItem

  association [0..*] to A_CustomerReturnSerialNumber  as _SerialNumber      on  _SerialNumber.CustomerReturn     = $projection.CustomerReturn
                                                                            and _SerialNumber.CustomerReturnItem = $projection.CustomerReturnItem

  association [0..*] to A_CustomerReturnItemPartner   as _Partner           on  _Partner.CustomerReturn     = $projection.CustomerReturn
                                                                            and _Partner.CustomerReturnItem = $projection.CustomerReturnItem
                                                                            
  association [0..*] to A_CustomerReturnItemText       as _Text             on  _Text.CustomerReturn     = $projection.CustomerReturn                                                                         
                                                                            and _Text.CustomerReturnItem = $projection.CustomerReturnItem

  association [0..*] to A_CustomerReturnItemRelatedObj as _RelatedObject    on  _RelatedObject.CustomerReturn     = $projection.CustomerReturn                                                                         
                                                                            and _RelatedObject.CustomerReturnItem = $projection.CustomerReturnItem

  association [0..*] to A_CustomerReturnItemPrcgElmnt as _PricingElement    on  _PricingElement.CustomerReturn     = $projection.CustomerReturn
                                                                            and _PricingElement.CustomerReturnItem = $projection.CustomerReturnItem

  association [0..*] to A_CustomerReturnProcessStep   as _ProcessStep       on  _ProcessStep.RetsMgmtProcess     = $projection.RetsMgmtProcess
                                                                            and _ProcessStep.RetsMgmtProcessItem = $projection.CustomerReturnItem

  // RFM enhancement : value-added services

  association [0..*] to A_CustomerReturnValAddedSrvc  as _ValueAddedService on  _ValueAddedService.CustomerReturn     = $projection.CustomerReturn
                                                                            and _ValueAddedService.CustomerReturnItem = $projection.CustomerReturnItem
  //Extensibility

  association [0..1] to E_SalesDocumentItemBasic      as _Extension         on  $projection.CustomerReturn     = _Extension.SalesDocument
                                                                            and $projection.CustomerReturnItem = _Extension.SalesDocumentItem


{
       @ObjectModel.readOnly: true
  key  CustomerReturn,

       @ObjectModel.text.element: 'CustomerReturnItemText'
  key  CustomerReturnItem,

       HigherLevelItem,

       CustomerReturnItemCategory,

       @Semantics.text: true
       CustomerReturnItemText,

       PurchaseOrderByCustomer,

       Material,

       MaterialByCustomer,

       @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
       RequestedQuantity,
       @Semantics.unitOfMeasure: true
       RequestedQuantityUnit,

       @ObjectModel.readOnly: true
       @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
       ItemGrossWeight,

       @ObjectModel.readOnly: true
       @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
       ItemNetWeight,

       @Semantics.unitOfMeasure: true
       @ObjectModel.readOnly: true
       ItemWeightUnit,

       @Semantics.quantity.unitOfMeasure: 'ItemVolumeUnit'
       @ObjectModel.readOnly: true
       ItemVolume,

       @Semantics.unitOfMeasure: true
       @ObjectModel.readOnly: true
       ItemVolumeUnit,

       @Semantics.currencyCode: true
       @ObjectModel.readOnly: true
       @ObjectModel.sapObjectNodeTypeReference: 'Currency'
       TransactionCurrency,

       @Semantics.amount.currencyCode: 'TransactionCurrency'
       @ObjectModel.readOnly: true
       NetAmount,

       MaterialGroup,
       @ObjectModel.readOnly: true
       Batch,
       @ObjectModel.sapObjectNodeTypeReference: 'Plant'
       Plant                                as ProductionPlant,
       @ObjectModel.sapObjectNodeTypeReference: 'StorageLocation'
       StorageLocation,
       @ObjectModel.sapObjectNodeTypeReference: 'ShippingPoint'
       ShippingPoint,
       ShippingType,
       DeliveryPriority,

       @ObjectModel.sapObjectNodeTypeReference: 'IncotermsClassification'
       IncotermsClassification,
       IncotermsTransferLocation,
       IncotermsLocation1,
       IncotermsLocation2,
       CustomerPaymentTerms,

      //Tax Classfication

       ProductTaxClassification1,
       ProductTaxClassification2,
       ProductTaxClassification3,
       ProductTaxClassification4,
       ProductTaxClassification5,
       ProductTaxClassification6,
       ProductTaxClassification7,
       ProductTaxClassification8,
       ProductTaxClassification9,
       
       @ObjectModel.sapObjectNodeTypeReference: 'SalesDocumentRjcnReason'
       SalesDocumentRjcnReason,
       @ObjectModel.sapObjectNodeTypeReference: 'BillingBlockReason'
       ItemBillingBlockReason,
       
       ProfitCenter,
       
       @ObjectModel.readOnly: true
       RetsMgmtProcess,
       @ObjectModel.readOnly: true
       RetsMgmtProcessItem,
       
       ReturnReason,
       RetsMgmtProcessingBlock,
       CustRetItmFollowUpActivity,
       ReturnsMaterialHasBeenReceived,

       ReturnsRefundType,
       ReturnsRefundProcgMode,
       cast (RetsProdValnIsSuspended as abap.char(1)) as RetsProdValnIsSuspended,
       
       ReturnsRefundExtent,
       PrelimRefundIsDetermined,
       @ObjectModel.readOnly: true
       
       ReturnsRefundRjcnReason,

       ReplacementMaterial,

       @Semantics.quantity.unitOfMeasure: 'ReplacementMaterialQtyUnit'
       ReplacementMaterialQuantity,
       @Semantics.unitOfMeasure: true
       ReplacementMaterialQtyUnit,

       ReplacementMaterialIsRequested,
       ReplacementMatlSupplyingPlant,

       NextPlantForFollowUpActivity,
       ReturnsTransshipmentPlant,
       Supplier,
       SupplierRetMatlAuthzn,
       @ObjectModel.readOnly: true
       SuplrRetMatlAuthznIsRequired,

       CustomerRetMatlInspResultCode,
       NextFllwUpActivityForMatlInsp,
       RetMatlInspResultCode,
       ProductIsInspectedAtCustSite,
       @ObjectModel.readOnly: true
       CustRetMatlAuthzn,

       @ObjectModel.readOnly: true
       CRMLogicalSystem,
       @ObjectModel.readOnly: true
       CRMObjectUUID,
       @ObjectModel.readOnly: true
       CRMObjectID,
       @ObjectModel.readOnly: true
       CRMObjectType,
       
       @ObjectModel.readOnly: true
       RetsMgmtItmLogProcgStatus,
       @ObjectModel.readOnly: true
       RetsMgmtItmCompnProcgStatus,
       @ObjectModel.readOnly: true
       RetsMgmtItmProcgStatus,

       @ObjectModel.readOnly: true
       ReturnsDocumentStatus,
       @ObjectModel.readOnly: true
       ReturnsDocumentApprovalStatus,

       @ObjectModel.readOnly: true
       @ObjectModel.sapObjectNodeTypeReference: 'SDProcessStatus'
       SDProcessStatus,

       ReferenceSDDocument,
       ReferenceSDDocumentItem,

       @ObjectModel.readOnly: true
       ReferenceSDDocumentCategory,
       @ObjectModel.readOnly: true
       @ObjectModel.sapObjectNodeTypeReference: 'SalesDocRejectionStatus'
       SDDocumentRejectionStatus,

       // For Access control

       @Consumption.hidden: true
       SalesDocumentBasic.SalesDocumentType as CustomerReturnType,
       @Consumption.hidden: true
       SalesDocumentBasic.OrganizationDivision,
       @Consumption.hidden: true
       SalesDocumentBasic.SalesOrganization,
       @Consumption.hidden: true
       SalesDocumentBasic.DistributionChannel,

       // Expose own associations

       _CustomerReturn,
       _ScheduleLine,
       _SerialNumber,
       _Partner,
       _Text,
       _RelatedObject,
       _PricingElement,
       _ProcessStep,

       // RFM enhancement : value-added services

       _ValueAddedService

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMERRETURNITEMENHANCED",
"I_SALESDOCUMENTBASIC"
],
"ASSOCIATED":
[
"A_CUSTOMERRETURN",
"A_CUSTOMERRETURNITEMPARTNER",
"A_CUSTOMERRETURNITEMPRCGELMNT",
"A_CUSTOMERRETURNITEMRELATEDOBJ",
"A_CUSTOMERRETURNITEMTEXT",
"A_CUSTOMERRETURNPROCESSSTEP",
"A_CUSTOMERRETURNSCHEDULELINE",
"A_CUSTOMERRETURNSERIALNUMBER",
"A_CUSTOMERRETURNVALADDEDSRVC",
"E_SALESDOCUMENTITEMBASIC",
"I_SALESDOCUMENTBASIC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/