R_InsurClmFNOLTP

@AbapCatalog.extensibility.extensible
@AbapCatalog.extensibility.elementSuffix: 'FNO'
@AbapCatalog.extensibility.quota.maximumFields: 100
@AbapCatalog.extensibility.quota.maximumBytes: 1000
@AbapCatalog.extensibility.dataSources: ['_Extension']
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'FNOL Claim Header'
@Metadata.ignorePropagatedAnnotations: true
@VDM: {
  viewType:#TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}
@ObjectModel: {
   semanticKey: [ 'InsuranceClaim' ],
usageType:{
  dataClass:      #TRANSACTIONAL,
  serviceQuality: #C,
  sizeCategory:   #XL
}
}
@ObjectModel.sapObjectNodeType.name: 'InsuranceClaim'
define root view entity R_InsurClmFNOLTP
  as select from I_InsuranceClaim
  composition [0..*] of R_InsurClmFNOLDamagedObjectTP as _DamagedVehicle
  composition [0..*] of R_InsurClmFNOLNoteTP          as _Note
  composition [1..*] of R_InsurClmFNOLFactsOriginTP   as _Facts
  composition [0..*] of R_InsurClmFNOLWtnssTP         as _Witness
  composition [1..*] of R_InsurClmFNOLFactsLossLocTP  as _SFCLoss
  composition [1..*] of R_InsurClmFNOLClmntTP         as _Claimant
  composition [1..*] of R_InsurClmFNOLVehDriverTP     as _Driver
  composition [1..*] of R_InsurClmFNOLDiagnosisTP     as _Diagnosis
  composition [1..*] of R_InsurClmFNOLInjuredSFCTP   as _QuestionInjured
  composition [1..*] of R_InsurClmFNOLFactsDmgdVehTP as _QuestionsDmgdVeh
  composition [1..*] of R_InsurClmFNOLSrvcPrvdrTP as _ServiceProvider
  association [0..1] to I_Address_2                    as _LossLocationAddress on  $projection.InsurClmLossLocAddressID = _LossLocationAddress.AddressID
  association [1..1] to E_InsuranceClaim_2             as _Extension on  $projection.InsuranceClaim = _Extension.InsuranceClaim
{
  key InsuranceClaim,
      InsuranceContract,
      InsurClmPolicyProduct,
      ChangedOnDateTime,
      LastChangedByUser,
      CreationDateTime,
      CreatedByUser,
      InsurClmLifeCycSts,
      InsurClmStatReason,
      InsurClmType,
      InsurClmAuthznGrp,
      InsurClmPolicyProdGeneration,
      InsurClmPolicyProductVersion,
      InsurClmIncdntType,
      InsurClmDateOfLoss,
      InsurClmCauseOfLoss,
      InsurClmLossLocAddressID,
      InsurClmTypeGeneration,
      InsurClmTypeVers,
      InsurClmTimeOfLoss,
      InsurClmTimeZoneOfLoss,
      InsurClmContractLastRenewal,
      InsurClmVersionChangeTime,
      InsurClmAssignUUID,
      InsurClmComplexity,
      InsurClmJurisdictionCountry,
      InsurClmJurisdictionRegion,
      InsurClmCovered,
      InsurClmBenefitTypeTree,
      InsurClmBnftTypeTreeGeneration,
      InsurClmBnftTypeTreeVersion,
      InsurClmIsWithoutProduct,
      InsurClmIsDummyClaim,
      InsurClmReportedDate,
      InsurClmAgentReportedDate,
      InsurClmSensitiveClaim,
      InsuranceClaimDraftIdentifier,
      _LossLocationAddress.StreetName                                                               as InsurClmLossLocStreet,
      _LossLocationAddress.HouseNumber                                                              as InsurClmLossLocHouseNumber,
      _LossLocationAddress.CityName                                                                 as InsurClmLossLocCity,
      _LossLocationAddress.Region                                                                   as InsurClmLossLocRegion,
      _LossLocationAddress.PostalCode                                                               as InsurClmLossLocPostalCode,
      _LossLocationAddress.Country                                                                  as InsurClmLossLocCountry,
              
      /* Associations */
      _AllwdSubclmType,
      _PolicyProduct,
      _PolicySnapshot,
      _DamagedVehicle,
      _Note,
      _Facts,
      _Witness,
      _SFCLoss,
      _Claimant,
      _Driver,
      _Diagnosis,
      _QuestionInjured,
      _QuestionsDmgdVeh,
      _ServiceProvider
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS_2",
"I_INSURANCECLAIM"
],
"ASSOCIATED":
[
"I_INSURCLAIMPOLICYPRODUCT",
"I_INSURCLMPOLICYSNAPSHOT",
"I_INSURINTCLMTYPEALLWDSUBCLM",
"R_INSURCLMFNOLCLMNTTP",
"R_INSURCLMFNOLDAMAGEDOBJECTTP",
"R_INSURCLMFNOLDIAGNOSISTP",
"R_INSURCLMFNOLFACTSDMGDVEHTP",
"R_INSURCLMFNOLFACTSLOSSLOCTP",
"R_INSURCLMFNOLFACTSORIGINTP",
"R_INSURCLMFNOLINJUREDSFCTP",
"R_INSURCLMFNOLNOTETP",
"R_INSURCLMFNOLSRVCPRVDRTP",
"R_INSURCLMFNOLVEHDRIVERTP",
"R_INSURCLMFNOLWTNSSTP"
],
"BASE":
[
"I_INSURANCECLAIM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/