R_InsurClmFNOLClmntTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'FNOL Claimant Details'
@Metadata.ignorePropagatedAnnotations: true
@VDM: {
  viewType:#TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}
@ObjectModel: {
   semanticKey: [ 'InsuranceClaim' ],
usageType:{
  dataClass:      #TRANSACTIONAL,
  serviceQuality: #C,
  sizeCategory:   #XL
}
}
@ObjectModel.sapObjectNodeType.name: 'InsuranceClaim'
define view entity R_InsurClmFNOLClmntTP
  as select from I_InsurClmPrtcpntOccrnc
  //  association        to parent R_InsurClmFNOLDamagedObjectTP as _Damaged    on  $projection.InsuranceClaim    = _Damaged.InsuranceClaim

  //                                                                            and $projection.InsurClmSubobject = _Damaged.InsurClmDamagedObject

  association [0..1] to I_Region                       as _Region     on  $projection.Region  = _Region.Region
                                                                      and $projection.Country = _Region.Country
  association        to parent R_InsurClmFNOLTP        as _InsurClaim on  $projection.InsuranceClaim = _InsurClaim.InsuranceClaim
  association [0..1] to I_Country                      as _Country    on  _Country.Country = $projection.Country
  association [1..1] to I_InsurClmInjuredPersnRltnDets as _Injured    on  $projection.InsuranceClaim    = _Injured.InsuranceClaim
                                                                      and $projection.InsurClmSubobject = _Injured.InsurClmInjuredPersonNumber
  association [1..1] to E_InsuranceClaimParticipant    as _Extension  on  $projection.InsuranceClaim            = _Extension.InsuranceClaim
                                                                      and $projection.InsurClmSubobjectCategory = _Extension.InsurClmSubobjectCategory
                                                                      and $projection.InsurClmSubobject         = _Extension.InsurClmSubobject
                                                                      and $projection.InsurClmParticipantRole   = _Extension.InsurClmParticipantRole
                                                                      and $projection.BusinessPartner           = _Extension.BusinessPartner
{
  key I_InsurClmPrtcpntOccrnc.InsuranceClaim,
  key I_InsurClmPrtcpntOccrnc.BusinessPartner,
  key I_InsurClmPrtcpntOccrnc.InsurClmSubobjectCategory,
  key I_InsurClmPrtcpntOccrnc.InsurClmSubobject,
  key I_InsurClmPrtcpntOccrnc.InsurClmParticipantRole,
      I_InsurClmPrtcpntOccrnc.LastChangedByUser,
      I_InsurClmPrtcpntOccrnc.ChangedOnDateTime,
      I_InsurClmPrtcpntOccrnc.BusinessPartnerName,
      I_InsurClmPrtcpntOccrnc.FormOfAddress,
      I_InsurClmPrtcpntOccrnc.LastName,
      I_InsurClmPrtcpntOccrnc.FirstName,
      I_InsurClmPrtcpntOccrnc.StreetName,
      I_InsurClmPrtcpntOccrnc.HouseNumber,
      I_InsurClmPrtcpntOccrnc.CityName,
      I_InsurClmPrtcpntOccrnc.PostalCode,
      I_InsurClmPrtcpntOccrnc.Region,
      I_InsurClmPrtcpntOccrnc.Country,
      I_InsurClmPrtcpntOccrnc.PhoneNumber,
      I_InsurClmPrtcpntOccrnc.EmailAddress,
      I_InsurClmPrtcpntOccrnc.BirthDate,
      I_InsurClmPrtcpntOccrnc.GenderCodeName,
      I_InsurClmPrtcpntOccrnc.AuthorizationGroup,
      @Semantics.booleanIndicator: true
      I_InsurClmPrtcpntOccrnc.IsBusinessPurposeCompleted,
      _Injured.InsurClmRelationship                    as InsurClmRelationship,
      _Injured.InsurClmFatalInjury                     as InsurClmFatalInjury,
      _Injured.InsurClmImpairmentPercent               as InsurClmImpairmentPercent,
      _Injured.InsurClmIntraCompany                    as InsurClmIntraCompany,
      _Injured.InsurClmNoInsurance                     as InsurClmNoInsurance,
      _Injured._RelshpTypeTxt.InsurClmRelationshipText as InsurClmRelationshipText,
      _Injured.InsurClmInjuredPersnAddrTxt             as InsurClmInjuredPersnAddrTxt,
      _Injured.InsurClmInjuryInsurCompanyName          as InsurClmInjuryInsurCompanyName,
      /* Associations */
      I_InsurClmPrtcpntOccrnc._BusinessPartner,
      I_InsurClmPrtcpntOccrnc._Claim,
      //     _Damaged,

      _InsurClaim
}
where
  InsurClmParticipantRole = 'CLAI'
// and InsurClmSubobjectCategory = 'D'

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURCLMINJUREDPERSNRLTNDETS",
"I_INSURCLMPRTCPNTOCCRNC",
"I_INSURCLMPRTCPNTRELSHPTYPETXT"
],
"ASSOCIATED":
[
"I_INSURANCECLAIM",
"I_INSURCLM1STNOTIFBP",
"R_INSURCLMFNOLTP"
],
"BASE":
[
"I_INSURCLMPRTCPNTOCCRNC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/