I_NotifTaskFllwUpActionParam

@AbapCatalog.sqlViewName: 'INTFTSKFOAPRM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED

@VDM.viewType: #BASIC

@EndUserText.label: 'Notif. Task Follow-Up Action Parameter'
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
    representativeKey: 'ItemCounter',
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #M,
        serviceQuality: #A }
}

define view I_NotifTaskFllwUpActionParam
  as select from qmsm_foa_param
  //=== Assocation to QM specific views

  association [1..1] to I_Notification             as _Notification             on  $projection.Notification     = _Notification.Notification
  association [1..1] to I_NotificationTask         as _NotificationTask         on  $projection.Notification     = _NotificationTask.Notification
                                                                                and $projection.NotificationTask = _NotificationTask.NotificationTask
//  association [0..1] to I_NotificationItem         as _NotificationItem         on  $projection.Notification     = _NotificationItem.Notification

//                                                                                and $projection.notificationitem = _NotificationItem.NotificationItem

  //=== Assocation to other views

  association [0..1] to I_Material                 as _Material                 on  $projection.Material = _Material.Material
  association [0..1] to I_Plant                    as _Plant                    on  $projection.Plant = _Plant.Plant
  association [0..1] to I_StorageLocation          as _StorageLocation          on  $projection.Plant           = _StorageLocation.Plant
                                                                                and $projection.StorageLocation = _StorageLocation.StorageLocation

  association [0..1] to I_OrderInternalID          as _OrderInternalID          on  $projection.OrderInternalID =  _OrderInternalID.OrderInternalID
                                                                                and $projection.OrderInternalID <> '0000000000'
  association [0..1] to I_OrderOperationBasic      as _OrderOperationBasic      on  $projection.OrderInternalID          =  _OrderOperationBasic.OrderInternalID
                                                                                and $projection.OrderOperationInternalID =  _OrderOperationBasic.OrderOperationInternalID
                                                                                and $projection.OrderInternalID          <> '0000000000'

  association [0..1] to I_MfgActionReasonCodeGroup as _MfgActionReasonCodeGroup on  $projection.MfgNonConformanceRsnCodeCtlg = _MfgActionReasonCodeGroup.MfgActionReasonCodeGroupCtlg
                                                                                and $projection.MfgNonConformanceRsnCodeGrp  = _MfgActionReasonCodeGroup.MfgActionReasonCodeGroup
  association [0..1] to I_MfgActionReasonCode      as _MfgActionReasonCode      on  $projection.MfgNonConformanceRsnCodeCtlg = _MfgActionReasonCode.MfgActionReasonCodeGroupCtlg
                                                                                and $projection.MfgNonConformanceRsnCodeGrp  = _MfgActionReasonCode.MfgActionReasonCodeGroup
                                                                                and $projection.MfgNonConformanceReasonCode  = _MfgActionReasonCode.ManufacturingActionReasonCode
                                                                                and _MfgActionReasonCode.Version             = '0000'
  //=== Assocation to common views

  association [0..1] to I_UnitOfMeasure            as _UnitOfMeasure            on  $projection.DefectiveQuantityUnit = _UnitOfMeasure.UnitOfMeasure

{
      @ObjectModel:{  foreignKey.association: '_NotificationTask',
                      readOnly: true }
  key qmsm_foa_param.qmnum                                               as Notification,
  key qmsm_foa_param.manum                                               as NotificationTask,
  key qmsm_foa_param.counter                                             as ItemCounter,

      qmsm_foa_param.paramtype                                           as QltyTskFllwUpActnParamType,
      @Semantics.quantity.unitOfMeasure: 'DefectiveQuantityUnit'
      qmsm_foa_param.menge                                               as DefectiveQuantity,

      @ObjectModel:{    foreignKey.association: '_UnitOfMeasure' }
      @Semantics.unitOfMeasure: true
      qmsm_foa_param.mgein                                               as DefectiveQuantityUnit,

      @ObjectModel:{    foreignKey.association: '_Material' }
      qmsm_foa_param.matnr                                               as Material,

      @ObjectModel:{    foreignKey.association: '_Plant' }
      qmsm_foa_param.werks                                               as Plant,

      @ObjectModel:{    foreignKey.association: '_StorageLocation' }
      qmsm_foa_param.lgort                                               as StorageLocation,
      qmsm_foa_param.affctd_obj_counter                                  as DefectAffectedObject,//only possible if item created from defect

//      _NotificationTask.NotificationItem,

      qmsm_foa_param.plnty                                               as BillOfOperationsType,
      qmsm_foa_param.plnnr                                               as BillOfOperationsGroup,
      qmsm_foa_param.plnal                                               as BillOfOperationsVariant,
      qmsm_foa_param.plnversn                                            as BillOfOperationsVersion,
      qmsm_foa_param.aufpl                                               as OrderInternalID,
      qmsm_foa_param.aplzl                                               as OrderOperationInternalID,
      qmsm_foa_param.mfgrewrkroutplnnr                                   as MfgReworkRoutingGroup,
      qmsm_foa_param.mfgrewrkroutplnal                                   as MfgReworkRoutingVariant,
      qmsm_foa_param.mpe_nc_rsn_code_ctlg                                as MfgNonConformanceRsnCodeCtlg,

      @ObjectModel:{    foreignKey.association: '_MfgActionReasonCodeGroup'   }
      qmsm_foa_param.mpe_nc_rsn_code_grp                                 as MfgNonConformanceRsnCodeGrp,

      @ObjectModel:{    foreignKey.association: '_MfgActionReasonCode'    }
      qmsm_foa_param.mpe_nc_rsn_code                                     as MfgNonConformanceReasonCode,
      qmsm_foa_param.mpe_nc_note                                         as MfgNonConformanceNote,
      qmsm_foa_param.prvbe                                               as ProductionSupplyArea,
      qmsm_foa_param.vlpla                                               as SourceStorageBin,
      qmsm_foa_param.defectuuid                                          as DefectUUID,
      
      qmsm_foa_param.chg_rec_id                                          as ChangeRecord,
      qmsm_foa_param.chg_rec_type                                        as ChangeRecordType,
      qmsm_foa_param.chg_rec_desc                                        as ChgRecordDescriptionText,
      
      /* Associations */
      _Notification,
      _NotificationTask,
//      _NotificationItem,

      _Material,
      _Plant,
      _StorageLocation,
      _UnitOfMeasure,
      _MfgActionReasonCodeGroup,
      _MfgActionReasonCode,
      _OrderInternalID,
      _OrderOperationBasic
}
where
  qmsm_foa_param.qmnum not like '$%'