R_ConditionDocument

@EndUserText.label: 'Condition Document'
@AccessControl: {
    authorizationCheck:     #MANDATORY,
    personalData.blocking:  #('TRANSACTIONAL_DATA'),
    privilegedAssociations: [  '_LastChangedByUser', '_CreatedByUser'  ]
    }
@ObjectModel: {
    representativeKey:        'ConditionDocument',
    usageType.serviceQuality: #B,
    usageType.dataClass:      #TRANSACTIONAL,
    usageType.sizeCategory:   #XXL
    }
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #SAP_INTERNAL_API
    }
@Metadata: {
    ignorePropagatedAnnotations: true,
    allowExtensions: false
    }

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view entity R_ConditionDocument
  as select from wcocoh

  association [0..*] to R_CndnDocBusVolSelCriteria   as _CndnDocBusVolSelCriteria      on  $projection.ConditionDocument = _CndnDocBusVolSelCriteria.ConditionDocument
  association [0..*] to R_CndnDocSettlmtCal          as _CndnDocSettlmtCal             on  $projection.ConditionDocument = _CndnDocSettlmtCal.ConditionDocument
  association [0..*] to R_ConditionDocumentItem      as _ConditionDocumentItem         on  $projection.ConditionDocument = _ConditionDocumentItem.ConditionDocument
  association [0..*] to R_CndnDocConditionUsage      as _CndnDocConditionUsage         on  $projection.ConditionDocument = _CndnDocConditionUsage.ConditionDocument

  association [0..1] to R_CndnContrType              as _CndnContrType                 on  $projection.CndnContrType = _CndnContrType.CndnContrType
  association [0..1] to I_CndnContrClassfctnType     as _CndnContrClassfctnType        on  $projection.CndnContrClassfctnType = _CndnContrClassfctnType.CndnContrClassfctnType
  association [0..1] to I_CndnContrProcVar           as _CndnContrProcVar              on  $projection.CndnContrProcVar = _CndnContrProcVar.CndnContrProcVar
  association [0..1] to I_CndnContrActvtnStatus      as _CndnDocActivationStatus       on  $projection.CndnDocActivationStatus = _CndnDocActivationStatus.CndnContrActvtnStatus

  /* Partners */
  association [0..1] to I_Supplier                   as _Supplier                      on  $projection.Supplier = _Supplier.Supplier
  association [0..1] to I_Customer                   as _Customer                      on  $projection.Customer = _Customer.Customer
  association [0..1] to I_Supplier                   as _PriorSupplier                 on  $projection.PriorSupplier = _PriorSupplier.Supplier
  association [0..1] to I_PersonWorkAgreement_1      as _PersonWorkAgreement           on  $projection.PersonWorkAgreement = _PersonWorkAgreement.PersonWorkAgreement

  /* Organizational Data */
  association [0..1] to I_CompanyCode                as _CompanyCode                   on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_PurchasingOrganization     as _PurchasingOrganization        on  $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization
  association [0..1] to I_PurchasingGroup            as _PurchasingGroup               on  $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup
  association [0..1] to I_SalesOrganization          as _SalesOrganization             on  $projection.SalesOrganization = _SalesOrganization.SalesOrganization
  association [0..1] to I_DistributionChannel        as _DistributionChannel           on  $projection.DistributionChannel = _DistributionChannel.DistributionChannel
  association [0..1] to I_Division                   as _Division                      on  $projection.Division = _Division.Division
  association [0..1] to I_SalesGroup                 as _SalesGroup                    on  $projection.SalesGroup = _SalesGroup.SalesGroup
  association [0..1] to I_SalesOffice                as _SalesOffice                   on  $projection.SalesOffice = _SalesOffice.SalesOffice

  /* Administrative Data */
  association [0..1] to I_User                       as _CreatedByUser                 on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                       as _LastChangedByUser             on  $projection.LastChangedByUser = _LastChangedByUser.UserID

  /* Currency and Exchange Rate */
  association [0..1] to I_Currency                   as _ConditionDocumentCurrency     on  $projection.ConditionDocumentCurrency = _ConditionDocumentCurrency.Currency
  association [0..1] to I_ExchangeRateType           as _ExchangeRateType              on  $projection.ExchangeRateType = _ExchangeRateType.ExchangeRateType

  association [0..1] to I_CndnContrSuplrSettlmtCat   as _CndnDocSuplrSettlmtCat        on  $projection.CndnDocSuplrSettlmtCat = _CndnDocSuplrSettlmtCat.CndnContrSuplrSettlmtCat
  association [0..1] to I_CndnContrCustSettlmtCat    as _CndnDocCustSettlmtCat         on  $projection.CndnDocCustSettlmtCat = _CndnDocCustSettlmtCat.CndnContrCustSettlmtCat
  association [0..1] to I_Product                    as _SettlmtProduct                on  $projection.SettlmtProduct = _SettlmtProduct.Product

  /* Calendars */
  association [0..1] to I_FactoryCalendar            as _FinalSettlmtCalendar          on  $projection.FinalSettlmtCalendar = _FinalSettlmtCalendar.FactoryCalendar
  association [0..1] to I_FactoryCalendar            as _PartialSettlmtCalendar        on  $projection.PartialSettlmtCalendar = _PartialSettlmtCalendar.FactoryCalendar
  association [0..1] to I_FactoryCalendar            as _DeltaSettlmtCalendar          on  $projection.DeltaSettlmtCalendar = _DeltaSettlmtCalendar.FactoryCalendar
  association [0..1] to I_FactoryCalendar            as _DeltaAccrualSettlmtCalendar   on  $projection.DeltaAccrualSettlmtCalendar = _DeltaAccrualSettlmtCalendar.FactoryCalendar
  association [0..1] to I_FactoryCalendar            as _AccrualClearingSettlmtCal     on  $projection.AccrualClearingSettlmtCalendar = _AccrualClearingSettlmtCal.FactoryCalendar
  association [0..1] to I_FactoryCalendar            as _CndnContrExtensionCalendar    on  $projection.CndnContrExtensionCalendar = _CndnContrExtensionCalendar.FactoryCalendar

  association [0..1] to I_BusVolTableGroup           as _BusVolTableGroup              on  $projection.BusVolTableGroup = _BusVolTableGroup.BusVolTableGroup
  association [0..1] to I_AmountFieldGroup           as _AmountFieldGroup              on  $projection.AmountFieldGroup = _AmountFieldGroup.AmountFieldGroup
  association [0..1] to I_UnitOfMeasure              as _ConditionDocumentUnit         on  $projection.ConditionDocumentUnit = _ConditionDocumentUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure              as _ConditionDocumentWeightUnit   on  $projection.ConditionDocumentWeightUnit = _ConditionDocumentWeightUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure              as _ConditionDocumentVolumeUnit   on  $projection.ConditionDocumentVolumeUnit = _ConditionDocumentVolumeUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure              as _CndnDocPointsQuantityUnit     on  $projection.CndnDocPointsQuantityUnit = _CndnDocPointsQuantityUnit.UnitOfMeasure

  association [0..1] to R_ConditionDocument          as _PrecedingConditionDocument    on  $projection.PrecedingConditionDocument = _PrecedingConditionDocument.ConditionDocument
  association [0..1] to I_CndnContrPurposeCat        as _CndnDocPurposeCategory        on  $projection.CndnDocPurposeCategory = _CndnDocPurposeCategory.CndnContrPurposeCat
  association [0..1] to I_CndnContrSourceDocCat      as _CndnDocSourceDocumentCategory on  $projection.CndnDocSourceDocumentCategory = _CndnDocSourceDocumentCategory.CndnContrSourceDocCat
  association [0..1] to I_CndnDocWorkerSettlmtCat    as _CndnDocWorkerSettlmtCat       on  $projection.CndnDocWorkerSettlmtCat = _CndnDocWorkerSettlmtCat.CndnDocWorkerSettlmtCat
  
  association [0..1] to I_CndnContrPrcgDetnRlvnceCat as _CndnDocPrcgDetnRlvnceCat      on  $projection.CndnDocPrcgDetnRlvnceCat = _CndnDocPrcgDetnRlvnceCat.CndnContrPrcgDetnRlvnceCat
  association [0..1] to R_BusVolTotAmtSpltCritraGrp  as _BusVolTotAmtSpltCritraGrp     on  $projection.BusVolTotAmtSpltCritraGrp = _BusVolTotAmtSpltCritraGrp.BusVolTotAmtSpltCritraGrp

  /* Tax */
  association [0..1] to I_Country                    as _TaxCountry                    on  $projection.TaxCountry = _TaxCountry.Country
  association [0..1] to I_Country                    as _SettlmtPartTxRegnCntry        on  $projection.SettlmtPartTxRegnCntry = _SettlmtPartTxRegnCntry.Country

  association [0..1] to I_CndnContrPartnerCat        as _CndnContrPartnerCat           on  $projection.CndnContrPartnerCat = _CndnContrPartnerCat.CndnContrPartnerCat
  association [0..1] to I_CndnContrSettlmtType       as _CndnContrSettlmtType          on  $projection.CndnContrSettlmtType = _CndnContrSettlmtType.CndnContrSettlmtType
  association [0..1] to I_CndnContrProcessCategory   as _CndnContrProcessCategory      on  $projection.CndnContrProcessCategory = _CndnContrProcessCategory.CndnContrProcessCategory

  /* Worker related fields */
  association [0..1] to I_CostCenter                 as _CndnDocWorkerCostCenter       on  $projection.CndnDocWorkerCostCenter        = _CndnDocWorkerCostCenter.CostCenter
                                                                                       and $projection.CndnDocWrkrControllingArea     = _CndnDocWorkerCostCenter.ControllingArea
                                                                                       and _CndnDocWorkerCostCenter.ValidityEndDate   >= $projection.ConditionDocumentValidToDate
                                                                                       and _CndnDocWorkerCostCenter.ValidityStartDate <= $projection.ConditionDocumentValidToDate
  association [0..1] to I_ControllingArea            as _CndnDocWrkrControllingArea    on  $projection.CndnDocWrkrControllingArea = _CndnDocWrkrControllingArea.ControllingArea

