I_BusinessPartnerProcessTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Business Partner (Process Data)'

@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.sapObjectNodeType.name: 'BusinessPartner'
@Search.searchable: true
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define root view entity I_BusinessPartnerProcessTP
  as select from I_BusinessPartnerProcess

  composition [0..*] of I_BusinessPartnerRoleProcTP    as _BusinessPartnerRole
  composition [0..*] of I_BusinessPartnerAddressProcTP as _BusinessPartnerAddress
  composition [0..*] of I_BPIndepMobileNumberProcTP    as _BPIndepMobileNumber
  composition [0..*] of I_BPIndepTelephoneNumberProcTP as _BPIndepTelephoneNumber
  composition [0..*] of I_BPIndepFaxNumberProcTP       as _BPIndepFaxNumber
  composition [0..*] of I_BPIndepEmailAddressProcessTP as _BPIndepEmailAddress
  composition [0..*] of I_BPIndepWebsiteURLProcTP      as _BPIndepWebsiteURL
  composition [0..1] of I_BPIndepCommMethodProcessTP   as _BPIndepCommunicationMethod
  composition [0..*] of I_BPIdentificationProcessTP    as _BusinessPartnerIdentification
  composition [0..*] of I_BPTaxNumberProcessTP         as _BusinessPartnerTaxNumber
  composition [0..*] of I_BusPartIndustryProcTP        as _BusinessPartnerIndustry
  composition [0..*] of I_BusinessPartnerBankProcTP    as _BusinessPartnerBank
  composition [0..1] of I_BPFinServicesDetailProcTP    as _BPFinServicesDetail
  composition [0..*] of I_BPEmploymentProcessTP        as _BPEmployment
  composition [0..*] of I_BPFiscalYearProcessTP        as _BPFiscalYear
  composition [0..*] of I_BPCreditWorthinessProcessTP  as _BPCreditWorthiness
  composition [0..*] of I_BPRatingProcessTP            as _BPRating
  composition [0..*] of I_BPFinSrvcsReportingProcessTP as _BPFinSrvcsReporting
  composition [0..*] of I_BusinessPartnerAliasProcTP   as _BusinessPartnerAliasName
  composition [0..*] of I_BusinessPrtnTxCmplncProcTP   as _BusinessPartnerTaxCompliance
  composition [0..1] of I_BusinessPartnerIsBankProcTP  as _BusinessPartnerIsBank
  composition [0..*] of I_BPDataControllerProcessTP    as _BusinessPartnerDataController
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_BusinessPartnerAddressProcTP as _BusinessPartnerStandardAddr on  $projection.MasterDataChangeProcess        = _BusinessPartnerStandardAddr.MasterDataChangeProcess
                                                                                       and $projection.MDChgProcessSrceSystem         = _BusinessPartnerStandardAddr.MDChgProcessSrceSystem
                                                                                       and $projection.MDChgProcessSrceObject         = _BusinessPartnerStandardAddr.MDChgProcessSrceObject
                                                                                       and $projection.MDChgProcessStep               = _BusinessPartnerStandardAddr.MDChgProcessStep
                                                                                       and _BusinessPartnerStandardAddr.StandardUsage = 'X'
  association [0..1] to I_BusPartCategory              as _BusinessPartnerCategory     on  $projection.BusinessPartnerCategory = _BusinessPartnerCategory.BusinessPartnerCategory
  association [0..1] to I_BusinessPartnerLegalForm     as _BusinessPartnerLegalForm    on  $projection.LegalForm = _BusinessPartnerLegalForm.LegalForm
  association [0..1] to I_BusPartAuthorizationGroup    as _AuthorizationGroup          on  $projection.AuthorizationGroup          = _AuthorizationGroup.AuthorizationGroup
                                                                                       and _AuthorizationGroup.AuthorizationObject = 'BUPA'
  association [0..1] to I_Language                     as _Language                    on  $projection.Language = _Language.Language
  association [0..1] to I_Language                     as _CorrespondenceLanguage      on  $projection.CorrespondenceLanguage = _CorrespondenceLanguage.Language
  association [0..1] to I_BusinessPartnerGrouping      as _BusinessPartnerGrouping     on  $projection.BusinessPartnerGrouping = _BusinessPartnerGrouping.BusinessPartnerGrouping
  association [0..1] to I_BusinessPartnerFormOfAddress as _FormOfAddress               on  $projection.FormOfAddress           = _FormOfAddress.FormOfAddress
                                                                                       and $projection.BusinessPartnerCategory = _FormOfAddress.BusinessPartnerCategory
  association [0..1] to I_Country                      as _NameCountry                 on  $projection.NameCountry = _NameCountry.Country
  association [0..1] to I_Country                      as _Nationality                 on  $projection.BusPartNationality = _Nationality.Country
  association [0..1] to I_Country                      as _NonResidentCompOriginCntry  on  $projection.NonResidentCompanyOriginCntry = _NonResidentCompOriginCntry.Country
  association [0..1] to I_BusPartNameFormat            as _NameFormat                  on  $projection.NameFormat  = _NameFormat.NameFormat
                                                                                       and $projection.NameCountry = _NameFormat.Country
  association [0..1] to I_BusPartPrefixName            as _LastNameSecondPrefixName    on  $projection.LastNameSecondPrefix = _LastNameSecondPrefixName.LastNamePrefix
  association [0..1] to I_BusPartPrefixName            as _BusPartPrefixName           on  $projection.LastNamePrefix = _BusPartPrefixName.LastNamePrefix
  association [0..1] to I_BPGenderValueHelp            as _BusinessPartnerGender       on  $projection.GenderCodeName = _BusinessPartnerGender.GenderCodeName
  association [0..1] to I_BusPartSupplementName        as _BusPartSupplementName       on  $projection.BusinessPartnerSupplementName = _BusPartSupplementName.BusinessPartnerSupplementName
  association [0..1] to I_BusPartMaritalStatus         as _MaritalStatus               on  $projection.BusPartMaritalStatus = _MaritalStatus.MaritalStatus
  association [0..1] to I_BusinessPartnerOccupation    as _Occupation                  on  $projection.BusinessPartnerOccupation = _Occupation.BusinessPartnerOccupation
  association [0..1] to I_BusPartBirthDateStatus       as _BusPartBirthDateStatus      on  $projection.BusinessPartnerBirthDateStatus = _BusPartBirthDateStatus.BusinessPartnerBirthDateStatus
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_BusPartPersonFullName        as _BusPartPersonFullName       on  $projection.PersonNumber                         = _BusPartPersonFullName.PersonNumber
                                                                                       and _BusPartPersonFullName.AddressRepresentationCode = ' '
  association [0..1] to I_AcademicTitle                as _AcademicTitleValueHelp      on  $projection.AcademicTitle = _AcademicTitleValueHelp.AcademicTitle
  association [0..1] to I_BusPartAcademicTitle         as _AcademicTitle2              on  $projection.AcademicTitle2 = _AcademicTitle2.AcademicTitle
  association [0..1] to I_BusinessPartnerGroupType     as _GroupType                   on  $projection.BusinessPartnerGroupType = _GroupType.BusinessPartnerGroupType
  association [0..1] to I_BPProcessKPIRecordType       as _RecordType                  on  $projection.MasterDataChangeProcess = _RecordType.MasterDataChangeProcess
                                                                                       and $projection.MDChgProcessStep        = _RecordType.MDChgProcessStep
                                                                                       and $projection.MDChgProcessSrceSystem  = _RecordType.MDChgProcessSrceSystem
                                                                                       and $projection.MDChgProcessSrceObject  = _RecordType.MDChgProcessSrceObject
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_MDChgProcKPIFilterRecordSts  as _KPIRecordStatusText         on  $projection.MDChgProcessValidationStatus = _KPIRecordStatusText.MDChangeProcKPIValueKey
  association [0..1] to I_MDChangeProcessKPIRowVH      as _KPIUpdateStatusText         on  $projection.MDChgProcKPIUpdateStatus = _KPIUpdateStatusText.MDChgProcKPIUpdateStatus
  association [0..*] to I_MDChgProcRecordMessages      as _RecordMessages              on  $projection.MasterDataChangeProcess = _RecordMessages.MasterDataChangeProcess
                                                                                       and $projection.MDChgProcessStep        = _RecordMessages.MDChgProcessStep
                                                                                       and $projection.MDChgProcessSrceSystem  = _RecordMessages.MDChgProcessSrceSystem
                                                                                       and $projection.MDChgProcessSrceObject  = _RecordMessages.MDChgProcessSrceObject
  association [0..1] to I_MDChangeProcessRecordTarget  as _RecordTarget                on  $projection.MasterDataChangeProcess          = _RecordTarget.MasterDataChangeProcess
                                                                                       and $projection.MDChgProcessSrceSystem           = _RecordTarget.MDChgProcessSrceSystem
                                                                                       and $projection.MDChgProcessSrceObject           = _RecordTarget.MDChgProcessSrceObject
                                                                                       and _RecordTarget.MDChgProcessSrceObjectTypeCode = '147'
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_MDChgProcKPIFilterActvtnSts  as _RecordTargetText            on  $projection.MDChgProcessActivationTarget = _RecordTargetText.MDChangeProcKPIValueKey
  association [0..1] to I_MDChgProcReplicationStatus   as _ReplicationStatus           on  $projection.MasterDataChangeProcess = _ReplicationStatus.MasterDataChangeProcess
                                                                                       and $projection.MDChgProcessStep        = _ReplicationStatus.MDChgProcessStep
                                                                                       and $projection.MDChgProcessSrceSystem  = _ReplicationStatus.MDChgProcessSrceSystem
                                                                                       and $projection.MDChgProcessSrceObject  = _ReplicationStatus.MDChgProcessSrceObject
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_MDChgProcKPIFltrReplication  as _ReplicationStatusText       on  $projection.MDChgProcessReplicationStatus = _ReplicationStatusText.MDChangeProcKPIValueKey

  association [0..1] to E_BusinessPartnerProcess       as _Extension                   on  $projection.MasterDataChangeProcess = _Extension.MasterDataChangeProcess
                                                                                       and $projection.MDChgProcessStep        = _Extension.MDChgProcessStep
                                                                                       and $projection.MDChgProcessSrceSystem  = _Extension.MDChgProcessSrceSystem
                                                                                       and $projection.MDChgProcessSrceObject  = _Extension.MDChgProcessSrceObject
{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
      MDChgProcessSourceModified,
      MDChgProcessSourceModifBinary,
      @Search.defaultSearchElement: true
      BusinessPartner,
      @ObjectModel.foreignKey.association: '_BusinessPartnerCategory'
      BusinessPartnerCategory,
      @ObjectModel.foreignKey.association: '_AuthorizationGroup'
      AuthorizationGroup,
      BusinessPartnerUUID,
      PersonNumber,
      ETag,
      BusinessPartnerName,
      BusinessPartnerFullName,
      CreatedByUser,
      CreationDate,
      CreationTime,
      LastChangedByUser,
      LastChangeDate,
      LastChangeTime,
      BusinessPartnerIsBlocked,
      IsBusinessPurposeCompleted,
      OrganizationBPName1,
      OrganizationBPName2,
      OrganizationBPName3,
      OrganizationBPName4,
      cast(
        case when InternationalLocationNumber1 = '0000000'
              and InternationalLocationNumber2 = '00000'
              and InternationalLocationNumber3 = '0'
        then '       '
        else InternationalLocationNumber1
      end as bu_location1str )                                                              as InternationalLocationNumber1,
      cast(
        case when InternationalLocationNumber1='0000000'
              and InternationalLocationNumber2='00000'
              and InternationalLocationNumber3='0'
        then '     '
        else InternationalLocationNumber2
      end as bu_location2str )                                                              as InternationalLocationNumber2,
      cast(
        case when InternationalLocationNumber1='0000000'
              and InternationalLocationNumber2='00000'
              and InternationalLocationNumber3='0'
        then ' '
        else InternationalLocationNumber3
      end as bu_location3str )                                                              as InternationalLocationNumber3,
      LegalForm,
      OrganizationFoundationDate,
      OrganizationLiquidationDate,
      Industry,
      FormOfAddress                                                                         as FormOfAddressPerson,
      FormOfAddress                                                                         as FormOfAddressOrganization,
      FormOfAddress                                                                         as FormOfAddressGroup,
      FormOfAddress,
      @ObjectModel.foreignKey.association: '_BusinessPartnerGrouping'
      BusinessPartnerGrouping,
      BusinessPartnerType,
      SearchTerm1,
      SearchTerm2,
      BPLastNameSearchHelp,
      BPFirstNameSearchHelp,

      IndependentAddressID,
      IsMarkedForArchiving,
      ContactPermission,
      LegalEntityOfOrganization,
      BusinessPartnerPrintFormat,
      BusinessPartnerDataOriginType,
      BusinessPartnerIsNotReleased,
      IsNotContractuallyCapable,
      /* Person Data */
      IsFemale,
      IsMale,
      IsSexUnknown,
      GenderCodeName,
      FirstName,
      LastName,
      AdditionalLastName,
      BusinessPartnerBirthName,
      MiddleName,
      @ObjectModel: {
                foreignKey.association: '_AcademicTitleValueHelp'
      }
      AcademicTitle,
      AcademicTitle2,
      BusinessPartnerSupplementName,
      LastNamePrefix,
      LastNameSecondPrefix,
      PersonFullName,
      BusinessPartnerNicknameLabel, //Known as ?

      Initials,
      NameFormat,
      NameCountry,
      CorrespondenceLanguage,
      IsNaturalPerson,
      BirthDate,
      BusinessPartnerBirthplaceName,
      BusinessPartnerDeathDate,
      BusinessPartnerBirthDateStatus,
      NaturalPersonEmployerName,
      BusinessPartnerOccupation,
      BusPartMaritalStatus,
      BusPartNationality,
      BusinessPartnerIDByExtSystem,
      NonResidentCompanyOriginCntry,
      /* Group Data */
      GroupBusinessPartnerName1,
      GroupBusinessPartnerName2,
      BusinessPartnerGroupType,
      Language,
      /* Standard Address */
      /* Has been moved to a virtual field in the projection layer, therefore the dummy entry */
      cast( '' as abap.char(209) )                                                          as AddressLine1Text,
      MDChgProcessValidationStatus,
      cast( case
        when MDChgProcessSourceModified = '' then 'N'
        when MDChgProcessSourceModified = 'X' then 'M'
        else MDChgProcessSourceModified end as mdc_source_modified )                        as MDChgProcKPIUpdateStatus,
      cast( case
        when _RecordTarget.MDChgProcessActivationTarget = '1' then 'D'
        else _RecordTarget.MDChgProcessActivationTarget end as mdc_activation_target_mult ) as MDChgProcessActivationTarget,
      cast( case
        when _ReplicationStatus.MasterDataChangeProcess is null then 'C'
        else 'F' end as mdc_replication_status )                                            as MDChgProcessReplicationStatus,
      MDChgProcSrceLastChgdDateTime,

      DataControllerSet,
      DataController1,
      DataController2,
      DataController3,
      DataController4,
      DataController5,
      DataController6,
      DataController7,
      DataController8,
      DataController9,
      DataController10,
      BPDataControllerIsNotRequired,

      BankCountry,
      BankKey,

      /* Associations */
      _BusinessPartnerRole,
      _BusinessPartnerAddress,
      _BusinessPartnerAliasName,
      _BPIndepTelephoneNumber,
      _BPIndepMobileNumber,
      _BPIndepFaxNumber,
      _BPIndepEmailAddress,
      _BPIndepWebsiteURL,
      _BPIndepCommunicationMethod,
      _BusinessPartnerIdentification,
      _BusinessPartnerTaxNumber,
      _BusinessPartnerIndustry,
      _BusinessPartnerBank,
      _BusinessPartnerIsBank,
      _BPFinServicesDetail,
      _BPEmployment,
      _BPFiscalYear,
      _BPCreditWorthiness,
      _BPRating,
      _BPFinSrvcsReporting,
      _BusinessPartnerTaxCompliance,
      _BusinessPartnerDataController,
      _BusinessPartnerStandardAddr,
      _BusinessPartnerCategory,
      _AuthorizationGroup,
      _BusinessPartnerGrouping,
      _AcademicTitleValueHelp,
      _AcademicTitle2,
      _FormOfAddress,
      _BusPartSupplementName,
      _NameCountry,
      _NameFormat,
      _Nationality,
      _NonResidentCompOriginCntry,
      _MaritalStatus,
      _Occupation,
      _BusPartBirthDateStatus,
      _BusPartPersonFullName,
      _GroupType,
      _BusinessPartnerLegalForm,
      _Language,
      _CorrespondenceLanguage,
      _LastNameSecondPrefixName,
      _BusPartPrefixName,
      _BusinessPartnerGender,
      _RecordType,
      _KPIRecordStatusText,
      _KPIUpdateStatusText,
      _RecordMessages,
      _RecordTarget,
      _RecordTargetText,
      _ReplicationStatus,
      _ReplicationStatusText

}