R_BusSolnOrdItmPriceElementTP

DDL: R_BUSSOLNORDITMPRICEELEMENTTP Type: view_entity TRANSACTIONAL

Business Solution Order Item Price Element - TP

R_BusSolnOrdItmPriceElementTP is a Transactional CDS View that provides data about "Business Solution Order Item Price Element - TP" in SAP S/4HANA. It reads from 2 data sources (I_PricingElement, I_ServiceDocumentEnhcd) and exposes 17 fields with key fields BusinessSolutionOrder, BusinessSolutionOrderItem, PricingProcedureStep, PricingProcedureCounter. It has 1 association to related views.

2 data source(s) 17 fields

Data Sources (2)

SourceAliasJoin Type
I_PricingElement _PricingElement from
I_ServiceDocumentEnhcd BusinessSolutionOrder inner

Associations (1)

CardinalityTargetAliasCondition
[1..1] R_BusinessSolutionOrderTP _BusinessSolutionOrder $projection.BusinessSolutionOrder = _BusinessSolutionOrder.BusinessSolutionOrder

Annotations (8)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
VDM.viewType #TRANSACTIONAL view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
EndUserText.label Business Solution Order Item Price Element - TP view

Fields (17)

KeyFieldSource TableSource FieldDescription
KEY BusinessSolutionOrder I_ServiceDocumentEnhcd ServiceDocument
KEY BusinessSolutionOrderItem
KEY PricingProcedureStep I_PricingElement PricingProcedureStep
KEY PricingProcedureCounter I_PricingElement PricingProcedureCounter
ConditionType I_PricingElement ConditionType
ConditionRateValue I_PricingElement ConditionRateValue
ConditionQuantity I_PricingElement ConditionQuantity
ConditionQuantityUnit I_PricingElement ConditionQuantityUnit
ConditionAmount I_PricingElement ConditionAmount
ConditionCurrency I_PricingElement ConditionCurrency
ConditionIsForStatistics I_PricingElement ConditionIsForStatistics
ConditionIsManuallyChanged I_PricingElement ConditionIsManuallyChanged
ConditionCalculationType I_PricingElement ConditionCalculationType
ConditionInactiveReason I_PricingElement ConditionInactiveReason
PricingDocument I_ServiceDocumentEnhcd PricingDocument
_BusinessSolutionOrder _BusinessSolutionOrder
_BusinessSolutionOrderItem _BusinessSolutionOrderItem 
@AbapCatalog.viewEnhancementCategory: [#NONE]

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: {
  usageType:{
    dataClass:      #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory:   #L
  }
}

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@EndUserText.label: 'Business Solution Order Item Price Element - TP'

define view entity R_BusSolnOrdItmPriceElementTP
  as select from I_PricingElement       as _PricingElement
    inner join   I_ServiceDocumentEnhcd as BusinessSolutionOrder on  BusinessSolutionOrder.PricingDocument   = _PricingElement.PricingDocument
                                                                 and BusinessSolutionOrder.ServiceObjectType = 'BUS2000172'

  association        to parent R_BusinessSolutionOrderItemTP as _BusinessSolutionOrderItem on  $projection.BusinessSolutionOrder     = _BusinessSolutionOrderItem.BusinessSolutionOrder
                                                                                           and $projection.BusinessSolutionOrderItem = _BusinessSolutionOrderItem.BusinessSolutionOrderItem

  association [1..1] to R_BusinessSolutionOrderTP            as _BusinessSolutionOrder     on  $projection.BusinessSolutionOrder = _BusinessSolutionOrder.BusinessSolutionOrder

{
       @ObjectModel.foreignKey.association: '_BusinessSolutionOrder'
  key  BusinessSolutionOrder.ServiceDocument                                          as BusinessSolutionOrder,

       @ObjectModel.foreignKey.association: '_BusinessSolutionOrderItem'
  key  cast( _PricingElement.PricingDocumentItem as crms4_number_int preserving type) as BusinessSolutionOrderItem,

  key  _PricingElement.PricingProcedureStep,
  key  _PricingElement.PricingProcedureCounter,
       _PricingElement.ConditionType,
       _PricingElement.ConditionRateValue,

       @Semantics.quantity.unitOfMeasure: 'ConditionQuantityUnit'
       _PricingElement.ConditionQuantity,
       _PricingElement.ConditionQuantityUnit,

       @Semantics.amount.currencyCode: 'ConditionCurrency'
       _PricingElement.ConditionAmount,
       _PricingElement.ConditionCurrency,

       _PricingElement.ConditionIsForStatistics,
       _PricingElement.ConditionIsManuallyChanged,
       _PricingElement.ConditionCalculationType,
       _PricingElement.ConditionInactiveReason,

       // Authorization

       BusinessSolutionOrder.PricingDocument,

       // Associations

       _BusinessSolutionOrder,
       _BusinessSolutionOrderItem
}
where
  _BusinessSolutionOrderItem.BusinessSolutionOrderItem = _PricingElement.PricingDocumentItem
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PRICINGELEMENT",
"I_SERVICEDOCUMENTENHCD",
"R_BUSINESSSOLUTIONORDERITEMTP"
],
"ASSOCIATED":
[
"R_BUSINESSSOLUTIONORDERITEMTP",
"R_BUSINESSSOLUTIONORDERTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More