I_Notification

@AbapCatalog.sqlViewName: 'INOTIFICATION'
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Notification'
@Analytics.dataCategory: #FACT
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations: ['_CreatedByUserContactCard', '_LastChangedByUserContactCard', '_NotificationPartner', '_StsObjConcatActiveStsILL']

@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #L,
        serviceQuality: #A },
    representativeKey: 'Notification'
}

define view I_Notification
  as select from qmel

  //=== Aggregations

  association [0..*] to I_NotificationPartner      as _NotificationPartner          on  $projection.NotificationStatusObject = _NotificationPartner.NotificationPartnerObject
  association [0..*] to I_NotificationItem         as _NotificationItem             on  $projection.Notification = _NotificationItem.Notification
  association [0..*] to I_NotificationTask         as _NotificationTask             on  $projection.Notification = _NotificationTask.Notification
  association [0..*] to I_NotificationActivity     as _NotificationActivity         on  $projection.Notification = _NotificationActivity.Notification

  //=== Associations to views of other applications

  association [0..1] to I_LogisticsOrder           as _LogisticsOrder               on  $projection.OrderID = _LogisticsOrder.OrderID
  association [0..1] to I_Plant                    as _Plant                        on  $projection.Plant = _Plant.Plant
  association [0..1] to I_Product                  as _Product                      on  $projection.Material = _Product.Product
  association [0..1] to I_ProductGroup             as _ProductGroup                 on  $projection.MaterialGroup = _ProductGroup.MaterialGroup
  association [0..1] to I_ProductGroup_2           as _ProductGroup_2               on  $projection.MaterialGroup = _ProductGroup_2.ProductGroup
  association [0..1] to I_PurchasingDocument       as _PurchasingDocument           on  $projection.PurchasingDocument = _PurchasingDocument.PurchasingDocument
  association [0..1] to I_Supplier                 as _Supplier                     on  $projection.Supplier = _Supplier.Supplier
  association [0..1] to I_Customer                 as _Customer                     on  $projection.Customer = _Customer.Customer
  association [0..1] to I_PMNotifMaintenanceData   as _PMNotifMaintenanceData       on  $projection.Notification = _PMNotifMaintenanceData.MaintenanceNotification
  association [0..1] to I_WBSElement               as _WBSElement                   on  $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
  association [0..1] to I_InspectionLot            as _InspectionLot                on  $projection.InspectionLot = _InspectionLot.InspectionLot
  association [0..1] to I_UserContactCard          as _CreatedByUserContactCard     on  $projection.CreatedByUser = _CreatedByUserContactCard.ContactCardID
  association [0..1] to I_UserContactCard          as _LastChangedByUserContactCard on  $projection.LastChangedByUser = _LastChangedByUserContactCard.ContactCardID
  association [0..1] to I_InspectionOperation      as _InspectionOperation          on  $projection.InspectionLot = _InspectionOperation.InspectionLot
                                                                                    and $projection.OrderOperationInternalID = _InspectionOperation.OrderOperationInternalID
  association [0..1] to I_OrderOperationBasic      as _OrderOperationBasic          on  $projection.MfgOrderInternalID = _OrderOperationBasic.OrderInternalID
                                                                                    and $projection.OrderOperationInternalID = _OrderOperationBasic.OrderOperationInternalID
                                                                                  
  //=== Associations to Configuration

  association [1..1] to I_NotificationType         as _NotificationType             on  $projection.NotificationType = _NotificationType.NotificationType
  association [0..1] to I_NotificationPriority     as _NotificationPriority         on  $projection.NotificationPriorityType = _NotificationPriority.NotificationPriorityType
                                                                                    and $projection.NotificationPriority     = _NotificationPriority.NotificationPriority
  association [0..1] to I_NotificationCatalog      as _NotificationCatalog          on  $projection.NotificationCatalog = _NotificationCatalog.NotificationCatalog
  association [0..1] to I_NotificationCodeGroup    as _NotificationCodeGroup        on  $projection.NotificationCatalog   = _NotificationCodeGroup.NotificationCatalog
                                                                                    and $projection.NotificationCodeGroup = _NotificationCodeGroup.NotificationCodeGroup
  association [0..1] to I_NotificationCode         as _NotificationCode             on  $projection.NotificationCatalog   = _NotificationCode.NotificationCatalog
                                                                                    and $projection.NotificationCodeGroup = _NotificationCode.NotificationCodeGroup
                                                                                    and $projection.NotificationCodeID    = _NotificationCode.NotificationCodeID
  association [1..1] to I_NotifProcessingPhase     as _NotifProcessingPhase         on  $projection.NotifProcessingPhase = _NotifProcessingPhase.NotifProcessingPhase

  //=== Assocation to foundation views

  association [0..1] to I_UnitOfMeasure            as _NotificationQuantityUnit     on  $projection.NotificationQuantityUnit = _NotificationQuantityUnit.UnitOfMeasure
  association [0..1] to I_StsObjConcatActiveStsILL as _StsObjConcatActiveStsILL     on  $projection.NotificationStatusObject = _StsObjConcatActiveStsILL.StatusObject

