I_BPIndepMobileNumberProcTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'BP Indep Mobile Number (Process)'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view entity I_BPIndepMobileNumberProcTP
  as select from I_BPIndepMobileNumberProc as BPIndepMobileNumber
  
  composition [0..*] of I_BPIndepMobileNumberTxtProcTP    as _BPIndepMobileNumberTxtProc
  association        to parent I_BusinessPartnerProcessTP as _BusinessPartner     on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                                  and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                                  and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                                  and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject

  association [0..1] to I_BusPartTelCountryPrefix         as _TelCountryPrefix    on  $projection.MobilePhoneCountry = _TelCountryPrefix.Country
  association [0..1] to I_BPProcessKPIRecordType          as _RecordType          on  $projection.MasterDataChangeProcess = _RecordType.MasterDataChangeProcess
                                                                                  and $projection.MDChgProcessStep        = _RecordType.MDChgProcessStep
                                                                                  and $projection.MDChgProcessSrceSystem  = _RecordType.MDChgProcessSrceSystem
                                                                                  and $projection.MDChgProcessSrceObject  = _RecordType.MDChgProcessSrceObject
  association [0..1] to I_MDChangeProcessKPIRowVH         as _KPIUpdateStatusText on  $projection.MDChgProcKPIUpdateStatus = _KPIUpdateStatusText.MDChgProcKPIUpdateStatus
  association [0..*] to I_MDChgProcRecordMessages         as _RecordMessages      on  $projection.MasterDataChangeProcess = _RecordMessages.MasterDataChangeProcess
                                                                                  and $projection.MDChgProcessStep        = _RecordMessages.MDChgProcessStep
                                                                                  and $projection.MDChgProcessSrceSystem  = _RecordMessages.MDChgProcessSrceSystem
                                                                                  and $projection.MDChgProcessSrceObject  = _RecordMessages.MDChgProcessSrceObject
{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key OrdinalNumber,
      AddressNumber,
      AddrCommunicationValidFromDate,
      MobilePhoneCountry,
      _TelCountryPrefix.TelephoneCountryPrefix                       as TelephoneCountryPrefix,
      IsDefaultPhoneNumber,
      CommNumberIsNotUsed,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      MobilePhoneNumber,
      CompleteTelephoneNumber,
      PhoneIsSMSEnabled,
      PhoneNumberType,
      ValidityStartDateTime,
      ValidityEndDateTime,
      @Semantics.businessDate.from: true
      case when ValidityStartDateTime != ''
      then cast ( (substring(ValidityStartDateTime,1,8) ) as abap.dats )
      else cast ( '00010101' as abap.dats )
      end                                                            as ValidityStartDate,
      @Semantics.businessDate.to: true
      case when ValidityEndDateTime != ''
      then cast ( (substring(ValidityEndDateTime,1,8) ) as abap.dats )
      else cast ( '99991231' as abap.dats )
      end                                                            as ValidityEndDate,
      MDChgProcessSourceModified,
      MDChgProcessSourceModifBinary,

      MDChgProcSrceLastChgdDateTime,

      cast( case
        when MDChgProcessSourceModified = '' then 'N'
        when MDChgProcessSourceModified = 'X' then 'M'
        else MDChgProcessSourceModified end as mdc_source_modified ) as MDChgProcKPIUpdateStatus,

      /* Associations */
      _BusinessPartner,
      _BPIndepMobileNumberTxtProc,
      _TelCountryPrefix,
      _RecordType,
      _KPIUpdateStatusText,
      _RecordMessages
}