I_PRICINGELEMENT

@AbapCatalog.sqlViewName: 'IPRICINGELEMENT'
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.semanticKey: ['PricingDocument', 'PricingDocumentItem', 'PricingProcedureStep', 'PricingProcedureCounter']
//@ObjectModel.representativeKey: ['PricingDocument', 'PricingDocumentItem', 'PricingProcedureStep', 'PricingProcedureCounter']

@EndUserText.label: 'Pricing Element'
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

define view I_PricingElement
  as select from prcd_elements

  association [0..1] to I_ConditionApplication         as _ConditionApplication         on  $projection.ConditionApplication = _ConditionApplication.ConditionApplication
  association [0..1] to I_PricingConditionType         as _PricingConditionType         on  $projection.ConditionApplication = _PricingConditionType.ConditionApplication
                                                                                        and $projection.ConditionType        = _PricingConditionType.ConditionType
  association [0..1] to I_ConditionCalculationType     as _ConditionCalculationType     on  $projection.ConditionCalculationType = _ConditionCalculationType.ConditionCalculationType
  association [0..1] to I_Currency                     as _ConditionCurrency            on  $projection.ConditionCurrency = _ConditionCurrency.Currency
  association [0..1] to I_Currency                     as _Currency                     on  $projection.TransactionCurrency = _Currency.Currency
  association [0..1] to I_UnitOfMeasure                as _ConditionQuantityUnit        on  $projection.ConditionQuantityUnit = _ConditionQuantityUnit.UnitOfMeasure
  association [0..1] to I_ConditionCategory            as _ConditionCategory            on  $projection.ConditionCategory = _ConditionCategory.ConditionCategory
  association [0..1] to I_ConditionOrigin              as _ConditionOrigin              on  $projection.ConditionOrigin = _ConditionOrigin.ConditionOrigin
  // These associations can not be established without further information, which is not available here

  // association [0..1] to I_GLAccountInChartOfAccounts as _GLAccountInChartOfAccounts on $projection.GLAccount = _GLAccountInChartOfAccounts.GLAccount

  // association [0..1] to I_TaxCode as _Taxcode on $projection.TaxCode = _Taxcode.TaxCode

  // association [0..1] to I_Extendedwhldgtaxcode as _ExtendedWhldgTaxCode on $projection.WithholdingTaxCode = _ExtendedWhldgTaxCode.WithholdingTaxCode

  association [0..1] to I_Supplier                     as _Supplier                     on  $projection.FreightSupplier = _Supplier.Supplier
  association [0..1] to I_ConditionControl             as _ConditionControl             on  $projection.ConditionControl = _ConditionControl.ConditionControl
  association [0..1] to I_ConditionInactiveReason      as _ConditionInactiveReason      on  $projection.ConditionInactiveReason = _ConditionInactiveReason.ConditionInactiveReason
  association [0..1] to I_ConditionClass               as _ConditionClass               on  $projection.ConditionClass = _ConditionClass.ConditionClass
  association [0..1] to I_PricingScaleBasis            as _PricingScaleBasis            on  $projection.PricingScaleBasis = _PricingScaleBasis.PricingScaleBasis
  association [0..1] to I_UnitOfMeasure                as _ScaleUnitOfMeasure           on  $projection.ConditionScaleBasisUnit = _ScaleUnitOfMeasure.UnitOfMeasure
  association [0..1] to I_Currency                     as _ScaleCurrency                on  $projection.ConditionScaleBasisCurrency = _ScaleCurrency.Currency
  association [0..1] to I_Currency                     as _ConditionAlternativeCurrency on  $projection.ConditionAlternativeCurrency = _ConditionAlternativeCurrency.Currency
  association [0..1] to I_BillingPriceSource           as _BillingPriceSource           on  $projection.BillingPriceSource = _BillingPriceSource.BillingPriceSource
  association [0..1] to I_VariantCondition             as _VariantCondition             on  $projection.VariantCondition = _VariantCondition.VariantCondition
  association [0..1] to I_StructureCondition           as _StructureCondition           on  $projection.StructureCondition = _StructureCondition.StructureCondition
  association [0..1] to I_ConditionAmountLimitExceeded as _ConditionAmountLimitExceeded on  $projection.ConditionAmountLimitExceeded = _ConditionAmountLimitExceeded.ConditionAmountLimitExceeded
  association [0..1] to I_ConditionBasisLimitExceeded  as _ConditionBasisLimitExceeded  on  $projection.ConditionBasisLimitExceeded = _ConditionBasisLimitExceeded.ConditionBasisLimitExceeded
  association [0..1] to I_Customer                     as _Customer                     on  $projection.CustomerRebateRecipient = _Customer.Customer
  association [0..1] to I_ConditionAcctAssgmtRelevance as _ConditionAcctAssgmtRelevance on  $projection.ConditionAcctAssgmtRelevance = _ConditionAcctAssgmtRelevance.ConditionAcctAssgmtRelevance
  association [0..1] to I_ConditionRateRatioUnit       as _ConditionRateRatioUnit       on  $projection.ConditionRateRatioUnit = _ConditionRateRatioUnit.ConditionRateRatioUnit

