C_SalesDocWithCustExpdPrice

@AbapCatalog.sqlViewName: 'CSDOCWCUSTEXPPRC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl: {
  authorizationCheck: #CHECK,
  privilegedAssociations: [ '_PricingElement' ]
}
@EndUserText.label: 'Sales Doc. w. Customer-Expected Price'

@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type:#CLIENT_DEPENDENT
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL

@Search.searchable: true
@ObjectModel.updateEnabled

@ObjectModel.semanticKey:  [ 'SalesDocument', 'SalesDocumentItem' ]

@UI.headerInfo: {
  typeName:         'Sales Document',
  typeNamePlural:   'Sales Documents',
  title: {
    type:   #STANDARD,
    value:  'SalesDocumentItem'
  }
}

@Metadata.allowExtensions: true

define view
C_SalesDocWithCustExpdPrice
as select from
I_SalesDocumentItem as SalesDocumentItem

inner join P_CustExpPriceIncompletionLog as _CustExpPriceIncompletionLog on SalesDocumentItem.SalesDocument = _CustExpPriceIncompletionLog.SDDocument
and SalesDocumentItem.SalesDocumentItem = _CustExpPriceIncompletionLog.SDDocumentItem

  inner join I_PricingElement as _Condition on SalesDocumentItem.SalesDocumentCondition = _Condition.PricingDocument
  and SalesDocumentItem.SalesDocumentItem = _Condition.PricingDocumentItem
  and _Condition.ConditionCategory = 'J'

association [0..*] to C_SalesDocumentContactPerson as _ContactPerson           on  $projection.SalesDocument = _ContactPerson.SalesDocument

association [0..1] to I_SalesDocument              as _SalesDocument           on  $projection.SalesDocument = _SalesDocument.SalesDocument

association [0..1] to C_SoldToValueHelp            as _SoldToParty             on  $projection.soldtoparty = _SoldToParty.Customer

association [0..1] to C_Dischannelvaluehelp        as _DistributionChannel     on  $projection.salesorganization   = _DistributionChannel.SalesOrganization
                                                                               and $projection.distributionchannel = _DistributionChannel.DistributionChannel

association [0..1] to C_OrgDivisionValueHelp       as _OrganizationDivision    on  $projection.salesorganization    = _OrganizationDivision.SalesOrganization
                                                                               and $projection.distributionchannel  = _OrganizationDivision.DistributionChannel
                                                                               and $projection.organizationdivision = _OrganizationDivision.Division
association [0..1] to C_Incompl_SalesDocCatVH      as _SalesDocumentCategory   on  $projection.sddocumentcategory = _SalesDocumentCategory.SDDocumentCategory
association [0..1] to C_SalesOfficeValueHelp       as _SalesOffice             on  $projection.salesorganization    = _SalesOffice.SalesOrganization
                                                                               and $projection.distributionchannel  = _SalesOffice.DistributionChannel
                                                                               and $projection.organizationdivision = _SalesOffice.OrganizationDivision
                                                                               and $projection.salesoffice          = _SalesOffice.SalesOffice

association [0..1] to C_Incompl_SalesDocTypeVH     as _SalesDocumentType       on  $projection.sddocumentcategory = _SalesDocumentType.SDDocumentCategory
                                                                               and $projection.salesdocumenttype  = _SalesDocumentType.SalesDocumentType
association [0..1] to C_SalesGroupValueHelp        as _SalesGroup              on  $projection.salesoffice = _SalesGroup.SalesOffice
                                                                               and $projection.salesgroup  = _SalesGroup.SalesGroup

association [0..1] to C_SalesDocumentUserVH        as _CreatedByUser           on  $projection.createdbyuser = _CreatedByUser.UserID
association [0..1] to I_Currency                   as _ConditionCurrency       on  $projection.ConditionCurrency = _ConditionCurrency.Currency

association [0..1] to I_UnitOfMeasure              as _ConditionQuantityUnit   on  $projection.ConditionQuantityUnit = _ConditionQuantityUnit.UnitOfMeasure

association [0..1] to I_Currency                   as _TransactionCurrency     on  $projection.TransactionCurrency = _TransactionCurrency.Currency

association [0..1] to I_UnitOfMeasure              as _TargetQuantityUnit      on  $projection.TargetQuantityUnit = _TargetQuantityUnit.UnitOfMeasure

association [0..1] to I_UnitOfMeasure              as _OrderQuantityUnit       on  $projection.OrderQuantityUnit = _OrderQuantityUnit.UnitOfMeasure
association [0..1] to I_ConditionApplication       as _ConditionApplication    on  $projection.ConditionApplication = _ConditionApplication.ConditionApplication

