I_BPIdentificationProcessTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'View for ID data for BP in processes'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@Search.searchable: true
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view entity I_BPIdentificationProcessTP
  as select from I_BPIdentificationProcess
  association        to parent I_BusinessPartnerProcessTP as _BusinessPartner     on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                                  and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                                  and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                                  and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
  association [0..1] to I_Country                         as _Country             on  $projection.Country = _Country.Country
  association [0..1] to I_Region                          as _Region              on  $projection.Country = _Region.Country
                                                                                  and $projection.Region  = _Region.Region
  association [0..1] to I_BusPartIdentificationType       as _BusPartIdentificationType on  $projection.BPIdentificationType    = _BusPartIdentificationType.BPIdentificationType
                                                                                  and $projection.businesspartnercategory = _BusPartIdentificationType.BusinessPartnerCategory
  association [0..1] to I_BPProcessKPIRecordType          as _RecordType          on  $projection.MasterDataChangeProcess = _RecordType.MasterDataChangeProcess
                                                                                  and $projection.MDChgProcessStep        = _RecordType.MDChgProcessStep
                                                                                  and $projection.MDChgProcessSrceSystem  = _RecordType.MDChgProcessSrceSystem
                                                                                  and $projection.MDChgProcessSrceObject  = _RecordType.MDChgProcessSrceObject
  association [0..1] to I_MDChangeProcessKPIRowVH         as _KPIUpdateStatusText on  $projection.MDChgProcKPIUpdateStatus = _KPIUpdateStatusText.MDChgProcKPIUpdateStatus
  association [0..*] to I_MDChgProcRecordMessages         as _RecordMessages      on  $projection.MasterDataChangeProcess = _RecordMessages.MasterDataChangeProcess
                                                                                  and $projection.MDChgProcessStep        = _RecordMessages.MDChgProcessStep
                                                                                  and $projection.MDChgProcessSrceSystem  = _RecordMessages.MDChgProcessSrceSystem
                                                                                  and $projection.MDChgProcessSrceObject  = _RecordMessages.MDChgProcessSrceObject

{
      //I_BPIdentificationProcess

  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key BPIdentificationType,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key BPIdentificationNumber,
      BusinessPartner,
      BPIdnNmbrIssuingInstitute,
      BPIdentificationEntryDate,
      ValidityStartDate,
      ValidityEndDate,
      Country,
      Region,
      _BusinessPartner.BusinessPartnerCategory,
      /* Record Identification */
      /* Has been moved to a virtual field in the projection layer, therefore the dummy entry */
      cast( '' as abap.char(209) )  as AddressLine1Text,
      MDChgProcessSourceModified,
      MDChgProcessSourceModifBinary,
      MDChgProcSrceLastChgdDateTime,
      
      cast( case
        when MDChgProcessSourceModified = '' then 'N'
        when MDChgProcessSourceModified = 'X' then 'M'
        else MDChgProcessSourceModified end as mdc_source_modified ) as MDChgProcKPIUpdateStatus,
      _BusinessPartner,
      _BusinessPartner._BusinessPartnerCategory,
      _BusPartIdentificationType,
      _Region,
      _Country,
      _RecordType,
      _KPIUpdateStatusText,
      _RecordMessages
}