I_MfgActionReasonCodeGroup

@AbapCatalog.sqlViewName: 'IMPERSNCGRP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.representativeKey: 'MfgActionReasonCodeGroup'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@ObjectModel.usageType:
{
  serviceQuality: #B,
  sizeCategory:   #S,
  dataClass:      #CUSTOMIZING
}
@Search.searchable: true
@EndUserText.label: 'Reason Code Group'
define view I_MfgActionReasonCodeGroup
  as select from qpgr as grp

  association [0..1] to I_Inspectioncatalog            as _Catalog           on  $projection.MfgActionReasonCodeGroupCtlg = _Catalog.InspectionCatalog

  association [0..*] to I_MfgActionReasonCodeGroupText as _Text              on  $projection.MfgActionReasonCodeGroupCtlg = _Text.MfgActionReasonCodeGroupCtlg
                                                                             and $projection.MfgActionReasonCodeGroup     = _Text.MfgActionReasonCodeGroup

  association [0..1] to I_User                         as _CreatedByUser     on  $projection.CreatedByUser = _CreatedByUser.UserID

  association [0..1] to I_User                         as _LastChangedByUser on  $projection.LastChangedByUser = _LastChangedByUser.UserID

{
      // key fields

      @ObjectModel.foreignKey.association: '_Catalog'
  key katalogart as MfgActionReasonCodeGroupCtlg,
      @ObjectModel.text.association: '_Text'
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key codegruppe as MfgActionReasonCodeGroup,

      // codegroup

      inaktiv    as CodeGroupIsInactive,
      status     as CodeGroupStatus,
      verwendung as MfgActionReasonCodeGroupIsUsed,

      // admin

      a_datum    as LastChangeDateTime,
      @ObjectModel.foreignKey.association: '_LastChangedByUser'
      aenderer   as LastChangedByUser,
      e_datum    as CreationDateTime,
      @ObjectModel.foreignKey.association: '_CreatedByUser'
      ersteller  as CreatedByUser,

      // text association

      _Text,

      // others

      _Catalog,
      _CreatedByUser,
      _LastChangedByUser
      
}
where
     grp.katalogart = '7'
  or grp.katalogart = '0'