{
  key knumv                                           as PricingDocument,
  key kposn                                           as PricingDocumentItem,
  key stunr                                           as PricingProcedureStep,
  key zaehk                                           as PricingProcedureCounter,
      @ObjectModel.foreignKey.association: '_ConditionApplication'
      kappl                                           as ConditionApplication,
      @ObjectModel.foreignKey.association: '_PricingConditionType'
      kschl                                           as ConditionType,
      --@Semantics.dateTime:true
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'PriceConditionDeterminationDte'
      kdatu                                           as PricingDateTime,

      cast( left(kdatu, 8) as kdatu )                 as PriceConditionDeterminationDte,


      @ObjectModel.foreignKey.association: '_ConditionCalculationType'
      krech                                           as ConditionCalculationType,
      kawrt                                           as ConditionBaseValue,
      kbetr                                           as ConditionRateValue,
      @ObjectModel.foreignKey.association: '_ConditionCurrency'
      waers                                           as ConditionCurrency,
      kkurs                                           as PriceDetnExchangeRate,
      @DefaultAggregation:#NONE
      @Semantics.quantity.unitOfMeasure: 'ConditionQuantityUnit'
      kpein                                           as ConditionQuantity,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_ConditionQuantityUnit'
      kmein                                           as ConditionQuantityUnit,
      kumza                                           as ConditionToBaseQtyNmrtr,
      kumne                                           as ConditionToBaseQtyDnmntr,
      @ObjectModel.foreignKey.association: '_ConditionCategory'
      kntyp                                           as ConditionCategory,
      kstat                                           as ConditionIsForStatistics,
      knprs                                           as PricingScaleType,
      kruek                                           as IsRelevantForAccrual,
      kreli                                           as CndnIsRelevantForInvoiceList,
      @ObjectModel.foreignKey.association: '_ConditionOrigin'
      kherk                                           as ConditionOrigin,
      kgrpe                                           as IsGroupCondition,
      kolnr                                           as AccessNumberOfAccessSequence,
      knumh                                           as ConditionRecord,
      kopos                                           as ConditionSequentialNumber,
      //association to T687 not available -> CDS view is missing, causes an ATC issue

      kvsl1                                           as AccountKeyForGLAccount,
      sakn1                                           as GLAccount,
      mwsk1                                           as TaxCode,
      //association to T687 not available -> CDS view is missing

      kvsl2                                           as AcctKeyForAccrualsGLAccount,
      sakn2                                           as AccrualsGLAccount,
      mwsk2                                           as WithholdingTaxCode,
      @ObjectModel.foreignKey.association: '_Supplier'
      lifnr                                           as FreightSupplier,
      @DefaultAggregation:#NONE
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      kdiff                                           as CndnRoundingOffDiffAmount,
      @DefaultAggregation:#NONE
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      kwert                                           as ConditionAmount,
      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_Currency'
      waerk                                           as TransactionCurrency,
      @ObjectModel.foreignKey.association: '_ConditionControl'
      ksteu                                           as ConditionControl,
      @ObjectModel.foreignKey.association: '_ConditionInactiveReason'
      kinak                                           as ConditionInactiveReason,
      @ObjectModel.foreignKey.association: '_ConditionClass'
      koaid                                           as ConditionClass,
      zaeko                                           as PrcgProcedureCounterForHeader,
      kfaktor                                         as FactorForConditionBasisValue,
      @ObjectModel.foreignKey.association: '_StructureCondition'
      kdupl                                           as StructureCondition,
      kfaktor1                                        as PeriodFactorForCndnBasisValue,
      @ObjectModel.foreignKey.association: '_PricingScaleBasis'
      kzbzg                                           as PricingScaleBasis,
      kstbs                                           as ConditionScaleBasisValue,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_ScaleUnitOfMeasure'
      konms                                           as ConditionScaleBasisUnit,
      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_ScaleCurrency'
      konws                                           as ConditionScaleBasisCurrency,
      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_ConditionAlternativeCurrency'
      kwaeh                                           as ConditionAlternativeCurrency,
      @DefaultAggregation:#NONE
      @Semantics.amount.currencyCode: 'ConditionAlternativeCurrency'
      kwert_k                                         as ConditionAmountInLocalCrcy,
      kfkiv                                           as CndnIsRelevantForIntcoBilling,
      kmprs                                           as ConditionIsManuallyChanged,
      @ObjectModel.foreignKey.association: '_BillingPriceSource'
      prsqu                                           as BillingPriceSource,
      txjlv                                           as TaxJurisdictionLevel,
      kbflag                                          as ConditionByteSequence,
      koupd                                           as CndnIsRelevantForLimitValue,
      @ObjectModel.foreignKey.association: '_ConditionBasisLimitExceeded'
      kmxaw                                           as ConditionBasisLimitExceeded,
      @ObjectModel.foreignKey.association: '_ConditionAmountLimitExceeded'
      kmxwr                                           as ConditionAmountLimitExceeded,
      kawrt_k                                         as CumulatedConditionBasisValue,
      @ObjectModel.foreignKey.association: '_Customer'
      kunnr                                           as CustomerRebateRecipient,
      kvarc                                           as ConditionIsForConfiguration,
      varcond                                         as VariantCondition,
      @ObjectModel.foreignKey.association: '_ConditionAcctAssgmtRelevance'
      ktrel                                           as ConditionAcctAssgmtRelevance,
      mdflg                                           as ConditionMatrixMaintRelevance,
      // _dataaging

      cpf_guid                                        as ConfigblParametersAndFormulas,
      @Semantics.quantity.unitOfMeasure: 'ConditionQuantityUnit'
      kaqty                                           as ConditionAdjustedQuantity,
      val_zero                                        as CndnValueZeroProcgCode,
      is_acct_detn_relevant                           as CndnIsAcctDetnRelevant,
      tax_country                                     as TaxCountry,
      common_suppl_data                               as PriceConditionHasSuplmntyData,
      pricingsubprocedure                             as PricingSubProcedure,

      //ConditionRateAmount

      @Semantics.amount.currencyCode: 'ConditionCurrency'
      @OData.v2.amount.noDecimalShift: true
      cast( case
              when krech = 'A'
                or krech = 'H'
                or krech = 'I'
                or krech = 'J'
                or krech = 'K'
                or krech = 'V'
                or krech = 'W'
                or krech = 'U'
              then
                0 //fill the field with zero

              else
                kbetr
            end    as vfprc_rate_amount)              as ConditionRateAmount,

      //ConditionBaseAmount

      //All absolute or percentage calculation rules:  Base value is Amount

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      @OData.v2.amount.noDecimalShift: true
      cast( case
             when krech = 'A'
               or krech = 'B'
               or krech = 'H'
               or krech = 'I'
               or krech = 'J'
               or krech = 'K'
               or krech = 'W'
             then
                kawrt
             else
                0  //fill the field with zero

             end    as   vfprc_base_amount)           as ConditionBaseAmount,

      //ConditionBaseQuantity

      //All not absolute or percentage calculation rules:  Base value is Quantity

      @Semantics.quantity.unitOfMeasure: 'ConditionQuantityUnit'
      cast( case
                   when krech = 'A'
                     or krech = 'B'
                     or krech = 'H'
                     or krech = 'I'
                     or krech = 'J'
                     or krech = 'K'
                     or krech = 'W'
                   then
                     0   //fill the field with zero

                   else
                      kawrt
                   end     as vfprc_element_quantity) as ConditionBaseQuantity,


      //ConditionRateRatio

      // Calculation rule is Percentage-like: Fill ConditionRateRatio, otherwise fill it with zero

      @Semantics.quantity.unitOfMeasure: 'ConditionRateRatioUnit'
      cast( case
        when krech = 'A'
        or krech = 'H'
        or krech = 'W'
        or krech = 'I'
        or krech = 'K'
        or krech = 'J'
        or krech = 'V'
        or krech = 'U'
         then
          kbetr
        else
          0 //fill the field with zero

      end       as vfprc_element_ratio)               as ConditionRateRatio,

      // Calculation rule is Percentage-like: Fill ConditionRateRatioUnit, otherwise leave it empty

      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_ConditionRateRatioUnit'
      case
      when krech = 'A'
      or krech = 'H'
      or krech = 'W'
      or krech = 'I'
      or krech = 'V'
      or krech = 'U'
      then cast('%' as msehi) //Percentage

      when
      krech = 'K'
      or krech = 'J'
       then cast('%O' as msehi ) //Permille

       else cast('' as msehi )
      end                                             as ConditionRateRatioUnit,

      //ConditionScaleBaseAmount

      //All absolute scale base types: Value is Amount

      @Semantics.amount.currencyCode: 'ConditionScaleBasisCurrency'// konws

      @OData.v2.amount.noDecimalShift: true
      cast( case
              when kzbzg = 'B'
              then
                kstbs
              else
                0  //fill the field with zero

              end    as   vfprc_scale_base_amount)    as ConditionScaleBaseAmount,

      //ConditionScaleBaseQuantity

      //All not absolute scale base types:  Base value is Quantity

      @Semantics.quantity.unitOfMeasure: 'ConditionScaleBasisUnit' // konms

      cast( case
              when kzbzg = 'C'
                or kzbzg = 'D'
                or kzbzg = 'E'
                or kzbzg = 'F'
                or kzbzg = 'L'
                or kzbzg = 'M'
                or kzbzg = 'N'
                or kzbzg = 'O'
                or kzbzg = 'P'
                or kzbzg = 'R'
                or kzbzg = 'S'
                or kzbzg = 'T'
                or kzbzg = 'X'
              then
                kstbs
              else
                0   //fill the field with zero

              end     as vfprc_scale_base_quantity)   as ConditionScaleBaseQuantity,

      //associations in projection list

      _ConditionApplication,
      _PricingConditionType,
      _ConditionCalculationType,
      _ConditionCurrency,
      _Currency,
      _ConditionQuantityUnit,
      _ConditionCategory,
      _ConditionOrigin,
      // _GLAccountInChartOfAccounts,

      // _Taxcode,

      // _ExtendedWhldgTaxCode,

      _Supplier,
      _ConditionControl,
      _ConditionInactiveReason,
      _ConditionClass,
      _PricingScaleBasis,
      _ScaleUnitOfMeasure,
      _ScaleCurrency,
      _ConditionAlternativeCurrency,
      _BillingPriceSource,
      _VariantCondition,
      _StructureCondition,
      _ConditionAmountLimitExceeded,
      _ConditionBasisLimitExceeded,
      _Customer,
      _ConditionAcctAssgmtRelevance,
      _ConditionRateRatioUnit

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"PRCD_ELEMENTS"
],
"ASSOCIATED":
[
"I_BILLINGPRICESOURCE",
"I_CONDITIONACCTASSGMTRELEVANCE",
"I_CONDITIONAMOUNTLIMITEXCEEDED",
"I_CONDITIONAPPLICATION",
"I_CONDITIONBASISLIMITEXCEEDED",
"I_CONDITIONCALCULATIONTYPE",
"I_CONDITIONCATEGORY",
"I_CONDITIONCLASS",
"I_CONDITIONCONTROL",
"I_CONDITIONINACTIVEREASON",
"I_CONDITIONORIGIN",
"I_CONDITIONRATERATIOUNIT",
"I_CURRENCY",
"I_CUSTOMER",
"I_PRICINGCONDITIONTYPE",
"I_PRICINGSCALEBASIS",
"I_STRUCTURECONDITION",
"I_SUPPLIER",
"I_UNITOFMEASURE",
"I_VARIANTCONDITION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/