R_InsurClmFNOLFactsLossLocTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'FNOL SFC for Loss Location'
@Metadata.ignorePropagatedAnnotations: true
@VDM: {
  viewType:#TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}
@ObjectModel: {
   semanticKey: [ 'InsuranceClaim' ],
usageType:{
  dataClass:      #TRANSACTIONAL,
  serviceQuality: #C,
  sizeCategory:   #XL
}
}
@ObjectModel.sapObjectNodeType.name: 'InsuranceClaim'
define view entity R_InsurClmFNOLFactsLossLocTP as select from I_InsurClmFactCapture
association to parent R_InsurClmFNOLTP as _Claim on  $projection.InsuranceClaim = _Claim.InsuranceClaim
association [1..1] to E_InsurClmFactCapture   as _Extension  on $projection.InsuranceClaim    = _Extension.InsuranceClaim 
                                               and $projection.InsurClmFactCaptureCategory =  _Extension.InsurClmFactCaptureCategory
                                               and $projection.InsurClmSFCSubobj           =  _Extension.InsurClmSFCSubobj
                                               and $projection.InsurClmFactCaptureQstn     =  _Extension.InsurClmFactCaptureQstn
                                               and $projection.InsurClmFactCaptureAnswer   =  _Extension.InsurClmFactCaptureAnswer 
{
    key InsuranceClaim,
    key InsuranceContract,
    key InsurClmFactCaptureCategory,
    key InsurClmSubobject as InsurClmSFCSubobj,
    key InsurFactsSubobject,
    key InsurClmFactCaptureQstn,
    key InsurClmFactCaptureAnswer,
    _FactCaptureAnswer.InsurClmFactFreeTextAnswerCat                                     as InsurClmFactFreeTextAnswerCat,
    InsurClmFactCaptureSqncVariant,
    InsurClmFactCaptureQstnPos,
    InsurClmFactCaptureQstnSqnc,
    InsurClmFactCaptureSqncVersion,
    _FactCaptureQstn.InsurClmFactCaptureQstnCat                                          as InsurClmFactCaptureQstnCat,
      _FactCaptureQstn._FactCaptureQstnText[ Language = $session.system_language ].InsurClmFactCaptureQstnShrtTxt,
      _FactCaptureQstn._FactCaptureQstnText[ Language = $session.system_language ].InsurClmFactCaptureQstnLongTxt,
      _FactCaptureAnswer._FactCaptureAnswerT[ Language = $session.system_language ].InsurClmFactAnswerShortText,
      _FactCaptureAnswer._FactCaptureAnswerT[ Language = $session.system_language ].InsurClmFactAnswerLongText,
      _FactCaptureTxtAnswer. InsurClmFactCaptureTextAnswer,

      // Transient field to hold answer keys for user selected answers for a multiple choice question

      //     InsurClmFactCaptureTextAnswer as InsurClmFactUsrSeldAnswerKeys,

      _FactCaptureTxtAnswer.InsurClmFactCaptureTextAnswer                                  as InsurClmFactUsrSeldAnswerKeys,
      _FactCaptureQstn. InsurClmFactQstnIsMltplChoice,
      _FactCaptureAnswer. InsurClmFactCaptureNextQstn,
      cast('' as xfeld preserving type )                                                   as InsurClmIsHiddenFlag,
    /* Associations */
    _Claim,
    _FactCaptureAnswer,
    _FactCaptureQstn,
    _FactCaptureTxtAnswer
}
where
      InsurClmFactCaptureCategory = 'LO'
  and InsurFactsSubobject         = 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURCLMFACTCAPTURE",
"I_INSURCLMFACTCAPTUREANSWER",
"I_INSURCLMFACTCAPTUREANSWERT",
"I_INSURCLMFACTCAPTUREQSTN",
"I_INSURCLMFACTCAPTUREQSTNTEXT",
"I_INSURCLMFACTCAPTURETXTANSWER"
],
"ASSOCIATED":
[
"I_INSURCLMFACTCAPTUREANSWER",
"I_INSURCLMFACTCAPTUREQSTN",
"I_INSURCLMFACTCAPTURETXTANSWER",
"R_INSURCLMFNOLTP"
],
"BASE":
[
"I_INSURCLMFACTCAPTURE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/