C_BPProcessChangesUnion

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Consumtion view of all changes'
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@Metadata.ignorePropagatedAnnotations: true
@UI.presentationVariant: [{
  sortOrder: [{ by: 'MDChgProcessSrceObjectTypeCode', direction: #DESC },
              { by: 'MDChgProcessRecordObjectID', direction: #ASC }]
}]
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view entity C_BPProcessChangesUnion
  as select from I_BPProcessChangesUnion
{
      //I_BPProcessChangesUnion

      @UI.hidden:true
  key MasterDataChangeProcess,
      @UI.hidden:true
  key MDChgProcessStep,
      @UI.hidden:true
  key MDChgProcessSrceSystem,
      @UI.hidden:true
  key MDChgProcessSrceObject,
      @EndUserText.label: 'Table Name'
  key MDChgProcessModelTableName,
      @EndUserText.label: 'Field Name'
  key MDChangeProcessModelFieldName,
      @UI.hidden:true
      @EndUserText.label: 'Object Identifier'
  key MDChgProcessRecordObjectID,
      @UI.hidden:true
  key cast( '147' as mdc_source_otc )          as MDChgProcessSrceObjectTypeCode,
      @EndUserText.label: 'Table'
      MDChangeProcModelTableDesc,
      @EndUserText.label: 'Field'
      MDChangeProcessModelFieldDesc,
      @EndUserText.label: 'Entity'
      @UI.hidden:true
      MDChgProcModelNodeExternalName,
      @EndUserText.label: 'Node'
      @UI.hidden: true
      MDChgProcModTableExternalName,
      @EndUserText.label: 'Field Name'
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPAPROCTP2_CALC_EXIT'
      @UI.hidden: true
      MDChgProcModFieldExternalName,
      @EndUserText.label: 'New Value'
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPAPROCTP2_CALC_EXIT'
      MDChgProcCurrentAttributeValue,
      @EndUserText.label: 'Old Value'
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPAPROCTP2_CALC_EXIT'
      MDChgProcPrevAttributeValue,
      @EndUserText.label: 'Is Changed'
      @UI.hidden:true
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPAPROCTP2_CALC_EXIT'
      MDChgProcessAttributeIsChanged,
      @UI.hidden:true
      @EndUserText.label: 'Change Type'
      MDChgProcessSourceModified,
      @EndUserText.label: 'Change Context'
      MDChgProcessRecordObjectText,

      //needed for DCL

      @UI.hidden:true
      IsBusinessPurposeCompleted,
      @UI.hidden:true
      AuthorizationGroup,
      @UI.hidden:true
      BusinessPartner,
      @UI.hidden:true
      DataControllerSet,
      //needed for relationship changes

      @UI.hidden:true
      cast ( '' as mdc_bprel_source_partner  ) as MDChgProcessSrceBusPart1,
      @UI.hidden:true
      cast ( '' as mdc_bprel_source_partner  ) as MDChgProcessSrceBusPart2,
      @UI.hidden:true
      AuthorizationGroup                       as BP1AuthorizationGroup,
      @UI.hidden:true
      AuthorizationGroup                       as BP2AuthorizationGroup,
      cast ('' as bu_reltyp )                  as RelationshipCategory
}

// Business Partner 1 in Relationship

union all select from I_BPRelshpProcessChangesUnion as Changes
  inner join          I_BusinessPartnerProcessTP    as BusinessPartner on  Changes.MasterDataChangeProcess = BusinessPartner.MasterDataChangeProcess
                                                                       and Changes.MDChgProcessStep        = BusinessPartner.MDChgProcessStep
                                                                       and Changes.MDChgProcessSrceSystem  = BusinessPartner.MDChgProcessSrceSystem
{
      //I_BPProcessChangesUnion

  key Changes.MasterDataChangeProcess,
  key Changes.MDChgProcessStep,
  key Changes.MDChgProcessSrceSystem,
  key BusinessPartner.MDChgProcessSrceObject,
  key Changes.MDChgProcessModelTableName,
  key Changes.MDChangeProcessModelFieldName,
  key Changes.MDChgProcessRecordObjectID,
  key cast( '1405' as mdc_source_otc ) as MDChgProcessSrceObjectTypeCode,
      Changes.MDChangeProcModelTableDesc,
      Changes.MDChangeProcessModelFieldDesc,
      Changes.MDChgProcModelNodeExternalName,
      Changes.MDChgProcModTableExternalName,
      Changes.MDChgProcModFieldExternalName,
      Changes.MDChgProcCurrentAttributeValue,
      Changes.MDChgProcPrevAttributeValue,
      Changes.MDChgProcessAttributeIsChanged,
      Changes.MDChgProcessSourceModified,
      Changes.MDChgProcessRecordObjectText,

      //needed for DCL

      BusinessPartner.IsBusinessPurposeCompleted,
      BusinessPartner.AuthorizationGroup,
      Changes.BusinessPartner1         as BusinessPartner,
      Changes.BP1DataControllerSet     as DataControllerSet,
      //needed for relationship changes

      Changes.MDChgProcessSrceBusPart1,
      Changes.MDChgProcessSrceBusPart2,
      Changes.BP1AuthorizationGroup,
      Changes.BP2AuthorizationGroup,
      Changes.RelationshipCategory
}
where
  Changes.MDChgProcessSrceBusPart1 = BusinessPartner.MDChgProcessSrceObject

// Business Partner 2 in Relationship

union all select from I_BPRelshpProcessChangesUnion as Changes
  inner join          I_BusinessPartnerProcessTP    as BusinessPartner on  Changes.MasterDataChangeProcess = BusinessPartner.MasterDataChangeProcess
                                                                       and Changes.MDChgProcessStep        = BusinessPartner.MDChgProcessStep
                                                                       and Changes.MDChgProcessSrceSystem  = BusinessPartner.MDChgProcessSrceSystem
{
      //I_BPProcessChangesUnion

  key Changes.MasterDataChangeProcess,
  key Changes.MDChgProcessStep,
  key Changes.MDChgProcessSrceSystem,
  key BusinessPartner.MDChgProcessSrceObject,
  key Changes.MDChgProcessModelTableName,
  key Changes.MDChangeProcessModelFieldName,
  key Changes.MDChgProcessRecordObjectID,
  key cast( '1405' as mdc_source_otc ) as MDChgProcessSrceObjectTypeCode,
      Changes.MDChangeProcModelTableDesc,
      Changes.MDChangeProcessModelFieldDesc,
      Changes.MDChgProcModelNodeExternalName,
      Changes.MDChgProcModTableExternalName,
      Changes.MDChgProcModFieldExternalName,
      Changes.MDChgProcCurrentAttributeValue,
      Changes.MDChgProcPrevAttributeValue,
      Changes.MDChgProcessAttributeIsChanged,
      Changes.MDChgProcessSourceModified,
      Changes.MDChgProcessRecordObjectText,

      //needed for DCL

      BusinessPartner.IsBusinessPurposeCompleted,
      BusinessPartner.AuthorizationGroup,
      Changes.BusinessPartner2         as BusinessPartner,
      Changes.BP2DataControllerSet     as DataControllerSet,
      //needed for relationship changes

      Changes.MDChgProcessSrceBusPart1,
      Changes.MDChgProcessSrceBusPart2,
      Changes.BP1AuthorizationGroup,
      Changes.BP2AuthorizationGroup,
      Changes.RelationshipCategory
}
where
  Changes.MDChgProcessSrceBusPart2 = BusinessPartner.MDChgProcessSrceObject

//Active Business Partner 1 in newly created Relationship

union all select from I_BPRelshpProcessChangesUnion as Changes
  inner join          I_BusinessPartnerProcessTP    as BusinessPartner on  Changes.MasterDataChangeProcess = BusinessPartner.MasterDataChangeProcess
                                                                       and Changes.MDChgProcessStep        = BusinessPartner.MDChgProcessStep

{
      //I_BPProcessChangesUnion

  key Changes.MasterDataChangeProcess,
  key Changes.MDChgProcessStep,
  key BusinessPartner.MDChgProcessSrceSystem,
  key BusinessPartner.MDChgProcessSrceObject,
  key Changes.MDChgProcessModelTableName,
  key Changes.MDChangeProcessModelFieldName,
  key Changes.MDChgProcessRecordObjectID,
  key cast( '1405' as mdc_source_otc ) as MDChgProcessSrceObjectTypeCode,
      Changes.MDChangeProcModelTableDesc,
      Changes.MDChangeProcessModelFieldDesc,
      Changes.MDChgProcModelNodeExternalName,
      Changes.MDChgProcModTableExternalName,
      Changes.MDChgProcModFieldExternalName,
      Changes.MDChgProcCurrentAttributeValue,
      Changes.MDChgProcPrevAttributeValue,
      Changes.MDChgProcessAttributeIsChanged,

      Changes.MDChgProcessSourceModified,
      Changes.MDChgProcessRecordObjectText,

      //needed for DCL

      BusinessPartner.IsBusinessPurposeCompleted,
      BusinessPartner.AuthorizationGroup,
      Changes.BusinessPartner1         as BusinessPartner,
      Changes.BP1DataControllerSet     as DataControllerSet,
      //needed for relationship changes

      Changes.MDChgProcessSrceBusPart1,
      Changes.MDChgProcessSrceBusPart2,
      Changes.BP1AuthorizationGroup,
      Changes.BP2AuthorizationGroup,
      Changes.RelationshipCategory
}
where
  (
      Changes.MDChgProcessSrceBusPart1       =  BusinessPartner.MDChgProcessSrceObject
  )
  and Changes.MDChgProcessSrceSystem         =  '-/-'
  and BusinessPartner.MDChgProcessSrceSystem <> '-/-'

//Active Business Partner 2 in newly created Relationship

union all select from I_BPRelshpProcessChangesUnion as Changes
  inner join          I_BusinessPartnerProcessTP    as BusinessPartner on  Changes.MasterDataChangeProcess = BusinessPartner.MasterDataChangeProcess
                                                                       and Changes.MDChgProcessStep        = BusinessPartner.MDChgProcessStep

{
      //I_BPProcessChangesUnion

  key Changes.MasterDataChangeProcess,
  key Changes.MDChgProcessStep,
  key BusinessPartner.MDChgProcessSrceSystem,
  key BusinessPartner.MDChgProcessSrceObject,
  key Changes.MDChgProcessModelTableName,
  key Changes.MDChangeProcessModelFieldName,
  key Changes.MDChgProcessRecordObjectID,
  key cast( '1405' as mdc_source_otc ) as MDChgProcessSrceObjectTypeCode,
      Changes.MDChangeProcModelTableDesc,
      Changes.MDChangeProcessModelFieldDesc,
      Changes.MDChgProcModelNodeExternalName,
      Changes.MDChgProcModTableExternalName,
      Changes.MDChgProcModFieldExternalName,
      Changes.MDChgProcCurrentAttributeValue,
      Changes.MDChgProcPrevAttributeValue,
      Changes.MDChgProcessAttributeIsChanged,
      Changes.MDChgProcessSourceModified,
      Changes.MDChgProcessRecordObjectText,

      //needed for DCL

      BusinessPartner.IsBusinessPurposeCompleted,
      BusinessPartner.AuthorizationGroup,
      Changes.BusinessPartner2         as BusinessPartner,
      Changes.BP2DataControllerSet     as DataControllerSet,
      //needed for relationship changes

      Changes.MDChgProcessSrceBusPart1,
      Changes.MDChgProcessSrceBusPart2,
      Changes.BP1AuthorizationGroup,
      Changes.BP2AuthorizationGroup,
      Changes.RelationshipCategory
}
where
  (
      Changes.MDChgProcessSrceBusPart2       =  BusinessPartner.MDChgProcessSrceObject
  )
  and Changes.MDChgProcessSrceSystem         =  '-/-'
  and BusinessPartner.MDChgProcessSrceSystem <> '-/-'