I_CndnContrProcVar

@AbapCatalog: {
  sqlViewName: 'IWCBCCPROCVAR',
  compiler.compareFilter: true,
  buffering: {
    status: #ACTIVE,
    type: #GENERIC,
    numberOfKeyFields: 001
  },
  preserveKey: true
}
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #NOT_REQUIRED
}
@ObjectModel: {
  representativeKey: 'CndnContrProcVar',
  modelingPattern: #ANALYTICAL_DIMENSION,
  supportedCapabilities: [#ANALYTICAL_DIMENSION, 
                          #CDS_MODELING_DATA_SOURCE, 
                          #CDS_MODELING_ASSOCIATION_TARGET, 
                          #SQL_DATA_SOURCE],
  usageType: {
    dataClass:      #CUSTOMIZING,
    serviceQuality: #B,
    sizeCategory:   #S
  }
}
@ClientHandling: {
     type: #INHERITED,
     algorithm: #SESSION_VARIABLE
}
@Analytics: {
    dataCategory: #DIMENSION,
    dataExtraction.enabled: false,
    internalName: #LOCAL
}
@EndUserText.label: 'Condition Contract Process Variant'
@Metadata.ignorePropagatedAnnotations: true

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_CndnContrProcVar
  as select from wcb_c_proc_var

  association [0..*] to I_CndnContrProcVarText       as _Text                       on  $projection.CndnContrProcVar = _Text.CndnContrProcVar
  association [0..1] to I_CndnContrApprvlProc        as _CndnContrApprvlProc        on  $projection.CndnContrApprvlProc = _CndnContrApprvlProc.CndnContrApprvlProc
  association [0..1] to I_SettlmtApplStsGrp          as _SettlmtApplStsGrp          on  $projection.SettlmtApplStsGrp = _SettlmtApplStsGrp.SettlmtApplStsGrp
  association [0..1] to I_SettlmtApplSts             as _SettlmtApplSts             on  $projection.SettlmtDfltApplSts = _SettlmtApplSts.SettlmtApplSts
  association [0..1] to I_SettlmtApplStsGrpStsAssgmt as _SettlmtApplStsGrpStsAssgmt on  $projection.SettlmtApplStsGrp  = _SettlmtApplStsGrpStsAssgmt.SettlmtApplStsGrp
                                                                                    and $projection.SettlmtDfltApplSts = _SettlmtApplStsGrpStsAssgmt.SettlmtApplSts
  association [0..*] to I_CndnContrProcVarTypeAssgmt as _CndnContrProcVarTypeAssgmt on  $projection.CndnContrProcVar = _CndnContrProcVarTypeAssgmt.CndnContrProcVar
  association [0..*] to I_CndnContrProcVarPurAssgmt  as _CndnContrProcVarPurAssgmt  on  $projection.CndnContrProcVar = _CndnContrProcVarPurAssgmt.CndnContrProcVar
  association [0..*] to I_CndnContrProcVarSlsAssgmt  as _CndnContrProcVarSlsAssgmt  on  $projection.CndnContrProcVar = _CndnContrProcVarSlsAssgmt.CndnContrProcVar
{
      @ObjectModel.text.association: '_Text'
  key process_variant  as CndnContrProcVar,

      @ObjectModel.foreignKey.association: '_SettlmtApplSts'
      default_estatus  as SettlmtDfltApplSts,
      @ObjectModel.foreignKey.association: '_SettlmtApplStsGrp'
      status_group     as SettlmtApplStsGrp,
      @ObjectModel.foreignKey.association: '_CndnContrApprvlProc'
      approval_process as CndnContrApprvlProc,

      /* Associations */
      _Text,
      _CndnContrApprvlProc,
      _SettlmtApplSts,
      _SettlmtApplStsGrp,
      _SettlmtApplStsGrpStsAssgmt,
      _CndnContrProcVarTypeAssgmt,
      _CndnContrProcVarPurAssgmt,
      _CndnContrProcVarSlsAssgmt
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"WCB_C_PROC_VAR"
],
"ASSOCIATED":
[
"I_CNDNCONTRAPPRVLPROC",
"I_CNDNCONTRPROCVARPURASSGMT",
"I_CNDNCONTRPROCVARSLSASSGMT",
"I_CNDNCONTRPROCVARTEXT",
"I_CNDNCONTRPROCVARTYPEASSGMT",
"I_SETTLMTAPPLSTS",
"I_SETTLMTAPPLSTSGRP",
"I_SETTLMTAPPLSTSGRPSTSASSGMT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/