@VDM: {
lifecycle.contract.type: #SAP_INTERNAL_API,
viewType: #TRANSACTIONAL
}
@AccessControl: {
authorizationCheck: #CHECK,
personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
semanticKey: ['CustomerReturn', 'CustomerReturnItem', 'PricingProcedureStep', 'PricingProcedureCounter'],
usageType: {
dataClass: #TRANSACTIONAL,
serviceQuality: #C,
sizeCategory: #XL
}
}
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Pricing Element for Returns Order Item - TP'
define view entity R_CustRetItemPricingElementTP
as select from I_PricingElement as PricingElement
inner join I_SalesDocumentBasic as CustomerReturn on CustomerReturn.SalesDocumentCondition = PricingElement.PricingDocument
and CustomerReturn.SDDocumentCategory = 'H'
association [1..1] to R_CustomerReturnTP as _CustomerReturn on $projection.CustomerReturn = _CustomerReturn.CustomerReturn
association to parent R_CustomerReturnItemTP as _Item on $projection.CustomerReturn = _Item.CustomerReturn
and $projection.CustomerReturnItem = _Item.CustomerReturnItem
{
key CustomerReturn.SalesDocument as CustomerReturn,
key PricingElement.PricingDocumentItem as CustomerReturnItem,
key PricingElement.PricingProcedureStep,
key PricingElement.PricingProcedureCounter,
@ObjectModel.foreignKey.association: '_ConditionApplication'
PricingElement.ConditionApplication,
@ObjectModel.foreignKey.association: '_PricingConditionType'
PricingElement.ConditionType,
// needed as condition type name is filled without any condition type key for subtotal lines
PricingElement._PricingConditionType._Text[1: Language=$session.system_language].ConditionTypeName as ConditionTypeName,
@ObjectModel.foreignKey.association: '_ConditionCalculationType'
PricingElement.ConditionCalculationType,
PricingElement.PriceConditionDeterminationDte,
@Semantics.amount.currencyCode: 'ConditionCurrency'
@OData.v2.amount.noDecimalShift: true
PricingElement.ConditionRateAmount,
@Semantics.quantity.unitOfMeasure: 'ConditionRateRatioUnit'
PricingElement.ConditionRateRatio,
@Semantics.amount.currencyCode: 'TransactionCurrency'
@OData.v2.amount.noDecimalShift: true
PricingElement.ConditionBaseAmount,
@Semantics.quantity.unitOfMeasure: 'ConditionQuantityUnit'
PricingElement.ConditionBaseQuantity,
@Semantics.quantity.unitOfMeasure: 'ConditionQuantityUnit'
PricingElement.ConditionQuantity,
@Semantics.amount.currencyCode: 'TransactionCurrency'
PricingElement.ConditionAmount,
@ObjectModel.foreignKey.association: '_ConditionCurrency'
PricingElement.ConditionCurrency,
@ObjectModel.foreignKey.association: '_TransactionCurrency'
PricingElement.TransactionCurrency,
@ObjectModel.foreignKey.association: '_ConditionQuantityUnit'
PricingElement.ConditionQuantityUnit,
PricingElement.ConditionRateRatioUnit,
PricingElement.ConditionIsForStatistics,
PricingElement.ConditionIsManuallyChanged,
@ObjectModel.foreignKey.association: '_ConditionInactiveReason'
PricingElement.ConditionInactiveReason,
@Semantics.booleanIndicator: true
cast(
case
when PricingElement.ConditionRateRatioUnit = ''
then 'X'
else ''
end as boole_d ) as ConditionRateValueIsAmount,
@Semantics.booleanIndicator: true
cast(
case
when PricingElement.ConditionRateRatioUnit = ''
then ''
else 'X'
end as boole_d ) as ConditionRateValueIsRatio,
@Semantics.booleanIndicator: true
cast(
case
when PricingElement.ConditionRateAmount is initial
and PricingElement.ConditionRateRatio is initial
then 'X'
else ''
end as boole_d ) as ConditionRateValueIsNull,
@Semantics.booleanIndicator: true
cast(
case
when PricingElement.ConditionQuantity is initial
then 'X'
else ''
end as boole_d ) as ConditionQuantityIsNull,
@Semantics.booleanIndicator: true
cast(
case
when PricingElement.ConditionAmount is initial
then 'X'
else ''
end as boole_d ) as ConditionAmountIsNull,
@Semantics.booleanIndicator: true
cast(
case
when PricingElement.ConditionCalculationType = 'A'
or PricingElement.ConditionCalculationType = 'B'
or PricingElement.ConditionCalculationType = 'H'
or PricingElement.ConditionCalculationType = 'I'
or PricingElement.ConditionCalculationType = 'J'
or PricingElement.ConditionCalculationType = 'K'
or PricingElement.ConditionCalculationType = 'W'
then ''
else 'X'
end as boole_d ) as ConditionBaseValueIsQuantity,
@Semantics.booleanIndicator: true
cast(
case
when PricingElement.ConditionCalculationType = 'A'
or PricingElement.ConditionCalculationType = 'B'
or PricingElement.ConditionCalculationType = 'H'
or PricingElement.ConditionCalculationType = 'I'
or PricingElement.ConditionCalculationType = 'J'
or PricingElement.ConditionCalculationType = 'K'
or PricingElement.ConditionCalculationType = 'W'
then 'X'
else ''
end as boole_d ) as ConditionBaseValueIsAmount,
//For Access Control
@Consumption.hidden: true
_CustomerReturn.CustomerReturnType,
@Consumption.hidden: true
_CustomerReturn.SalesOrganization,
@Consumption.hidden: true
_CustomerReturn.DistributionChannel,
@Consumption.hidden: true
_CustomerReturn.OrganizationDivision,
//Associations
_Item,
_CustomerReturn,
PricingElement._ConditionApplication,
PricingElement._PricingConditionType,
PricingElement._ConditionCurrency,
PricingElement._Currency as _TransactionCurrency,
PricingElement._ConditionQuantityUnit,
PricingElement._ConditionInactiveReason,
PricingElement._ConditionCalculationType
}
where
PricingElement.PricingDocumentItem != '000000' //Ignore Header Conditions
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CONDITIONTYPETEXT",
"I_PRICINGCONDITIONTYPE",
"I_PRICINGELEMENT",
"I_SALESDOCUMENTBASIC",
"R_CUSTOMERRETURNTP"
],
"ASSOCIATED":
[
"I_CONDITIONAPPLICATION",
"I_CONDITIONCALCULATIONTYPE",
"I_CONDITIONINACTIVEREASON",
"I_CURRENCY",
"I_PRICINGCONDITIONTYPE",
"I_UNITOFMEASURE",
"R_CUSTOMERRETURNITEMTP",
"R_CUSTOMERRETURNTP"
],
"BASE":
[
"I_PRICINGELEMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/