{
  key qmel.qmnum                                          as Notification,
      @ObjectModel.foreignKey.association: '_NotificationType'
      qmel.qmart                                          as NotificationType,
      qmel.qmtxt                                          as NotificationText,
      qmel.artpr                                          as NotificationPriorityType,
      @ObjectModel.foreignKey.association: '_NotificationPriority'
      qmel.priok                                          as NotificationPriority,
      @Semantics.user.createdBy: true
      @ObjectModel.foreignKey.association: '_CreatedByUserContactCard'
      qmel.ernam                                          as CreatedByUser,
      @Semantics.systemDate.createdAt: true
      qmel.erdat                                          as CreationDate,
      @Semantics.user.lastChangedBy: true
      @ObjectModel.foreignKey.association: '_LastChangedByUserContactCard'
      qmel.aenam                                          as LastChangedByUser,
      @Semantics.systemDate.lastChangedAt: true
      qmel.aedat                                          as LastChangedDate,
      qmel.mzeit                                          as NotificationCreationTime,
      qmel.qmdat                                          as NotificationReportingDate,
      qmel.qmnam                                          as ReportedByUser,
      qmel.strmn                                          as NotificationRequiredStartDate,
      qmel.strur                                          as NotificationRequiredStartTime,
      qmel.ltrmn                                          as NotificationRequiredEndDate,
      qmel.ltrur                                          as NotificationRequiredEndTime,

      qmel.tzonso                                         as NotificationTimeZone,

      //       qmel.waers,

      @ObjectModel.foreignKey.association: '_LogisticsOrder'
      qmel.aufnr                                          as OrderID, // LogisticsOrder

      qmel.verid                                          as ProductionVersion,
      //       qmel.rm_matnr,

      //       qmel.rm_werks,

      //       qmel.sa_aufnr,

      @ObjectModel.foreignKey.association: '_Product'
      qmel.matnr                                          as Material,
      //       qmel.revlv,

      @ObjectModel.foreignKey.association: '_ProductGroup'
      qmel.matkl                                          as MaterialGroup,
      //       qmel.prdha,

      //       qmel.kzkri,

      //       qmel.kzdkz,

      @ObjectModel.foreignKey.association: '_Customer'
      qmel.kunum                                          as Customer,
      //       qmel.feknz,

      //       qmel.maknz,

      qmel.objnr                                          as NotificationStatusObject,
      qmel.qmdab                                          as NotificationCompletionDate,
      //       qmel.qmzab,

      //       qmel.rbnr,

      //       qmel.rbnri,

      //       qmel.indtx,

      cast( qmel.kzmla as vdm_j_masterlanguage )          as MasterLanguage,
      qmel.herkz                                          as NotificationOrigin,
      //       qmel.bezdt,

      //       qmel.bezur,

      @ObjectModel.foreignKey.association: '_Supplier'
      qmel.lifnum                                         as Supplier,
      //       qmel.buname,

      //       qmel.vbeln,

      qmel.bstnk                                          as PurchaseOrderByCustomer,
      qmel.bstdk                                          as CustomerPurchaseOrderDate,
      qmel.spart                                          as ActiveDivision,
      qmel.vkorg                                          as SalesOrganization,
      qmel.vtweg                                          as DistributionChannel,
      //       qmel.adrnr,

      //       qmel.aezeit,

      //       qmel.erzeit,

      @ObjectModel.foreignKey.association: '_Plant'
      qmel.mawerk                                         as Plant,
      @ObjectModel.foreignKey.association: '_NotificationCatalog'
      qmel.qmkat                                          as NotificationCatalog,
      @ObjectModel.foreignKey.association: '_NotificationCodeGroup'
      qmel.qmgrp                                          as NotificationCodeGroup,
      @ObjectModel.foreignKey.association: '_NotificationCode'
      qmel.qmcod                                          as NotificationCodeID,
      //       qmel.auswirk,

      //       qmel.teilev,

      @ObjectModel.foreignKey.association: '_InspectionLot'
      qmel.prueflos                                       as InspectionLot,
      qmel.charg                                          as Batch,
      //       qmel.lgortcharg

      //       qmel.lichn,

      qmel.hersteller                                     as Manufacturer,
      //       qmel.ematnr,

      qmel.ekorg                                          as PurchasingOrganization,
      qmel.bkgrp                                          as PurchasingGroup,
      //       qmel.lgortvorg,

      qmel.fertaufnr                                      as ProductionOrder,
      qmel.fertaufpl                                      as MfgOrderInternalID,
      @ObjectModel.foreignKey.association: '_PurchasingDocument'
      qmel.ebeln                                          as PurchasingDocument,
      qmel.ebelp                                          as PurchasingDocumentItem,
      qmel.mjahr                                          as MaterialDocumentYear,
      qmel.mblnr                                          as MaterialDocument,
      qmel.mblpo                                          as MaterialDocumentItem,
      qmel.ls_kdauf                                       as OrderDocument,
      qmel.ls_kdpos                                       as OrderDocumentItem,
      qmel.ls_vbeln                                       as DeliveryDocument,
      qmel.ls_posnr                                       as DeliveryDocumentItem,
      qmel.crobjty                                        as WorkCenterTypeCode,
      qmel.arbpl                                          as MainWorkCenterInternalID,
      qmel.arbplwerk                                      as MainWorkCenterPlant,
      //       qmel.feart,

      qmel.pnlkn                                          as OrderOperationInternalID,
      @Semantics.quantity.unitOfMeasure: 'NotificationQuantityUnit'
      qmel.mgeig                                          as NotificationInternalQuantity,
      @Semantics.quantity.unitOfMeasure: 'NotificationQuantityUnit'
      qmel.mgfrd                                          as NotificationExternalQty,
      @ObjectModel.foreignKey.association: '_NotificationQuantityUnit'
      @Semantics.unitOfMeasure:true
      qmel.mgein                                          as NotificationQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'NotificationQuantityUnit'
      qmel.bzmng                                          as NotificationReferenceQuantity,
      @Semantics.quantity.unitOfMeasure: 'NotificationQuantityUnit'
      qmel.rkmng                                          as NotificationComplaintQuantity,
      @Semantics.quantity.unitOfMeasure: 'NotificationQuantityUnit'
      qmel.rgmng                                          as NotifReturnDeliveryQuantity,
      qmel.rkdat                                          as NotificationReturnDeliveryDate,
      //       qmel.coaufnr,

      qmel.qwrnum                                         as NotificationLinkedNotification,
      qmel.refnum                                         as NotificationExtReferenceNumber,
      //       qmel.kdmat,

      //       qmel.idnlf,

      //       qmel.serialnr,

      qmel.kzloesch                                       as IsDeleted,
      qmel.cvp_xblck                                      as IsBusinessPurposeCompleted,
      qmel.proddat                                        as ProductionDate,
      qmel.deviceid                                       as AdditionalDeviceData,
      //       qmel.vkbur,

      //       qmel.vkgrp,

      //       qmel.autkz,

      //       qmel.bedid,

      //       qmel.bedzl,

      //       qmel.profil_typ,

      //       qmel.profil_id,

      //       qmel.handle,

      //       qmel.tsegfl,

      //       qmel.tsegtp,

      //       qmel.tzonid,

      //       qmel.funktion,

      //       qmel./sapsmoss/instn,

      //       qmel./sapsmoss/mnumm,

      //       qmel./sapsmoss/ossys,

      //       qmel./sapsmoss/dbsys,

      //       qmel./sapsmoss/rel,

      //       qmel./sapsmoss/comp,

      //       qmel./sapsmoss/front,

      //       qmel./sapsmoss/systyp,

      //       qmel./sapsmoss/addid,

      //       qmel./sapsmoss/addrel,

      //       qmel./sapsmoss/tstmp,

      //       qmel./sapsmoss/status,

      //       qmel./sapsmoss/erdat,

      //       qmel./sapsmoss/erzeit,

      //       qmel./sapsmoss/sysid,

      //       qmel./sapsmoss/mandt,

      cast ( qmel.psp_nr as ps_s4_pspnr preserving type ) as WBSElementInternalID,
      //       qmel.estimated_costs,

      //       qmel.claimed_costs,

      //       qmel.result_costs,

      //       qmel.chance,

      //       qmel.opponent,

      //       qmel.kalnr,

      //       qmel.kalvar,

      //       qmel.objnr_real,

      //       qmel.objnr_stat,

      @ObjectModel.foreignKey.association: '_NotifProcessingPhase'
      qmel.phase                                          as NotifProcessingPhase,

//    Most likely not required to provide a non-initial value in any case as there is no BOBF managed BO consuming this

//      case qmel.changeddatetime

//        when 0 then cast( '19000101010101' as tzntstmps )

//        else qmel.changeddatetime end                     as ChangedDateTime,

      qmel.changeddatetime as ChangedDateTime,

      qmel.shn_objty     as ShiftNoteWorkCenterType,
      qmel.shn_objid     as ShiftNoteWorkCenterInternalID,
      qmel.shn_funct_loc as FunctionalLocation,
      qmel.shn_equipment as Equipment,
      qmel.shn_origin    as ShiftNoteOrigin,
      //       qmel.uii


      // Associations

      _NotificationItem,
      _NotificationTask,
      _NotificationActivity,
      _LogisticsOrder,
      _PurchasingDocument,
      _Plant,
      _Product,
      _ProductGroup_2,
      @VDM.lifecycle.status:#DEPRECATED
      _ProductGroup,
      _Supplier,
      _Customer,
      _NotificationQuantityUnit,
      _PMNotifMaintenanceData,
      _WBSElement,
      _InspectionLot,
      _InspectionOperation, 
      _OrderOperationBasic,
      _NotificationType,
      _NotificationPriority,
      _NotificationCatalog,
      _NotificationCodeGroup,
      _NotificationCode,
      _NotifProcessingPhase,
      _StsObjConcatActiveStsILL,
      _CreatedByUserContactCard,
      _LastChangedByUserContactCard,
      _NotificationPartner
}