I_MfgActionReasonCode

@AbapCatalog: {
  sqlViewName: 'IMPERSNCODE',
  compiler.compareFilter: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  privilegedAssociations: ['_CreatedByUser', '_LastChangedByUser']
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: ['MfgActionReasonCodeGroupCtlg', 'MfgActionReasonCodeGroup', 'ManufacturingActionReasonCode', 'Version']
@VDM.viewType: #BASIC
@ObjectModel.usageType:
{
  serviceQuality: #B,
  sizeCategory:   #S,
  dataClass:      #CUSTOMIZING
}
@Search.searchable: true
@EndUserText.label: 'Reason Code'
define view I_MfgActionReasonCode
  as select from qpcd as code
  association [0..*] to I_MfgActionReasonCodeText  as _Text              on  $projection.MfgActionReasonCodeGroupCtlg  = _Text.MfgActionReasonCodeGroupCtlg
                                                                         and $projection.MfgActionReasonCodeGroup      = _Text.MfgActionReasonCodeGroup
                                                                         and $projection.ManufacturingActionReasonCode = _Text.ManufacturingActionReasonCode
                                                                         and $projection.Version                       = _Text.Version

  association [0..1] to I_MfgActionReasonCodeGroup as _Group             on  $projection.MfgActionReasonCodeGroupCtlg = _Group.MfgActionReasonCodeGroupCtlg
                                                                         and $projection.MfgActionReasonCodeGroup     = _Group.MfgActionReasonCodeGroup

  association [0..1] to I_Inspectioncatalog        as _Catalog           on  $projection.MfgActionReasonCodeGroupCtlg = _Catalog.InspectionCatalog

  association [0..1] to I_User                     as _CreatedByUser     on  $projection.CreatedByUser = _CreatedByUser.UserID

  association [0..1] to I_User                     as _LastChangedByUser on  $projection.LastChangedByUser = _LastChangedByUser.UserID

{
      // key fields

      @ObjectModel.foreignKey.association: '_Catalog'
  key code.katalogart        as MfgActionReasonCodeGroupCtlg,
      @ObjectModel.foreignKey.association: '_Group'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgActnRsnCodeGrpStdVH', element: 'MfgActionReasonCodeGroup' } } ]
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key code.codegruppe        as MfgActionReasonCodeGroup,
      @ObjectModel.text.association: '_Text'
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key code.code              as ManufacturingActionReasonCode,
  key code.version           as Version,

      // for compatibility reasons

      ''                     as MfgActionReasonCodeCategory,

      // code data

      code.fehlklasse        as DefectClass,
      code.folgeakti         as Action,
      code.geloescht         as IsDeleted,
      code.gueltigab         as ValidityStartDate,
      code.inaktiv           as CodeIsInactive,
      _Group.CodeGroupStatus as CodeGroupStatus,
      code.verwendung        as MfgActionReasonCodeIsUsed,

      // admin data

      @ObjectModel.foreignKey.association: '_CreatedByUser'
      code.ersteller         as CreatedByUser,
      code.e_datum           as CreationDateTime,
      @ObjectModel.foreignKey.association: '_LastChangedByUser'
      code.aenderer          as LastChangedByUser,
      code.a_datum           as LastChangeDateTime,

      // text associations

      _Text,

      // others

      _Group,
      _Catalog,
      _CreatedByUser,
      _LastChangedByUser

}
where
     code.katalogart = '7'
  or code.katalogart = '0'
  or code.katalogart = '9'