I_InsuranceClaim

@AbapCatalog.sqlViewName: 'INSURANCECLAIM'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Schaden-/Leistungsfall'
@VDM.viewType: #BASIC
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true

define view I_InsuranceClaim
  as select from iclclaim

  association [0..1] to I_InsurClaimPolicyProduct    as _PolicyProduct   on  $projection.InsurClmPolicyProduct        = _PolicyProduct.InsurClmPolicyProduct
                                                                         and $projection.InsurClmPolicyProdGeneration = _PolicyProduct.InsurClmPolicyProdGeneration
                                                                         and $projection.InsurClmPolicyProductVersion = _PolicyProduct.InsurClmPolicyProductVersion

  association [0..1] to I_InsurClmPolicySnapshot     as _PolicySnapshot  on  $projection.InsuranceClaim              = _PolicySnapshot.InsuranceClaim
                                                                         and _PolicySnapshot.InsurClmContractVersion = '00'

  association [0..*] to I_InsurIntClmTypeAllwdSubclm as _AllwdSubclmType on  $projection.InsurClmType           = _AllwdSubclmType.InsurClmType
                                                                         and $projection.InsurClmTypeGeneration = _AllwdSubclmType.InsurClmTypeGeneration
                                                                         and $projection.InsurClmTypeVers       = _AllwdSubclmType.InsurClmTypeVers
  //association [1..1] to E_InsuranceClaim             as _Extension       on  I_InsurClm1stNotif.insuranceclaim = _Extension.InsuranceClaim

  //and _Extension.InsurClmActive         = 'A'

