R_InsurClmFNOLVehDriverTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'FNOL Driver details'
@Metadata.ignorePropagatedAnnotations: true
@VDM: {
  viewType:#TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}
@ObjectModel: {
   semanticKey: [ 'InsuranceClaim' ],
usageType:{
  dataClass:      #TRANSACTIONAL,
  serviceQuality: #C,
  sizeCategory:   #XL
}
}
@ObjectModel.sapObjectNodeType.name: 'InsuranceClaim'
define view entity R_InsurClmFNOLVehDriverTP
  as select from I_InsurClmPrtcpntOccrnc
  composition [1..*] of R_InsurClmFNOLDriverSFCTP   as _DriverQuestions
  association [1..1] to I_InsurClmParticipant       as _Part              on  $projection.InsuranceClaim  = _Part.InsuranceClaim
                                                                          and $projection.BusinessPartner = _Part.BusinessPartner
  //association        to parent R_InsurClmFNOLDamagedObjectTP as _Damaged on  $projection.InsuranceClaim        = _Damaged.InsuranceClaim

  //                                                                      and $projection.InsurClmDamagedObject = _Damaged.InsurClmDamagedObject

  association        to parent R_InsurClmFNOLTP            as _InsurClaim on  $projection.InsuranceClaim = _InsurClaim.InsuranceClaim
  association [1..1] to I_InsurClmPrtcpntOccrnc     as _InsuComp          on  $projection.InsuranceClaim          = _InsuComp.InsuranceClaim
                                                                          and _InsuComp.InsurClmSubobjectCategory = 'PA'
                                                                          and _InsuComp.InsurClmSubobject         = $projection.BusinessPartner
                                                                          and _InsuComp.InsurClmParticipantRole   = 'EXTI'
  association [1..1] to E_InsuranceClaimParticipant as _Extension         on  $projection.InsuranceClaim           = _Extension.InsuranceClaim
                                                                          and _Extension.InsurClmSubobjectCategory = 'C'
                                                                          and $projection.InsurClmDamagedObject    = _Extension.InsurClmSubobject
                                                                          and $projection.InsurClmParticipantRole  = _Extension.InsurClmParticipantRole
                                                                          and $projection.BusinessPartner          = _Extension.BusinessPartner
{
  key                 InsuranceClaim,
  key                 cast(InsurClmSubobject as icl_damobjau)          as InsurClmDamagedObject,
  key                 concat(InsurClmParticipantRole, BusinessPartner) as InsurFactsSubobject,
                      BusinessPartner,
                      BusinessPartner                                  as InsuranceClaimVehicleDriver,
                      //BusinessPartner                                                                      as BusinessPartnerForEdit,

                      BusinessPartner                                  as EmploymentBusinessPartner,
                      InsurClmParticipantRole,
                      LastChangedByUser,
                      ChangedOnDateTime,
                      _InsuComp.BusinessPartner                        as InsurClmDrvrInsuranceCompany,
                      _Part.InsurClmFNOLReferenceNumber,
                      @Semantics.name.fullName: true
                      BusinessPartnerName,
                      FormOfAddress,
                      @Semantics.booleanIndicator: true
                      cast( '' as abap.char(1) )                       as InsurClmVehDriverActionIsChkd,
                      @Semantics.booleanIndicator: true
                      cast ('' as abap.char(1))                        as InsurClmTransferDrvrIsNotChkd,
                      @Semantics.booleanIndicator: true
                      cast( '' as abap.char(1) )                       as InsurClmFNOLActionIsChkd,
                      @Semantics.name.familyName: true
                      LastName,
                      @Semantics.name.givenName: true
                      FirstName,
                      GenderCodeName,
                      @Semantics.address.street: true
                      StreetName,
                      @Semantics.address.number: true
                      HouseNumber,
                      @Semantics.address.city: true
                      CityName,
                      @Semantics.address.zipCode: true
                      PostalCode,
                      @Semantics.address.region: true
                      Region,
                      @Semantics.address.country: true
                      Country,
                      @Semantics.telephone.type: [#PREF]
                      PhoneNumber,
                      @Semantics.eMail.address: true
                      EmailAddress,
                      BirthDate,

                      _BusinessPartner,
                      _DriverQuestions,
                      //_Damaged,

                      _InsurClaim

}
where
       InsurClmSubobjectCategory = 'C'
  and(
       InsurClmParticipantRole   = 'DRI1'
    or InsurClmParticipantRole   = 'DRI3'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURCLMPARTICIPANT",
"I_INSURCLMPRTCPNTOCCRNC"
],
"ASSOCIATED":
[
"I_INSURCLM1STNOTIFBP",
"R_INSURCLMFNOLDRIVERSFCTP",
"R_INSURCLMFNOLTP"
],
"BASE":
[
"I_INSURCLMPRTCPNTOCCRNC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/