{

  key cast( num as wcb_condition_document preserving type )                  as ConditionDocument,
      @ObjectModel.foreignKey.association: '_CndnContrType'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_CndnContrTypeStdVH', element: 'CndnContrType' } }]
      }
      cast( contract_type as wcb_contract_type preserving type )             as CndnContrType,
      @ObjectModel.foreignKey.association: '_CndnContrClassfctnType'
      category                                                               as CndnContrClassfctnType,
      @ObjectModel.foreignKey.association: '_CndnContrProcVar'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_CndnContrProcVarStdVH', element: 'CndnContrProcVar' } }]
      }
      process_variant                                                        as CndnContrProcVar,
      reference                                                              as DocumentReferenceID,
      assignment                                                             as CndnDocAssignmentReference,
      ext_num                                                                as ExternalDocumentReferenceID,
      ext_partner                                                            as CndnDocExternalPartner,
      @ObjectModel.foreignKey.association: '_CndnDocActivationStatus'
      cast( deact as wcb_cc_state preserving type )                          as CndnDocActivationStatus,

      /* Validity */
      @Semantics.businessDate.from: true
      date_from                                                              as ConditionDocumentValidFromDate,
      @Semantics.businessDate.to: true
      date_to                                                                as ConditionDocumentValidToDate,

      /* Partners */
      @ObjectModel.foreignKey.association: '_Supplier'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_Supplier_VH', element: 'Supplier' } }]
      }
      cast( vend_owner as wcb_vend_owner preserving type )                   as Supplier,
      @ObjectModel.foreignKey.association: '_Customer'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_Customer_VH', element: 'Customer' } }]
      }
      cast( cust_owner as wcb_cust_owner preserving type )                   as Customer,
      @ObjectModel.foreignKey.association: '_PriorSupplier'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_Supplier_VH', element: 'Supplier' } }]
      }
      kolif                                                                  as PriorSupplier,
      @Consumption:{
        valueHelpDefinition: [{ entity: { name:'I_PersWrkAgrmtSrchHelp_1' , element: 'PersonWorkAgreement' } }]
      }
      person_owner                                                           as PersonWorkAgreement,

      /* Organizational Data */
      @ObjectModel.foreignKey.association: '_CompanyCode'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } }]
      }
      cast( bukrs as bukrs preserving type )                                 as CompanyCode,
      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
      ekorg                                                                  as PurchasingOrganization,
      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      ekgrp                                                                  as PurchasingGroup,
      @ObjectModel.foreignKey.association: '_SalesOrganization'
      cast( vkorg as vkorg preserving type )                                 as SalesOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      cast( vtweg as vtweg  preserving type )                                as DistributionChannel,
      @ObjectModel.foreignKey.association: '_Division'
      cast( spart as spart preserving type )                                 as Division,
      @ObjectModel.foreignKey.association: '_Salesgroup'
      vkgrp                                                                  as SalesGroup,
      @ObjectModel.foreignKey.association: '_SalesOffice'
      vkbur                                                                  as SalesOffice,

      /* Administrative Data */
      @Semantics.user.createdBy: true
      created_by                                                             as CreatedByUser,
      @Semantics.systemDate.createdAt: true
      created_on                                                             as CreationDate,
      rec_time                                                               as CreationTime,
      zonlo                                                                  as CreationTimeZone,
      @Semantics.systemDateTime.createdAt: true
      created_on_tstmp                                                       as CreationUTCDateTime,
      @Semantics.user.lastChangedBy: true
      ch_name                                                                as LastChangedByUser,
      @Semantics.systemDate.lastChangedAt: true
      ch_date                                                                as LastChangedDate,
      ch_time                                                                as LastChangeTime,
      @Semantics.systemDateTime.lastChangedAt: true
      ch_tstmp                                                               as LastChangeUTCDateTime,

      /* Currency and Exchange Rate */
      @ObjectModel.foreignKey.association: '_ConditionDocumentCurrency'
      cast( cc_curr as wcb_cndn_doc_curr preserving type )                   as ConditionDocumentCurrency,
      cast( rate as wlf_wcb_wkurs_no_cnext preserving type )                 as ExchangeRate,
      @ObjectModel.foreignKey.association: '_ExchangeRateType'
      rate_type                                                              as ExchangeRateType,
      rate_date                                                              as ExchangeRateDate,

      /* Payment terms and method */
      zterm                                                                  as PaymentTerms,
      cast( zbd1t as wlf_dzbdet preserving type )                            as CashDiscount1Days,
      cast( zbd1p as wlf_dzbd1p preserving type )                            as CashDiscount1Percent,
      cast( zbd2t as wlf_dzbd2t preserving type )                            as CashDiscount2Days,
      cast( zbd2p as wlf_dzbd2p preserving type )                            as CashDiscount2Percent,
      cast( zbd3t as wlf_dzbd3t preserving type )                            as NetPaymentDays,
      zlsch                                                                  as PaymentMethod,

      @ObjectModel.foreignKey.association: '_CndnDocSuplrSettlmtCat'
      cast( settl_type_vend as wb2_supplier_settlement_cat preserving type ) as CndnDocSuplrSettlmtCat,
      @ObjectModel.foreignKey.association: '_CndnDocCustSettlmtCat'
      cast( settl_type_cust as wb2_customer_settlement_cat preserving type ) as CndnDocCustSettlmtCat,
      @ObjectModel.foreignKey.association: '_SettlmtProduct'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_ProductVH', element: 'Product' } }]
      }
      cast( settl_matnr as wb2_settlement_product preserving type )          as SettlmtProduct,

      /* Calendars */
      @ObjectModel.foreignKey.association: '_FinalSettlmtCalendar'
      settl_cal_final                                                        as FinalSettlmtCalendar,
      @ObjectModel.foreignKey.association: '_PartialSettlmtCalendar'
      settl_cal_part                                                         as PartialSettlmtCalendar,
      @ObjectModel.foreignKey.association: '_DeltaSettlmtCalendar'
      settl_cal_delta                                                        as DeltaSettlmtCalendar,
      @ObjectModel.foreignKey.association: '_DeltaAccrualSettlmtCalendar'
      settl_cal_accr                                                         as DeltaAccrualSettlmtCalendar,
      @ObjectModel.foreignKey.association: '_AccrualClearingSettlmtCal'
      settl_cal_accr_rollo                                                   as AccrualClearingSettlmtCalendar,
      @ObjectModel.foreignKey.association: '_CndnContrExtensionCalendar'
      extension_cal                                                          as CndnContrExtensionCalendar,

      @ObjectModel.foreignKey.association: '_PrecedingConditionDocument'
      pred_cc                                                                as PrecedingConditionDocument,
      @ObjectModel.foreignKey.association: '_CndnDocPurposeCategory'
      cc_purpose                                                             as CndnDocPurposeCategory,

      /* Source Document */
      @ObjectModel.foreignKey.association: '_CndnDocSourceDocumentCategory'
      ext_ref_cat                                                            as CndnDocSourceDocumentCategory,
      ext_ref                                                                as CndnDocSourceDocument,
      ext_ref_item                                                           as CndnDocSourceDocumentItem,

      @ObjectModel.foreignKey.association: '_BusVolTableGroup'
      bvtab_group                                                            as BusVolTableGroup,
      @ObjectModel.foreignKey.association: '_AmountFieldGroup'
      af_group                                                               as AmountFieldGroup,

      /* Units */
      @ObjectModel.foreignKey.association: '_ConditionDocumentUnit'
      settl_meins                                                            as ConditionDocumentUnit,
      @ObjectModel.foreignKey.association: '_ConditionDocumentWeightUnit'
      settl_gewei                                                            as ConditionDocumentWeightUnit,
      @ObjectModel.foreignKey.association: '_ConditionDocumentVolumeUnit'
      settl_voleh                                                            as ConditionDocumentVolumeUnit,
      @ObjectModel.foreignKey.association: '_CndnDocPointsQuantityUnit'
      settl_punei                                                            as CndnDocPointsQuantityUnit,

      accruals_upd_req                                                       as AccrualUpdateIsRequired,

      /* UUIDs */
      cast( guid as wcb_cndn_doc_uuid preserving type )                      as ConditionDocumentUUID,
      cast( ext_guid as wcb_cndn_doc_source_uuid preserving type )           as ConditionDocumentSourceUUID,

      /* Tax */
      @ObjectModel.foreignKey.association: '_TaxCountry'
      tax_reporting_country                                                  as TaxCountry,
      @ObjectModel.foreignKey.association: '_SettlmtPartTxRegnCntry'
      tax_country                                                            as SettlmtPartTxRegnCntry,

      /* VAT Registration */
      stceg                                                                  as SettlmtPartTxRegnNmbr,

      @ObjectModel.foreignKey.association: '_CndnDocPrcgDetnRlvnceCat'
      coco_det_rel_contr                                                     as CndnDocPrcgDetnRlvnceCat,
      @ObjectModel.foreignKey.association: '_BusVolTotAmtSpltCritraGrp'
      afsc_group                                                             as BusVolTotAmtSpltCritraGrp,

      num_basic_contract                                                     as BasicConditionContract,

      @ObjectModel.foreignKey.association: '_CndnContrPartnerCat'
      owner_type                                                             as CndnContrPartnerCat,
      @ObjectModel.foreignKey.association: '_CndnContrProcessCategory'
      process_category                                                       as CndnContrProcessCategory,
      @ObjectModel.foreignKey.association: '_CndnContrSettlmtType'
      cast( rebate_type as wb2_rebate_type_fio preserving type )             as CndnContrSettlmtType,

      /* Worker related fields */
      pers_kostl                                                             as CndnDocWorkerCostCenter,
      pers_kokrs                                                             as CndnDocWrkrControllingArea,
      settl_type_person                                                      as CndnDocWorkerSettlmtCat,

      /* SAP Object Node Type abbreviation and object semantics */
      sont_abbrv_h                                                           as CndnDocObjNodeTypeAbbr,
      semantic_type_h                                                        as CndnDocSemanticCode,

      data_controller                                                        as DataController,

      /* Associations */
      _CndnDocBusVolSelCriteria,
      _CndnDocSettlmtCal,
      _ConditionDocumentItem,
      _CndnDocConditionUsage,
      _CndnContrType,
      _CndnContrClassfctnType,
      _CndnContrProcVar,
      _CndnDocActivationStatus,
      _Supplier,
      _Customer,
      _PriorSupplier,
      _PersonWorkAgreement,
      _CompanyCode,
      _PurchasingOrganization,
      _PurchasingGroup,
      _SalesOrganization,
      _DistributionChannel,
      _Division,
      _SalesGroup,
      _SalesOffice,
      _CreatedByUser,
      _LastChangedByUser,
      _ConditionDocumentCurrency,
      _ExchangeRateType,
      _CndnDocSuplrSettlmtCat,
      _CndnDocCustSettlmtCat,
      _SettlmtProduct,
      _FinalSettlmtCalendar,
      _PartialSettlmtCalendar,
      _DeltaSettlmtCalendar,
      _DeltaAccrualSettlmtCalendar,
      _AccrualClearingSettlmtCal,
      _CndnContrExtensionCalendar,
      _PrecedingConditionDocument,
      _CndnDocPurposeCategory,
      _CndnDocSourceDocumentCategory,
      _BusVolTableGroup,
      _AmountFieldGroup,
      _ConditionDocumentUnit,
      _ConditionDocumentWeightUnit,
      _ConditionDocumentVolumeUnit,
      _CndnDocPointsQuantityUnit,
      _TaxCountry,
      _SettlmtPartTxRegnCntry,
      _CndnDocPrcgDetnRlvnceCat,
      _BusVolTotAmtSpltCritraGrp,
      _CndnContrPartnerCat,
      _CndnContrProcessCategory,
      _CndnContrSettlmtType,
      _CndnDocWorkerCostCenter,
      _CndnDocWrkrControllingArea,
      _CndnDocWorkerSettlmtCat      

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"WCOCOH"
],
"ASSOCIATED":
[
"I_AMOUNTFIELDGROUP",
"I_BUSVOLTABLEGROUP",
"I_CNDNCONTRACTVTNSTATUS",
"I_CNDNCONTRCLASSFCTNTYPE",
"I_CNDNCONTRCUSTSETTLMTCAT",
"I_CNDNCONTRPARTNERCAT",
"I_CNDNCONTRPRCGDETNRLVNCECAT",
"I_CNDNCONTRPROCESSCATEGORY",
"I_CNDNCONTRPROCVAR",
"I_CNDNCONTRPURPOSECAT",
"I_CNDNCONTRSETTLMTTYPE",
"I_CNDNCONTRSOURCEDOCCAT",
"I_CNDNCONTRSUPLRSETTLMTCAT",
"I_CNDNDOCWORKERSETTLMTCAT",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTER",
"I_COUNTRY",
"I_CURRENCY",
"I_CUSTOMER",
"I_DISTRIBUTIONCHANNEL",
"I_DIVISION",
"I_EXCHANGERATETYPE",
"I_FACTORYCALENDAR",
"I_PERSONWORKAGREEMENT_1",
"I_PRODUCT",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_SALESGROUP",
"I_SALESOFFICE",
"I_SALESORGANIZATION",
"I_SUPPLIER",
"I_UNITOFMEASURE",
"I_USER",
"R_BUSVOLTOTAMTSPLTCRITRAGRP",
"R_CNDNCONTRTYPE",
"R_CNDNDOCBUSVOLSELCRITERIA",
"R_CNDNDOCCONDITIONUSAGE",
"R_CNDNDOCSETTLMTCAL",
"R_CONDITIONDOCUMENT",
"R_CONDITIONDOCUMENTITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/