R_CndnDocConditionUsage

@AbapCatalog: {
  sqlViewName: 'RWLFCDCNDUSAGE',
  compiler.compareFilter: true,
  viewEnhancementCategory: [#NONE],
  dataMaintenance: #DISPLAY_ONLY
}
@EndUserText.label: 'Condition Document Condition Usage'
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
  representativeKey: 'DocRelationshipUUID',
  usageType: {
    dataClass:      #TRANSACTIONAL,
    serviceQuality: #B,
    sizeCategory:   #XXL
  }
}
@ClientHandling: {
  type: #INHERITED,
  algorithm: #SESSION_VARIABLE
}
@Metadata: {
  ignorePropagatedAnnotations: true
}

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view R_CndnDocConditionUsage
  as select from P_CndnContrCndnUsgeMatlDocs

  association [0..1] to R_ConditionDocument   as _ConditionDocument    on  $projection.ConditionDocument = _ConditionDocument.ConditionDocument

  association [0..1] to I_BillingDocument     as _BillingDocument      on  $projection.BillingDocument = _BillingDocument.BillingDocument
  association [0..1] to I_BillingDocumentItem as _BillingDocumentItem  on  $projection.BillingDocument     = _BillingDocumentItem.BillingDocument
                                                                       and $projection.BillingDocumentItem = _BillingDocumentItem.BillingDocumentItem
  association [0..1] to I_CndnContrAccrSource as _CndnDocAccrualSource on  $projection.CndnDocAccrualSource = _CndnDocAccrualSource.CndnContrAccrSource

{
  key DocRelationshipUUID,
      PricingDocument,
      PricingProcedureStep,
      PricingProcedureCounter,

      cast ( ConditionContract as wcb_condition_document preserving type ) as ConditionDocument,
      cast ( CndnContrUUID as wcb_cndn_doc_uuid preserving type )          as ConditionDocumentUUID,
      ConditionRecord,
      ConditionSequentialNumberShort,
      CndnContrAccrRvslSts                                                 as CndnDocAccrReversalStatus,

      /* Accrual Source Document - Generic*/
      AccrSrceDocCategory,
      AccrSrceDocument,
      AccrSrceDocumentYear,
      AccrSrceDocumentItem,
      ConditionApplication,
      ConditionType,
      @Semantics.amount.currencyCode: 'AccrSrceDocCurrency'
      @Aggregation.default: #SUM
      ConditionAmount,
      @Semantics.currencyCode: true
      AccrSrceDocCurrency,
      AccrSrceDocPostingDate,
      SettlmtDate,
      SettlmtDateSequentialID,
      RefSettlmtDate,
      RefSettlmtDateSequentialID,
      AccrSrceDocFiscalYear,
      AccrSrceDocItemPlant,
      AccrSrceDocCompanyCode,

      cast( '1' as wb2_accruals_source )                                   as CndnDocAccrualSource,

      /* Material Document*/
      MaterialDocument,
      MaterialDocumentYear,
      MaterialDocumentItem,

      /* Settlement Management Document*/
      cast( '          ' as wbeln_ag preserving type )                     as SettlmtMgmtDoc,
      cast( '000000' as wposnr_lf preserving type )                        as SettlmtMgmtDocItem,

      /* Billing Document*/
      cast( '          ' as vbeln_vf preserving type )                     as BillingDocument,
      cast( '000000' as posnr_vf preserving type )                         as BillingDocumentItem,

      /* Associations */
      _BillingDocument,
      _BillingDocumentItem,

      _AccrSrceDocCompanyCode,
      _AccrSrceDocCurrency,
      _AccrSrceDocItemPlant,
      _CndnDocAccrualSource                                                as _CndnDocAccrualSource,
      _CndnContrAccrRvslSts                                                as _CndnDocAccrReversalStatus,
      _ConditionApplication,
      _ConditionDocument,
      _ConditionType
}
union all select from P_CndnContrCndnUsgeSetlMgmtDoc

association [0..1] to R_ConditionDocument   as _ConditionDocument    on  $projection.ConditionDocument = _ConditionDocument.ConditionDocument

association [0..1] to I_BillingDocument     as _BillingDocument      on  $projection.BillingDocument = _BillingDocument.BillingDocument
association [0..1] to I_BillingDocumentItem as _BillingDocumentItem  on  $projection.BillingDocument     = _BillingDocumentItem.BillingDocument
                                                                     and $projection.BillingDocumentItem = _BillingDocumentItem.BillingDocumentItem
association [0..1] to I_CndnContrAccrSource as _CndnDocAccrualSource on  $projection.CndnDocAccrualSource = _CndnDocAccrualSource.CndnContrAccrSource

