A_SalesOrderItemPrElement

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Item Pricing Element'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASOIPRELEMENT',
  compiler.compareFilter: true
}
@AccessControl: { 
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #XXL
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_SalesOrderItemPrElement
  as select from I_PricingElement     as PricingElement
    inner join   I_SalesDocumentBasic as SalesOrder on  SalesDocumentCondition = PricingElement.PricingDocument
                                                    and SDDocumentCategory     = 'C'
  association [1..1] to A_SalesOrder     as _SalesOrder     on  $projection.SalesOrder = _SalesOrder.SalesOrder
  association [1..1] to A_SalesOrderItem as _SalesOrderItem on  $projection.SalesOrder     = _SalesOrderItem.SalesOrder
                                                            and $projection.SalesOrderItem = _SalesOrderItem.SalesOrderItem
{
      @ObjectModel.readOnly: true
  key cast(SalesOrder.SalesDocument as vdm_sales_order preserving type) as SalesOrder,

      @ObjectModel.readOnly: true
  key cast(PricingDocumentItem as sales_order_item preserving type)     as SalesOrderItem,

  key PricingProcedureStep,
  key PricingProcedureCounter,

      ConditionType,

      @ObjectModel.readOnly: true
      PricingDateTime,
      
      @ObjectModel.readOnly: true
      PriceConditionDeterminationDte,

      @ObjectModel.readOnly: true
      ConditionCalculationType,

      @ObjectModel.readOnly: true
      ConditionBaseValue,

      ConditionRateValue,

      ConditionCurrency,

      //PriceDetnExchangeRate,


      @Semantics.quantity.unitOfMeasure: 'ConditionQuantityUnit'
      @Semantics.quantity.unitOfMeasureSAPCode: 'ConditionQuantitySAPUnit' 
      @Semantics.quantity.unitOfMeasureISOCode: 'ConditionQuantityISOUnit'
      ConditionQuantity,

      @Semantics.unitOfMeasure: true
      ConditionQuantityUnit,
      cast(_ConditionQuantityUnit.UnitOfMeasureSAPCode as sd_cndn_qty_sapunit preserving type) as ConditionQuantitySAPUnit,
      cast(_ConditionQuantityUnit.UnitOfMeasureISOCode as sd_cndn_qty_isounit preserving type) as ConditionQuantityISOUnit,

      @ObjectModel.readOnly: true
      ConditionCategory,

      @ObjectModel.readOnly: true
      ConditionIsForStatistics,

      @ObjectModel.readOnly: true
      PricingScaleType,

      @ObjectModel.readOnly: true
      IsRelevantForAccrual,

      @ObjectModel.readOnly: true
      CndnIsRelevantForInvoiceList,

      @ObjectModel.readOnly: true
      ConditionOrigin,

      @ObjectModel.readOnly: true
      IsGroupCondition,

      @ObjectModel.readOnly: true
      ConditionRecord,

      @ObjectModel.readOnly: true
      ConditionSequentialNumber,

      @ObjectModel.readOnly: true
      TaxCode,

      @ObjectModel.readOnly: true
      WithholdingTaxCode,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      @ObjectModel.readOnly: true
      CndnRoundingOffDiffAmount,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      @ObjectModel.readOnly: true
      ConditionAmount,

      @Semantics.currencyCode: true
      PricingElement.TransactionCurrency,

      @ObjectModel.readOnly: true
      ConditionControl,

      @ObjectModel.readOnly: true
      ConditionInactiveReason,

      @ObjectModel.readOnly: true
      ConditionClass,

      @ObjectModel.readOnly: true
      PrcgProcedureCounterForHeader,

      @ObjectModel.readOnly: true
      FactorForConditionBasisValue,

      @ObjectModel.readOnly: true
      StructureCondition,

      @ObjectModel.readOnly: true
      PeriodFactorForCndnBasisValue,

      @ObjectModel.readOnly: true
      PricingScaleBasis,

      @ObjectModel.readOnly: true
      ConditionScaleBasisValue,

      @ObjectModel.readOnly: true
      @Semantics.unitOfMeasure: true
      ConditionScaleBasisUnit,

      @ObjectModel.readOnly: true
      @Semantics.currencyCode: true
      ConditionScaleBasisCurrency,

      @ObjectModel.readOnly: true
      CndnIsRelevantForIntcoBilling,

      @ObjectModel.readOnly: true
      ConditionIsManuallyChanged,

      @ObjectModel.readOnly: true
      ConditionIsForConfiguration,

      @ObjectModel.readOnly: true
      VariantCondition,

      // For Access control

      @Consumption.hidden: true
      SalesOrder.SalesDocumentType                                      as SalesOrderType,
      @Consumption.hidden: true
      SalesOrder.OrganizationDivision,
      @Consumption.hidden: true
      SalesOrder.SalesOrganization,
      @Consumption.hidden: true
      SalesOrder.DistributionChannel,

      //Expose associations

      _SalesOrder,
      _SalesOrderItem
}
where
  PricingDocumentItem != '000000' //Ignore Header conditions 

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PRICINGELEMENT",
"I_SALESDOCUMENTBASIC",
"I_UNITOFMEASURE"
],
"ASSOCIATED":
[
"A_SALESORDER",
"A_SALESORDERITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/