I_BusinessPartnerBankProcTP

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@Search.searchable: true
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@EndUserText.label: 'Business Partner Bank (Process Data)'
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view entity I_BusinessPartnerBankProcTP
  as select from I_BusinessPartnerBankProc as BusinessPartnerBank
  association        to parent I_BusinessPartnerProcessTP as _BusinessPartner     on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                                  and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                                  and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                                  and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
  association [0..1] to I_Country                         as _Country             on  $projection.BankCountryKey = _Country.Country
  association [0..1] to I_BPProcessKPIRecordType          as _RecordType          on  $projection.MasterDataChangeProcess = _RecordType.MasterDataChangeProcess
                                                                                  and $projection.MDChgProcessStep        = _RecordType.MDChgProcessStep
                                                                                  and $projection.MDChgProcessSrceSystem  = _RecordType.MDChgProcessSrceSystem
                                                                                  and $projection.MDChgProcessSrceObject  = _RecordType.MDChgProcessSrceObject
  association [0..1] to I_MDChangeProcessKPIRowVH         as _KPIUpdateStatusText on  $projection.MDChgProcKPIUpdateStatus = _KPIUpdateStatusText.MDChgProcKPIUpdateStatus
  association [0..*] to I_MDChgProcRecordMessages         as _RecordMessages      on  $projection.MasterDataChangeProcess = _RecordMessages.MasterDataChangeProcess
                                                                                  and $projection.MDChgProcessStep        = _RecordMessages.MDChgProcessStep
                                                                                  and $projection.MDChgProcessSrceSystem  = _RecordMessages.MDChgProcessSrceSystem
                                                                                  and $projection.MDChgProcessSrceObject  = _RecordMessages.MDChgProcessSrceObject
{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key BankIdentification,
      BusinessPartner,
      BankCountryKey,
      BankNumber,
      @Search.defaultSearchElement: true
      BankAccount,
      BankControlKey,
      BankAccountReferenceText,
      BankAccountHolderName,
      BusinessPartnerExternalBankID,
      CollectionAuthInd,
      BankAccountName,
      BPBankDetailsChangeTargetID,
      BPBankIsProtected,
      ValidityStartDateTime,
      ValidityEndDateTime,
      @Semantics.businessDate.from: true
      case when ValidityStartDateTime != 00010101000000
      then tstmp_to_dats(ValidityStartDateTime,'UTC',  $session.client, 'NULL')
      else cast ( '00010103' as abap.dats )
      end                                                            as ValidityStartDate,
      @Semantics.businessDate.to: true
      case when ValidityEndDateTime != 00010101000000
      then tstmp_to_dats(ValidityEndDateTime,'UTC',  $session.client, 'NULL')
      else cast ( '99991231' as abap.dats)
      end                                                            as ValidityEndDate,
      BPBankDetailsChangeDate,
      IBAN,
      BusinessPartnerBank._IBAN.IBANValidityStartDate,
      MDChgProcessSourceModified,
      MDChgProcessSourceModifBinary,
      MDChgProcSrceLastChgdDateTime,
      
      /* Record Identification */
      /* Has been moved to a virtual field in the projection layer, therefore the dummy entry */
      cast( '' as abap.char(209) )  as AddressLine1Text,
      cast( case
        when MDChgProcessSourceModified = '' then 'N'
        when MDChgProcessSourceModified = 'X' then 'M'
        else MDChgProcessSourceModified end as mdc_source_modified ) as MDChgProcKPIUpdateStatus,

      _Bank,
      _BusinessPartner,
      _IBAN,
      _Country,
      _RecordType,
      _KPIUpdateStatusText,
      _RecordMessages
}