I_StorageLocation

@AbapCatalog: {
                sqlViewName: 'ISTORAGELOCATION',
                preserveKey: true,
                compiler.compareFilter: true
              }
@EndUserText.label: 'Storage Location'
@ObjectModel: {
                usageType: {
                             sizeCategory: #S,
                             serviceQuality: #A,
                             dataClass:#CUSTOMIZING
                           },
                representativeKey: 'StorageLocation',
                sapObjectNodeType: {
                                     name: 'StorageLocation'
                                   },
                modelingPattern: #ANALYTICAL_DIMENSION,
                supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #EXTRACTION_DATA_SOURCE]
              }
@VDM: {
        viewType: #BASIC,
        lifecycle.contract.type: #PUBLIC_LOCAL_API
      }
@AccessControl: {
                  authorizationCheck: #NOT_REQUIRED,
                  personalData.blocking: #NOT_REQUIRED
                }
@ClientHandling.algorithm: #SESSION_VARIABLE
@Analytics: {
              dataCategory: #DIMENSION,
              dataExtraction.enabled: true
            }
@Search.searchable: true
@Metadata: {
             allowExtensions: true,
             ignorePropagatedAnnotations: true
           }

define view I_StorageLocation
  as select from t001l
  association [1..1] to I_Plant as _Plant on $projection.Plant = _Plant.Plant
  association [1..1] to I_ConfignDeprecationCode  as _ConfignDeprecationCode on $projection.ConfigDeprecationCode = _ConfignDeprecationCode.ConfigurationDeprecationCode   
  association [0..*] to I_ConfignDeprecationCodeText     as _ConfignDeprecationCodeText      on  $projection.ConfigDeprecationCode= _ConfignDeprecationCodeText.DomainValue 
  association [0..*] to I_SalesOrganizationText          as _SalesOrganizationText           on  $projection.SalesOrganization = _SalesOrganizationText.SalesOrganization                                                                         
{
      @ObjectModel.foreignKey.association: '_Plant'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlantStdVH', element: 'Plant' }, useAsTemplate: true } ]
  key werks                     as Plant,
      @ObjectModel.text.element: 'StorageLocationName'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key lgort                     as StorageLocation,
      @Semantics.text: true
      cast(lgobe as lgort_name) as StorageLocationName,
      @Consumption.valueHelpDefinition: [{ entity:  { name:    'I_SalesOrganizationStdVH', element: 'SalesOrganization' }, useAsTemplate: true    }]
//      @ObjectModel.text.association: '_SalesOrganizationText'  

      vkorg                     as SalesOrganization,
      vtweg                     as DistributionChannel,
      spart                     as Division,
      xblgo                     as IsStorLocAuthznCheckActive,
      xhupf                     as HandlingUnitIsRequired,
      @ObjectModel.foreignKey.association: '_ConfignDeprecationCode'
//     @Consumption.valueHelpDefinition: [{ entity:  { name:    'I_ConfignDeprecationCode', element: 'ConfigurationDeprecationCode' }, useAsTemplate: true    }]

//      @ObjectModel.text.association: '_ConfignDeprecationCodeText'  

      configdeprecationcode     as ConfigDeprecationCode,
      _Plant,
      _ConfignDeprecationCode,
     _ConfignDeprecationCodeText,
     _SalesOrganizationText
      
}