R_ConditionDocumentItem

@EndUserText.label: 'Condition Document Item'
@AccessControl: {
    authorizationCheck:     #MANDATORY,
    personalData.blocking:  #('TRANSACTIONAL_DATA')
    }
@ObjectModel: {
    usageType.serviceQuality: #B,
    usageType.dataClass:      #TRANSACTIONAL,
    usageType.sizeCategory:   #XXL
    }
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #SAP_INTERNAL_API
    }
@Metadata: {
    ignorePropagatedAnnotations: true,
    allowExtensions: false
    }

define view entity R_ConditionDocumentItem
  as select from wcocoi

  association [1..1] to R_ConditionDocument          as _ConditionDocument          on $projection.ConditionDocument = _ConditionDocument.ConditionDocument
  association [0..1] to I_CndnDocItmActivationStatus as _CndnDocItmActivationStatus on $projection.CndnDocItmActivationStatus = _CndnDocItmActivationStatus.CndnDocItmActivationStatus

  /* Partners */
  association [0..1] to I_Customer                   as _Customer                   on $projection.Customer = _Customer.Customer
  association [0..1] to I_Supplier                   as _Supplier                   on $projection.Supplier = _Supplier.Supplier

  association [0..1] to I_Product                    as _Product                    on $projection.Product = _Product.Product

  /* Referenced Condition Documents */
  association [0..1] to R_ConditionDocument          as _CndnDocItmRefcdCndnDoc     on $projection.CndnDocItmRefcdCndnDoc = _CndnDocItmRefcdCndnDoc.ConditionDocument

  /* Intercompany Cost Distribution related fields */
  association [0..1] to I_CompanyCode                as _CompanyCode                on $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_WBSElementBasicData        as _WBSElementInternalID       on $projection.WBSElementInternalID = _WBSElementInternalID.WBSElementInternalID
  association [0..1] to I_InternalOrder              as _SettlmtMgmtOrder           on $projection.SettlmtMgmtOrder = _SettlmtMgmtOrder.InternalOrder

{

  key cast( num as wcb_condition_document preserving type )             as ConditionDocument,
  key item_guid                                                         as ConditionDocumentItemUUID,
      cast( posnr as wcb_condition_document_item preserving type )      as ConditionDocumentItem,
      cast( deact as wcb_cndn_doc_itm_act_sts preserving type )         as CndnDocItmActivationStatus, // GFN, DE, association


      /* Validity */
      @Semantics.businessDate.from: true
      date_from                                                         as CndnDocItemValidFromDate,
      @Semantics.businessDate.to: true
      date_to                                                           as CndnDocItemValidToDate,

      /* Partners */
      cast( eligible_cust as kunnr preserving type )                    as Customer,
      cast( eligible_vendor as lifnr preserving type )                  as Supplier,

      cast( material as productnumber preserving type )                 as Product,

      /* Referenced Condition Documents */
      cast( list_num as wcb_cndndoc_itm_refcd_cndndoc preserving type ) as CndnDocItmRefcdCndnDoc,

      /* Intercompany Cost Distribution related fields */
      cast( bukrs as fis_bukrs preserving type )                        as CompanyCode,
      cast( kostl as fis_kostl preserving type )                        as CostCenter,
      cast( ps_psp_pnr as wlf_psp_pnr_no_cnext preserving type )        as WBSElementInternalID,
      aufnr                                                             as SettlmtMgmtOrder,
      distribution_ratio                                                as SettlementDistributionRatio,

      /* UUIDs */
      cast( guid as wcb_cndn_doc_uuid preserving type )                 as ConditionDocumentUUID,
      cast( ext_guid as wcb_cndn_doc_itm_source_uuid preserving type )  as CndnDocItemSourceUUID,

      /* SAP Object Node Type abbreviation and object semantics */
      sont_abbrv_i                                                      as CndnDocObjNodeTypeAbbr,
      semantic_type_i                                                   as CndnDocSemanticCode,

      /* Associations */
      _ConditionDocument,
      _CndnDocItmActivationStatus,
      _Customer,
      _Supplier,
      _Product,
      _CndnDocItmRefcdCndnDoc,
      _CompanyCode,
      _WBSElementInternalID,
      _SettlmtMgmtOrder
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"WCOCOI"
],
"ASSOCIATED":
[
"I_CNDNDOCITMACTIVATIONSTATUS",
"I_COMPANYCODE",
"I_CUSTOMER",
"I_INTERNALORDER",
"I_PRODUCT",
"I_SUPPLIER",
"I_WBSELEMENTBASICDATA",
"R_CONDITIONDOCUMENT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/