{
  key claim                                                       as InsuranceClaim,
      policy                                                      as InsuranceContract,
      polprod                                                     as InsurClmPolicyProduct,
      cast( changetime as icl_achangetime_fiori preserving type ) as ChangedOnDateTime,
      changedby                                                   as LastChangedByUser,
      cast( createtime as icl_createutc_fiori   preserving type ) as CreationDateTime,
      createdby                                                   as CreatedByUser,
//      Missing field Added 06.07.2023

      achangedby                                                  as InsurClmWholeClmChgdBy,
      cast ( achangetime as icl_achangetime_fiori preserving type )   as  InsurClmWholeClmChgDteTme,
      exclaimnocat                                                as InsurClmExternalNumberCategory,
      cast( statuschg as timestamp)                               as InsurClmSubclmStsChgdOnDteTime,
      status                                                      as InsurClmLifeCycSts,
      cast ( statuschg as icl_achangetime_fiori preserving type ) as InsurClmStsChgdOnDteTime,
      lumpsumoption                                               as InsuranceClaimLumpSum,
      lumpsumoption                                               as InsuranceClaimIsLumpSum,
      withdrawam                                                  as InsurClmBndlWithdrawAmt,
      withdrawcurr                                                as InsurClmBndlWithdrawCrcy,
      withdrawseq                                                 as InsurClmBndlWthdrwlSqnc,
      sthandler                                                   as InsuranceClaimIsStatusHandler,
      stnoclaim                                                   as InsuranceClaimIsNoClaimMade,
      stclosed                                                    as InsuranceClaimIsStatusClosed,
      statreason                                                  as InsurClmStatReason,
      followup_dt                                                 as InsClmAutoResubmsnDte,
      claimtype                                                   as InsurClmType,
      authclm                                                     as InsurClmAuthznGrp,
      generat                                                     as InsurClmPolicyProdGeneration,
      version                                                     as InsurClmPolicyProductVersion,
      losstype                                                    as InsurClmIncdntType,
      dateloss                                                    as InsurClmDateOfLoss,
      losscause                                                   as InsurClmCauseOfLoss,
      lossaddress                                                 as InsurClmLossLocAddressID,
      cltypeg                                                     as InsurClmTypeGeneration,
      cltypev                                                     as InsurClmTypeVers,
      lossevent                                                   as InsuranceClaimBundleLossEvent,
      peril                                                       as InsuranceClaimReinsurancePeril,
      timeloss                                                    as InsurClmTimeOfLoss,
      ltimezone                                                   as InsurClmTimeZoneOfLoss,
      xdateestim                                                  as InsuranceClaimIsDateEstimate,
      datechanger                                                 as InsuranceClaimDateChangeReason,
      xauthrep                                                    as InsurClmIsRptdToAuth,
      cast( lrenewal   as icl_lrenewal_fiori   preserving type )  as InsurClmContractLastRenewal,
      cast( verchngutc as icl_verchngutc_fiori preserving type )  as InsurClmVersionChangeTime,
      assign_guid                                                 as InsurClmAssignUUID,
      complex                                                     as InsurClmComplexity,
      juriscountry                                                as InsurClmJurisdictionCountry,
      jurisregion                                                 as InsurClmJurisdictionRegion,
      assign_state                                                as InsurClmActyAssgmtSts,
      ownertype                                                   as InsuranceClaimOwnerType,
      owner                                                       as InsuranceClaimOwner,
      ownertype_grp                                               as InsuranceClaimOwnerTypeGroup,
      owner_grp                                                   as InsuranceClaimOwnerGroup,
      xcumul                                                      as InsuranceClaimIsCumulative,
      viewfault                                                   as InsuranceClaimViewFault,
      viewfaultph                                                 as InsurClmVwFaultPlcyHldr,
      xtpknown                                                    as InsurClmIsThirdPartyKnown,
      covered                                                     as InsurClmCovered,
      xclaimb                                                     as InsurClmIsEntrInPaytAmtAuthzns,
      xnonotif                                                    as InsuranceClaimIsNoNotif,
      xreserve                                                    as InsuranceClaimIsReserve,
      cast ( wf_exec_time as icl_lrenewal_fiori preserving type ) as InsurClmWrkflwExecDteTme,
      wf_status                                                   as InsurClmWorkflowStatus,
      opendate                                                    as InsurClmOpenDate,
      max_itemnr                                                  as InsuranceClaimMaxItemNumber,
      sif_status                                                  as InsurClmSecondInjuryFundStatus,
      invstg_status                                               as InsurClmIncdntInvstgnSts,
      effective_dt                                                as InsuranceClaimEffectiveDate,
      lossrep_dt                                                  as InsuranceClaimLossRepDate,
      statpension                                                 as InsurClmStatutoryPensionType,
      withdrawam                                                  as InsurClmWithdrawAmt,
      withdrawcurr                                                as InsurClmWithdrawCrcy,
      withdrawseq                                                 as InsurClmWthdrwlSqnc,
      alternateben                                                as InsuranceClaimAlternateBenefit,
      generatenotif                                               as InsuranceClaimSpecialRiskNotif,
      notifreason                                                 as InsuranceClaimNotifReason,
      autfollowup                                                 as InsuranceClaimAutoResubmission,
      followup_dt                                                 as InsuranceClaimFollowUpDate,
      processing_dt                                               as InsuranceClaimProcessingDate,
      statusobjid                                                 as InsuranceClaimStatusObjectNmbr,
      dunnlevel                                                   as InsuranceClaimDunningStatus,
      cleardate                                                   as InsuranceClaimClearDate,
      prembalanam                                                 as InsurClmPremiumBalanceAmount,
      prembalanamcurr                                             as InsurClmPremiumBalanceCurrency,
      withdrawtype                                                as InsuranceClaimWithdrawalType,
      react_dt                                                    as InsuranceClaimReactDate,
      cast ( gennotiftime  as icl_lrenewal_fiori preserving type ) as InsurClmSpecialRiskMsgDateTime,
      cast ( ben_calc_fail as icl_lrenewal_fiori preserving type )as InsurClmIncrrtBnftCalcDateTime,
      polsystem                                                   as InsuranceClaimPolicySystem,
      // Added BENTREE,BENTREEG,BENTREEV field for Claim item, Payment App - start - 20.10.2021

      bentree                                                     as InsurClmBenefitTypeTree,
      bentreeg                                                    as InsurClmBnftTypeTreeGeneration,
      bentreev                                                    as InsurClmBnftTypeTreeVersion,
      // Added BENTREE,BENTREEG,BENTREEV field for Claim item, Payment App - end - 20.10.2021

      xwithout_product                                            as InsurClmIsWithoutProduct,
      xdummyclaim                                                 as InsurClmIsDummyClaim,
      lossrepcompa                                                as InsurClmReportedDate,
      lossrepagent                                                as InsurClmAgentReportedDate,
      xsensitive                                                  as InsurClmSensitiveClaim,
      exclaimno                                                   as InsuranceClaimExternalNumber,
      //      Added for FNOL Claim Nr. to appear in FNOL RAP based Fiori app

      fnol_claimnr                                                as InsuranceClaimDraftIdentifier,
      archive_status                                              as InsurClmArchivingStatus,
      archive_flud                                                as InsurClmArchResubmsnDte,
      rejection                                                   as InsurClmArchRjcnRsn,
      _PolicyProduct,
      _PolicySnapshot,
      _AllwdSubclmType
}

where
      active  =  #icl_active.'A'
  and deleted <> #boole.'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ICLCLAIM"
],
"ASSOCIATED":
[
"I_INSURCLAIMPOLICYPRODUCT",
"I_INSURCLMPOLICYSNAPSHOT",
"I_INSURINTCLMTYPEALLWDSUBCLM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/