association [0..1] to I_PricingConditionType       as _PricingConditionType    on  $projection.ConditionApplication = _PricingConditionType.ConditionApplication
                                                                               and $projection.ConditionType        = _PricingConditionType.ConditionType

association [0..1] to C_PricingConditionType_VH    as _PricingConditionTypeVH  on  $projection.ConditionType        = _PricingConditionTypeVH.ConditionType
                                                                               and $projection.ConditionApplication = _PricingConditionTypeVH.ConditionApplication

association [0..1] to I_ConditionCategory          as _ConditionCategory       on  $projection.ConditionCategory = _ConditionCategory.ConditionCategory
association [0..1] to I_SalesDocumentRjcnReason    as _SalesDocumentRjcnReason on  $projection.SalesDocumentRjcnReason = _SalesDocumentRjcnReason.SalesDocumentRjcnReason


association [0..*] to C_CustExpdPriceCondition     as _PricingElement          on  $projection.SalesDocumentCondition = _PricingElement.PricingDocument
                                                                               and $projection.SalesDocumentItem      = _PricingElement.PricingDocumentItem


{
                  @Search.defaultSearchElement: true
                  @Search.fuzzinessThreshold: 0.9
                  @Search.ranking: #HIGH
                  @ObjectModel.readOnly: true
                  @UI: {lineItem: [ { position: 10, importance: #HIGH } ]}
                  @ObjectModel.foreignKey.association: null
  key             SalesDocumentItem.SalesDocument                                            as SalesDocument,


                  @UI: {lineItem: [ { position: 11, importance: #HIGH } ]}
  key             cast(SalesDocumentItem.SalesDocumentItem as posnr preserving type)         as SalesDocumentItem,

                  @UI.hidden: true
  key             _Condition.PricingDocument,

                  @UI.hidden: true
  key             _Condition.PricingDocumentItem,

                  @UI.hidden: true
  key             _Condition.PricingProcedureStep,

                  @UI.hidden: true
  key             _Condition.PricingProcedureCounter,


                  @Search.defaultSearchElement: true
                  @Search.fuzzinessThreshold: 0.8
                  @Consumption.filter.hidden: true
                  _SalesDocument.PurchaseOrderByCustomer,

                  @Consumption.valueHelpDefinition: [{entity:{name:'C_SalesDocSalesOrganizationVH', element:'SalesOrganization'} }]
                  @UI: {selectionField: [ { position: 10 } ]}
                  _SalesDocument.SalesOrganization,

                  @Consumption.valueHelp: '_DistributionChannel'
                  @UI: {selectionField: [ { position: 20 } ]}
                  _SalesDocument.DistributionChannel,

                  @Consumption.valueHelp: '_OrganizationDivision'
                  _SalesDocument.OrganizationDivision,

                  @Consumption.valueHelp: '_SalesOffice'
                  _SalesDocument.SalesOffice,

                  @Consumption.valueHelp: '_SalesGroup'
                  _SalesDocument.SalesGroup,

                  @Search.defaultSearchElement: true
                  @Search.fuzzinessThreshold: 0.8
                  @Consumption.valueHelp: '_SalesDocumentType'
                  @ObjectModel.foreignKey.association: '_SalesDocumentType'
                  @Consumption.filter.hidden: true
                  _SalesDocument.SalesDocumentType,

                  @Search.defaultSearchElement: true
                  @Search.fuzzinessThreshold: 0.8
                  @Consumption.valueHelp: '_SalesDocumentCategory'
                  @ObjectModel.foreignKey.association: '_SalesDocumentCategory'
                  @Consumption.filter.hidden: true
                  _SalesDocument.SDDocumentCategory,

                  @Consumption.semanticObject: 'Customer'
                  @Consumption.valueHelpDefinition: [{association: '_SoldToParty'}]
                  @Search.defaultSearchElement: true
                  @Search.fuzzinessThreshold: 0.8
                  @ObjectModel.foreignKey.association: '_SoldToParty'
                  @UI: {selectionField.position: 30, lineItem: [ { position: 20 } ]}
                  _SalesDocument.SoldToParty,

                  @Consumption.semanticObject: 'Material'
                  @Search.defaultSearchElement: true
                  @Search.fuzzinessThreshold: 0.8
                  //SDF4

                  @Consumption.valueHelpDefinition: [{ entity: { name: 'I_ProductStdVH', element: 'Product' }}]
                  @ObjectModel.text.element: [ 'MaterialName' ]
                  @UI: {selectionField.position: 40, lineItem: [ { position: 30 } ]}
                  cast(SalesDocumentItem.Material as productnumber preserving type )         as Material,
                  @UI.hidden: true
                  SalesDocumentItem._MaterialText[1:Language=$session.system_language].MaterialName,

                  @UI.hidden: true
                  SalesDocumentItem.SalesDocumentCondition,

                  @Consumption.semanticObject: 'UserID'
                  @Consumption.valueHelp: '_CreatedByUser'
                  @Search.defaultSearchElement: true
                  @Search.fuzzinessThreshold: 0.9
                  @ObjectModel.foreignKey.association: '_CreatedByUser'
                  _SalesDocument.CreatedByUser,

                  @Semantics.businessDate.to: true
                  _SalesDocument.CreationDate,

                  @DefaultAggregation:#NONE
                  @Semantics.amount.currencyCode: 'TransactionCurrency'
                  @UI: {lineItem: [ { position: 95 } ]}
                  SalesDocumentItem.NetAmount,

                  @Semantics.currencyCode: true
                  @ObjectModel.foreignKey.association: '_TransactionCurrency'
                  @UI.hidden: true
                  SalesDocumentItem.TransactionCurrency,

                  @UI.hidden: true
                  @DefaultAggregation: #NONE
                  @Semantics.quantity.unitOfMeasure: 'TargetQuantityUnit'
                  SalesDocumentItem.TargetQuantity,

                  @UI.hidden: true
                  @Semantics.unitOfMeasure: true
                  @ObjectModel.foreignKey.association: '_TargetQuantityUnit'
                  SalesDocumentItem.TargetQuantityUnit,

                  @UI: {lineItem: [ { position: 70 } ]}
                  @Semantics.amount.currencyCode: 'TransactionCurrency'
                  @Consumption.filter.hidden: true
                  SalesDocumentItem.NetPriceAmount,

                  @UI: {lineItem: [ { position: 80 } ]}
                  @DefaultAggregation: #NONE
                  @Semantics.quantity.unitOfMeasure: 'NetPriceQuantityUnit'
                  @Consumption.filter.hidden: true
                  cast(SalesDocumentItem.NetPriceQuantity as net_price_unit preserving type) as NetPriceQuantity,

                  @Semantics.unitOfMeasure: true
                  @ObjectModel.foreignKey.association: '_NetPriceQuantityUnit'
                  @Consumption.filter.hidden: true
                  SalesDocumentItem.NetPriceQuantityUnit,

                  @DefaultAggregation:#NONE
                  @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
                  @UI: {lineItem: [ { position: 90 } ]}
                  @Consumption.filter.hidden: true
                  SalesDocumentItem.OrderQuantity,

                  @Semantics.unitOfMeasure: true
                  @ObjectModel.foreignKey.association: '_OrderQuantityUnit'
                  @UI.hidden: true
                  SalesDocumentItem.OrderQuantityUnit,

                  @ObjectModel.foreignKey.association: '_SalesDocumentRjcnReason'
                  @Consumption.filter.hidden: true
                  SalesDocumentItem.SalesDocumentRjcnReason,

                  ------ Item Condtions-----------
                  @UI.hidden: true
                  @ObjectModel.foreignKey.association: '_ConditionCategory'
                  _Condition.ConditionCategory,

                  @ObjectModel.foreignKey.association: '_ConditionCurrency'
                  @UI.hidden: true
                  _Condition.ConditionCurrency,

                  @DefaultAggregation: #NONE
                  @Search.fuzzinessThreshold: 0.9
                  @Consumption.filter.hidden: true
                  @Semantics.amount.currencyCode: 'ConditionCurrency'
                  @UI: {lineItem: [ { position: 40, importance: #HIGH } ]}
                  @OData.v2.amount.noDecimalShift: true
                  case
                      when
                      _Condition.ConditionCalculationType = 'C'
                      then
                       cast( _Condition.ConditionRateAmount as customer_exp_price )
                      end

                                                                                             as CustomerExpectedPrice,
                  @DefaultAggregation: #NONE
                  @Search.fuzzinessThreshold: 0.9
                  @Consumption.filter.hidden: true
                  @Semantics.amount.currencyCode: 'ConditionCurrency'
                  @UI: {lineItem: [ { position: 50 } ]}
                  @OData.v2.amount.noDecimalShift: true
                  case
                       when
                       _Condition.ConditionCalculationType = 'B'
                       then
                       cast( _Condition.ConditionRateAmount as customer_exp_value )
                       end                                                                   as CustomerExpectedValue,

                  @UI: {lineItem: [ { position: 60 } ]}
                  @DefaultAggregation:#NONE
                  @Semantics.quantity.unitOfMeasure: 'ConditionQuantityUnit'
                  @Consumption.filter.hidden: true
                  cast(_Condition.ConditionQuantity as customer_price_unit preserving type)  as ConditionQuantity,


                  @Semantics.unitOfMeasure: true
                  @ObjectModel.foreignKey.association: '_ConditionQuantityUnit'
                  @Consumption.filter.hidden: true
                  _Condition.ConditionQuantityUnit,

                  @ObjectModel.foreignKey.association: '_ConditionApplication'
                  @UI.hidden: true
                  _Condition.ConditionApplication,

                  @Search.ranking: #HIGH
                  @Consumption.filter.hidden: true
                  @ObjectModel.foreignKey.association: '_PricingConditionType'
                  @UI: {lineItem: [ { position: 100 } ]}
                  @ObjectModel.text.element:  [ 'ConditionTypeName' ]
                  _Condition.ConditionType,

                  @UI.hidden: true
                  _PricingConditionType._Text[1:Language=$session.system_language].ConditionTypeName,

                  @Consumption.filter.hidden: true
                  _SalesOffice,
                  @Consumption.filter.hidden: true
                  _SalesGroup,
                  @Consumption.filter.hidden: true
                  _SoldToParty,
                  @Consumption.filter.hidden: true
                  _CreatedByUser,
                  _ContactPerson,
                  @Consumption.filter.hidden: true
                  _SalesDocument,
                  _PricingElement,
                  @Consumption.filter.hidden: true
                  _SalesDocumentType,
                  @Consumption.filter.hidden: true
                  _ConditionCategory,
                  @Consumption.filter.hidden: true
                  _ConditionCurrency,
                  @Consumption.filter.hidden: true
                  _OrderQuantityUnit,
                  @Consumption.filter.hidden: true
                  _TargetQuantityUnit,
                  @Consumption.filter.hidden: true
                  _DistributionChannel,
                  @Consumption.filter.hidden: true
                  _TransactionCurrency,
                  @Consumption.filter.hidden: true
                  _PricingConditionType,
                  @Consumption.filter.hidden: true
                  _OrganizationDivision,
                  @Consumption.filter.hidden: true
                  _ConditionApplication,
                  @Consumption.filter.hidden: true
                  _NetPriceQuantityUnit,
                  @Consumption.filter.hidden: true
                  _ConditionQuantityUnit,
                  @Consumption.filter.hidden: true
                  _SalesDocumentCategory,
                  @Consumption.filter.hidden: true
                  _PricingConditionTypeVH,
                  @Consumption.filter.hidden: true
                  _SalesDocumentRjcnReason,
                  @Consumption.filter.hidden: true
                  _SalesDocument._SalesOrganization
}
where
      _SalesDocument.SalesDocumentProcessingType <> 'S'
  and SalesDocumentItem.SalesDocumentRjcnReason  =  ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CONDITIONTYPETEXT",
"I_MATERIALTEXT",
"I_PRICINGCONDITIONTYPE",
"I_PRICINGELEMENT",
"I_SALESDOCUMENT",
"I_SALESDOCUMENTITEM",
"P_CUSTEXPPRICEINCOMPLETIONLOG"
],
"ASSOCIATED":
[
"C_CUSTEXPDPRICECONDITION",
"C_DISCHANNELVALUEHELP",
"C_INCOMPL_SALESDOCCATVH",
"C_INCOMPL_SALESDOCTYPEVH",
"C_ORGDIVISIONVALUEHELP",
"C_PRICINGCONDITIONTYPE_VH",
"C_SALESDOCUMENTCONTACTPERSON",
"C_SALESDOCUMENTUSERVH",
"C_SALESGROUPVALUEHELP",
"C_SALESOFFICEVALUEHELP",
"C_SOLDTOVALUEHELP",
"I_CONDITIONAPPLICATION",
"I_CONDITIONCATEGORY",
"I_CURRENCY",
"I_PRICINGCONDITIONTYPE",
"I_SALESDOCUMENT",
"I_SALESDOCUMENTRJCNREASON",
"I_SALESORGANIZATION",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_SALESDOCUMENT",
"I_SALESDOCUMENTITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/