{
  key DocRelationshipUUID,
      PricingDocument,
      PricingProcedureStep,
      PricingProcedureCounter,

      cast ( ConditionContract as wcb_condition_document preserving type ) as ConditionDocument,
      cast ( CndnContrUUID as wcb_cndn_doc_uuid preserving type )          as ConditionDocumentUUID,
      ConditionRecord,
      ConditionSequentialNumberShort,
      CndnContrAccrRvslSts                                                 as CndnDocAccrReversalStatus,

      /* Accrual Source Document - Generic*/
      AccrSrceDocCategory,
      AccrSrceDocument,
      AccrSrceDocumentYear,
      AccrSrceDocumentItem,
      ConditionApplication,
      ConditionType,
      @Semantics.amount.currencyCode: 'AccrSrceDocCurrency'
      @Aggregation.default: #SUM
      ConditionAmount,
      @Semantics.currencyCode: true
      AccrSrceDocCurrency,
      AccrSrceDocPostingDate,
      SettlmtDate,
      SettlmtDateSequentialID,
      RefSettlmtDate,
      RefSettlmtDateSequentialID,
      AccrSrceDocFiscalYear,
      AccrSrceDocItemPlant,
      AccrSrceDocCompanyCode,

      CndnContrAccrSource                                                  as CndnDocAccrualSource,

      /* Material Document*/
      cast( '          '  as mblnr preserving type )                       as MaterialDocument,
      cast( '0000' as mjahr preserving type  )                             as MaterialDocumentYear,
      cast( '0000' as mblpo preserving type )                              as MaterialDocumentItem,

      /* Settlement Management Document*/
      SettlmtMgmtDoc,
      SettlmtMgmtDocItem,

      /* Billing Document*/
      cast( '          ' as vbeln_vf preserving type )                     as BillingDocument,
      cast( '000000' as posnr_vf preserving type )                         as BillingDocumentItem,

      /* Associations */
      _BillingDocument,
      _BillingDocumentItem,

      _AccrSrceDocCompanyCode,
      _AccrSrceDocCurrency,
      _AccrSrceDocItemPlant,
      _CndnDocAccrualSource                                                as _CndnDocAccrualSource,
      _CndnContrAccrRvslSts                                                as _CndnDocAccrReversalStatus,
      _ConditionApplication,
      _ConditionDocument,
      _ConditionType
}
union all select from P_CndnContrCndnUsgeBillgDocs

association [0..1] to R_ConditionDocument   as _ConditionDocument    on  $projection.ConditionDocument = _ConditionDocument.ConditionDocument

association [0..1] to I_BillingDocument     as _BillingDocument      on  $projection.BillingDocument = _BillingDocument.BillingDocument
association [0..1] to I_BillingDocumentItem as _BillingDocumentItem  on  $projection.BillingDocument     = _BillingDocumentItem.BillingDocument
                                                                     and $projection.BillingDocumentItem = _BillingDocumentItem.BillingDocumentItem
association [0..1] to I_CndnContrAccrSource as _CndnDocAccrualSource on  $projection.CndnDocAccrualSource = _CndnDocAccrualSource.CndnContrAccrSource

{
  key DocRelationshipUUID,
      PricingDocument,
      PricingProcedureStep,
      PricingProcedureCounter,

      cast ( ConditionContract as wcb_condition_document preserving type ) as ConditionDocument,
      cast ( CndnContrUUID as wcb_cndn_doc_uuid preserving type )          as ConditionDocumentUUID,
      ConditionRecord,
      ConditionSequentialNumberShort,
      CndnContrAccrRvslSts                                                 as CndnDocAccrReversalStatus,

      /* Accrual Source Document - Generic*/
      AccrSrceDocCategory,
      AccrSrceDocument,
      AccrSrceDocumentYear,
      AccrSrceDocumentItem,
      ConditionApplication,
      ConditionType,
      @Semantics.amount.currencyCode: 'AccrSrceDocCurrency'
      @Aggregation.default: #SUM
      ConditionAmount,
      @Semantics.currencyCode: true
      AccrSrceDocCurrency,
      AccrSrceDocPostingDate,
      SettlmtDate,
      SettlmtDateSequentialID,
      RefSettlmtDate,
      RefSettlmtDateSequentialID,
      AccrSrceDocFiscalYear,
      AccrSrceDocItemPlant,
      AccrSrceDocCompanyCode,

      cast( '1' as wb2_accruals_source )                                   as CndnDocAccrualSource,

      /* Material Document*/
      cast( '          '  as mblnr preserving type )                       as MaterialDocument,
      cast( '0000' as mjahr preserving type  )                             as MaterialDocumentYear,
      cast( '0000' as mblpo preserving type )                              as MaterialDocumentItem,

      /* Settlement Management Document*/
      cast( '          '  as wbeln_ag preserving type )                    as SettlmtMgmtDoc,
      cast( '000000' as wposnr_lf preserving type )                        as SettlmtMgmtDocItem,

      /* Billing Document*/
      BillingDocument,
      BillingDocumentItem,

      /* Associations */
      _BillingDocument,
      _BillingDocumentItem,

      _AccrSrceDocCompanyCode,
      _AccrSrceDocCurrency,
      _AccrSrceDocItemPlant,
      _CndnDocAccrualSource                                                as _CndnDocAccrualSource,
      _CndnContrAccrRvslSts                                                as _CndnDocAccrReversalStatus,
      _ConditionApplication,
      _ConditionDocument,
      _ConditionType
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_CNDNCONTRCNDNUSGEBILLGDOCS",
"P_CNDNCONTRCNDNUSGEMATLDOCS",
"P_CNDNCONTRCNDNUSGESETLMGMTDOC"
],
"ASSOCIATED":
[
"I_BILLINGDOCUMENT",
"I_BILLINGDOCUMENTITEM",
"I_CNDNCONTRACCRRVSLSTS",
"I_CNDNCONTRACCRSOURCE",
"I_COMPANYCODE",
"I_CONDITIONAPPLICATION",
"I_CURRENCY",
"I_PLANT",
"I_PRICINGCONDITIONTYPE",
"R_CONDITIONDOCUMENT"
],
"BASE":
[
"P_CNDNCONTRCNDNUSGEMATLDOCS"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/