A_BusSolnOrderItemPriceElement

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Item Price Element'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ABSOITMPRCELMNT',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #C,
     sizeCategory:   #XXL
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_BusSolnOrderItemPriceElement
  as select from I_PricingElement               as  PricingElement
  inner join     I_ServiceDocumentEnhcd         as  BusinessSolutionOrder on  BusinessSolutionOrder.PricingDocument   = PricingElement.PricingDocument
                                                                          and BusinessSolutionOrder.ServiceObjectType = 'BUS2000172'
  association [1..1] to A_BusinessSolutionOrder as _BusinessSolutionOrder on $projection.BusinessSolutionOrder        = _BusinessSolutionOrder.BusinessSolutionOrder
  association [0..1] to I_UnitOfMeasure         as _ConditionQuantityUnit on $projection.ConditionQuantityUnit = _ConditionQuantityUnit.UnitOfMeasure
{       

  key BusinessSolutionOrder.ServiceDocument        as BusinessSolutionOrder,
  key PricingDocumentItem                          as BusinessSolutionOrderItem,
  key PricingProcedureStep,
  key PricingProcedureCounter,

      ConditionType,
      ConditionRateValue,
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      ConditionCurrency,
      @Semantics.quantity.unitOfMeasure: 'ConditionQuantityUnit'
      ConditionQuantity,
      @Semantics.unitOfMeasure: true
      ConditionQuantityUnit,
      cast(_ConditionQuantityUnit.UnitOfMeasureSAPCode as sd_ord_qty_sapunit preserving type) as ConditionQuantitySAPUnit,
      cast(_ConditionQuantityUnit.UnitOfMeasureISOCode as sd_ord_qty_isounit preserving type) as ConditionQuantityISOUnit,
        
      _BusinessSolutionOrder
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PRICINGELEMENT",
"I_SERVICEDOCUMENTENHCD",
"I_UNITOFMEASURE"
],
"ASSOCIATED":
[
"A_BUSINESSSOLUTIONORDER",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/