P_MatrixCnsldtnFoundation

@AbapCatalog.sqlViewName: 'PMCFNDN'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #COMPOSITE
@VDM.private:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.buffering.status: #NOT_ALLOWED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED

define view P_MatrixCnsldtnFoundation
  with parameters
    P_ConsolidationUnitHierarchy : fincs_hryid,
    P_ConsolidationPrftCtrHier   : fincs_hryid,
    P_ConsolidationSegmentHier   : fincs_hryid,
    P_KeyDate                    : sydate


  as select from P_MJEL_CnsldtnFoundation
                 ( P_ConsolidationUnitHierarchy: $parameters.P_ConsolidationUnitHierarchy,
                   P_ConsolidationPrftCtrHier: $parameters.P_ConsolidationPrftCtrHier,
                   P_ConsolidationSegmentHier: $parameters.P_ConsolidationSegmentHier,
                   P_KeyDate: $parameters.P_KeyDate ) as CnsldtnFoundation
    inner join   I_CnsldtnVersion as CnsldtnVersion on CnsldtnVersion.ConsolidationVersion = CnsldtnFoundation.rvers and
                                                       CnsldtnVersion.ConsolidationLedger  = CnsldtnFoundation.rldnr

  ///////////////////////////////////////////////////////////////////////////////

  //                                       associations

  ///////////////////////////////////////////////////////////////////////////////

  association [1..1] to I_CnsldtnLedger              as _Ledger                     on  $projection.ConsolidationLedger = _Ledger.ConsolidationLedger

  association [1..1] to I_CnsldtnDimension           as _Dimension                  on  $projection.ConsolidationDimension = _Dimension.ConsolidationDimension

  association [1..1] to I_CnsldtnVersion             as _Version                    on  $projection.ConsolidationVersion = _Version.ConsolidationVersion

  association [1..1] to I_CnsldtnVersion             as _VersionElement             on  $projection.ConsolidationVersionElement = _VersionElement.ConsolidationVersion

  association [1..1] to I_Globalcompany              as _Company                    on  $projection.Company = _Company.Company

  association [0..1] to I_DebitCreditCode            as _DebitCreditCode            on  $projection.DebitCreditCode = _DebitCreditCode.DebitCreditCode

  association [1..1] to I_CnsldtnUnit_2              as _CnsldtnUnit                on  $projection.ConsolidationDimension = _CnsldtnUnit.ConsolidationDimension
                                                                                    and $projection.ConsolidationUnit      = _CnsldtnUnit.ConsolidationUnit

  association [1..1] to I_CnsldtnUnitForElimination  as _CnsldtnUnitForElimination  on  $projection.ConsolidationDimension   = _CnsldtnUnitForElimination.ConsolidationDimension
                                                                                    and $projection.ConsolidationUnitForElim = _CnsldtnUnitForElimination.ConsolidationUnit

  association [1..1] to I_CnsldtnGroupWithEmptyValue as _CnsldtnGroup               on  $projection.ConsolidationDimension = _CnsldtnGroup.ConsolidationDimension
                                                                                    and $projection.ConsolidationGroup     = _CnsldtnGroup.ConsolidationGroup

  association [1..1] to I_CnsldtnChartOfAccounts     as _ChartOfAccounts            on  $projection.ConsolidationChartOfAccounts = _ChartOfAccounts.ConsolidationChartOfAccounts

  association [1..1] to I_GroupReportingFSItem       as _FinStmntItm                on  $projection.ConsolidationChartOfAccounts = _FinStmntItm.ConsolidationChartOfAccounts
                                                                                    and $projection.FinancialStatementItem       = _FinStmntItm.FinancialStatementItem

  association [0..1] to I_CnsldtnUnit_2              as _PartnerUnit                on  $projection.ConsolidationDimension   = _PartnerUnit.ConsolidationDimension
                                                                                    and $projection.PartnerConsolidationUnit = _PartnerUnit.ConsolidationUnit

  association [0..1] to I_CompanyCode                as _CompanyCode                on  $projection.CompanyCode = _CompanyCode.CompanyCode

  association [0..1] to I_CnsldtnGLAccount           as _GLAccountInChartOfAccounts on  $projection.ChartOfAccounts = _GLAccountInChartOfAccounts.ChartOfAccounts
                                                                                    and $projection.GLAccount       = _GLAccountInChartOfAccounts.GLAccount

  association [0..1] to I_GLAccountInCompanyCode     as _GLAccountInCompanyCode     on  $projection.CompanyCode = _GLAccountInCompanyCode.CompanyCode
                                                                                    and $projection.GLAccount   = _GLAccountInCompanyCode.GLAccount

  association [0..1] to I_CnsldtnGLChartOfAccounts   as _GLChartOfAccounts          on  $projection.ChartOfAccounts = _GLChartOfAccounts.ChartOfAccounts

  association [0..1] to I_CnsldtnSubItemCategory     as _SubItemCategory            on  $projection.SubItemCategory = _SubItemCategory.SubItemCategory

  association [0..1] to I_CnsldtnSubItem             as _SubItem                    on  $projection.SubItemCategory = _SubItem.SubItemCategory
                                                                                    and $projection.SubItem         = _SubItem.SubItem

  association [1..1] to I_CnsldtnDocumentType        as _DocumentType               on  $projection.ConsolidationDimension    = _DocumentType.ConsolidationDimension
                                                                                    and $projection.ConsolidationDocumentType = _DocumentType.ConsolidationDocumentType

  association [1..1] to I_CnsldtnPostingLevel        as _PostingLevel               on  $projection.PostingLevel = _PostingLevel.PostingLevel

  association [0..1] to I_CnsldtnUnit_2              as _InvesteeUnit               on  $projection.ConsolidationDimension    = _InvesteeUnit.ConsolidationDimension
                                                                                    and $projection.InvesteeConsolidationUnit = _InvesteeUnit.ConsolidationUnit

  association [1..1] to I_CnsldtnApportionment       as _Apportionment              on  $projection.ConsolidationApportionment = _Apportionment.ConsolidationApportionment

  association [1..1] to I_CnsldtnCrcyCnvrsnDiffType  as _CrcyCnvrsnDiffType         on  $projection.CurrencyConversionsDiffType = _CrcyCnvrsnDiffType.CurrencyConversionsDiffType

  association [0..1] to I_Currency                   as _TransactionCurrency        on  $projection.TransactionCurrency = _TransactionCurrency.Currency

  association [0..1] to I_Currency                   as _LocalCurrency              on  $projection.LocalCurrency = _LocalCurrency.Currency

  association [0..1] to I_Currency                   as _GroupCurrency              on  $projection.GroupCurrency = _GroupCurrency.Currency

  association [0..1] to I_UnitOfMeasure              as _BaseUnit                   on  $projection.BaseUnit = _BaseUnit.UnitOfMeasure

  association [0..1] to I_CnsldtnInternalOrder       as _InternalOrder              on  $projection.OrderID = _InternalOrder.InternalOrder

  association [0..1] to I_CnsldtnCustomer            as _Customer                   on  $projection.Customer = _Customer.Customer

  association [0..1] to I_CnsldtnSupplier            as _Supplier                   on  $projection.Supplier = _Supplier.Supplier

  association [0..1] to I_CnsldtnMaterial            as _Material                   on  $projection.Material = _Material.Material

  association [0..1] to I_CnsldtnMaterialGroup       as _MaterialGroup              on  $projection.MaterialGroup = _MaterialGroup.MaterialGroup

  association [0..1] to I_CnsldtnPlant               as _Plant                      on  $projection.Plant = _Plant.Plant

  association [0..1] to I_CnsldtnFinTransType        as _FinancialTransactionType   on  $projection.FinancialTransactionType = _FinancialTransactionType.FinancialTransactionType

  association [0..1] to I_CnsldtnWBSElement          as _WBSElement                 on  $projection.Project              = _WBSElement.Project
                                                                                    and $projection.WBSElementExternalID = _WBSElement.WBSElement

  association [0..1] to I_WBSElementBasicData        as _WBSElementInternalID       on  $projection.WBSElementInternalID = _WBSElementInternalID.WBSElementInternalID

  association [0..1] to I_CnsldtnProject             as _Project                    on  $projection.Project = _Project.Project

  association [0..1] to I_CnsldtnCostCenter          as _CostCenter                 on  $projection.ControllingArea = _CostCenter.ControllingArea
                                                                                    and $projection.CostCenter      = _CostCenter.CostCenter

  association [0..1] to I_CnsldtnProfitCenter        as _ProfitCenter               on  $projection.ControllingArea = _ProfitCenter.ControllingArea
                                                                                    and $projection.ProfitCenter    = _ProfitCenter.ProfitCenter

  association [0..1] to I_CnsldtnProfitCenterForElim as _ProfitCenterForElim        on  $projection.ControllingArea             = _ProfitCenterForElim.ControllingArea
                                                                                    and $projection.ConsolidationPrftCtrForElim = _ProfitCenterForElim.ProfitCenter

  association [0..1] to I_CnsldtnFunctionalArea      as _FunctionalArea             on  $projection.FunctionalArea = _FunctionalArea.FunctionalArea

  association [0..1] to I_CnsldtnBusinessArea        as _BusinessArea               on  $projection.BusinessArea = _BusinessArea.BusinessArea

  association [0..1] to I_CnsldtnControllingArea     as _ControllingArea            on  $projection.ControllingArea = _ControllingArea.ControllingArea

  association [0..1] to I_CnsldtnSegment             as _Segment                    on  $projection.Segment = _Segment.Segment

  association [0..1] to I_CnsldtnSegmentForElim      as _SegmentForElim             on  $projection.ConsolidationSegmentForElim = _SegmentForElim.Segment

  association [0..1] to I_CnsldtnCostCenter          as _PartnerCostCenter          on  $projection.ControllingArea   = _PartnerCostCenter.ControllingArea
                                                                                    and $projection.PartnerCostCenter = _PartnerCostCenter.CostCenter

  association [0..1] to I_CnsldtnProfitCenter        as _PartnerProfitCenter        on  $projection.ControllingArea     = _PartnerProfitCenter.ControllingArea
                                                                                    and $projection.PartnerProfitCenter = _PartnerProfitCenter.ProfitCenter

  association [0..1] to I_CnsldtnFunctionalArea      as _PartnerFunctionalArea      on  $projection.PartnerFunctionalArea = _PartnerFunctionalArea.FunctionalArea

  association [0..1] to I_CnsldtnBusinessArea        as _PartnerBusinessArea        on  $projection.PartnerBusinessArea = _PartnerBusinessArea.BusinessArea

  association [1..1] to I_Globalcompany              as _PartnerCompany             on  $projection.PartnerCompany = _PartnerCompany.Company

  association [0..1] to I_CnsldtnSegment             as _PartnerSegment             on  $projection.PartnerSegment = _PartnerSegment.Segment

  association [0..1] to I_CnsldtnBillingType         as _BillingDocumentType        on  $projection.BillingDocumentType = _BillingDocumentType.BillingDocumentType

  association [0..1] to I_CnsldtnSalesOrganization   as _SalesOrganization          on  $projection.SalesOrganization = _SalesOrganization.SalesOrganization

  association [0..1] to I_CnsldtnDistributionChannel as _DistributionChannel        on  $projection.DistributionChannel = _DistributionChannel.DistributionChannel

  association [0..1] to I_CnsldtnDivision            as _Division                   on  $projection.OrganizationDivision = _Division.Division

  association [0..1] to I_CnsldtnMaterial            as _SoldMaterial               on  $projection.SoldMaterial = _SoldMaterial.Material

  association [0..1] to I_CnsldtnProduct             as _SoldProduct                on  $projection.SoldProduct = _SoldProduct.Product

  association [0..1] to I_CnsldtnMaterialGroup       as _SoldProductGroup           on  $projection.SoldProductGroup = _SoldProductGroup.MaterialGroup

  association [0..1] to I_CnsldtnCustomerGroup       as _CustomerGroup              on  $projection.CustomerGroup = _CustomerGroup.CustomerGroup

  association [0..1] to I_CnsldtnCountry             as _Country                    on  $projection.CustomerSupplierCountry = _Country.Country

  association [0..1] to I_CnsldtnIndustry            as _Industry                   on  $projection.CustomerSupplierIndustry = _Industry.Industry

  association [0..1] to I_CnsldtnSalesDistrict       as _SalesDistrict              on  $projection.SalesDistrict = _SalesDistrict.SalesDistrict

  association [0..1] to I_CnsldtnCustomer            as _BillToParty                on  $projection.BillToParty = _BillToParty.Customer

  association [0..1] to I_CnsldtnCustomer            as _ShipToParty                on  $projection.ShipToParty = _ShipToParty.Customer

  association [0..1] to I_CnsldtnAdhocItem           as _AdhocItem                  on  $projection.ConsolidationChartOfAccounts = _AdhocItem.ConsolidationChartOfAccounts
                                                                                    and $projection.CnsldtnAdhocItem             = _AdhocItem.CnsldtnAdhocItem

  association [0..1] to I_CnsldtnAdhocSet            as _AdhocSet                   on  $projection.ConsolidationChartOfAccounts = _AdhocSet.ConsolidationChartOfAccounts
                                                                                    and $projection.CnsldtnAdhocSet              = _AdhocSet.CnsldtnAdhocSet

  association [0..1] to I_CnsldtnAdhocSetItem        as _AdhocSetItem               on  $projection.ConsolidationChartOfAccounts = _AdhocSetItem.ConsolidationChartOfAccounts
                                                                                    and $projection.CnsldtnAdhocSet              = _AdhocSetItem.CnsldtnAdhocSet
                                                                                    and $projection.CnsldtnAdhocSetItem          = _AdhocSetItem.CnsldtnAdhocSetItem
{
      @ObjectModel.foreignKey.association: '_Ledger'
  key rldnr                                                          as ConsolidationLedger,
      @ObjectModel.foreignKey.association: '_Dimension'
  key rdimen                                                         as ConsolidationDimension,

      @Semantics.fiscal.year: true
  key ryear                                                          as FiscalYear,
  key docnr                                                          as ConsolidationDocumentNumber,
  key docln                                                          as ConsolidationPostingItem,

      @ObjectModel.foreignKey.association: '_CnsldtnGroup'
  key rcongr                                                         as ConsolidationGroup,

      @Semantics.fiscal.period: true
  key poper                                                          as FiscalPeriod,

  key period_mode                                                    as PeriodMode,

      @Semantics.fiscal.yearPeriod: true
      year_period                                                    as FiscalYearPeriod,

      @Semantics.fiscal.yearVariant: true
      cast ('K4' as fis_periv)                                       as FiscalYearVariant,

      poper_posting                                                  as PostingFiscalPeriod,

      cast (rrcty as fincs_rrcty  preserving type )                  as GLRecordType,

      @ObjectModel.foreignKey.association: '_VersionElement'
      cast (rvers as fincs_vers_elem preserving type )               as ConsolidationVersionElement,

      @ObjectModel.foreignKey.association: '_Version'
      ref_version                                                    as ConsolidationVersion,

      @Semantics.currencyCode:true
      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      rtcur                                                          as TransactionCurrency,

      @Semantics.currencyCode:true
      @ObjectModel.foreignKey.association: '_LocalCurrency'
      rhcur                                                          as LocalCurrency,

      @Semantics.currencyCode:true
      @ObjectModel.foreignKey.association: '_GroupCurrency'
      rkcur                                                          as GroupCurrency,

      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_BaseUnit'
      runit                                                          as BaseUnit,

      //TODO Where is DOCTY and what's difference compare with docct

      docct                                                          as DocumentCategory,

      @ObjectModel.foreignKey.association: '_DocumentType'
      docty                                                          as ConsolidationDocumentType,

      @ObjectModel.foreignKey.association: '_DebitCreditCode'
      drcrk                                                          as DebitCreditCode,

      @ObjectModel.foreignKey.association: '_Company'
      rcomp                                                          as Company,

      @ObjectModel.foreignKey.association: '_CnsldtnUnit'
      rbunit                                                         as ConsolidationUnit,

      @ObjectModel.foreignKey.association: '_CnsldtnUnitForElimination'
      rbunit_eliminated                                              as ConsolidationUnitForElim,

      @ObjectModel.foreignKey.association: '_ChartOfAccounts'
      ritclg                                                         as ConsolidationChartOfAccounts,

      @ObjectModel.foreignKey.association: '_FinStmntItm'
      ritem                                                          as FinancialStatementItem,

      @ObjectModel.foreignKey.association: '_PartnerUnit'
      rbuptr                                                         as PartnerConsolidationUnit,

      @ObjectModel.foreignKey.association: '_CompanyCode'
      robukrs                                                        as CompanyCode,

      @ObjectModel.foreignKey.association: '_SubItemCategory'
      sityp                                                          as SubItemCategory,

      @ObjectModel.foreignKey.association: '_SubItem'
      subit                                                          as SubItem,

      @ObjectModel.foreignKey.association: '_PostingLevel'
      plevl                                                          as PostingLevel,

      @ObjectModel.foreignKey.association: '_Apportionment'
      rpflg                                                          as ConsolidationApportionment,

      @ObjectModel.foreignKey.association: '_CrcyCnvrsnDiffType'
      rtflg                                                          as CurrencyConversionsDiffType,


      @Semantics.fiscal.year: true
      yracq                                                          as ConsolidationAcquisitionYear,

      @Semantics.fiscal.period: true
      pracq                                                          as ConsolidationAcquisitionPeriod,

      @ObjectModel.foreignKey.association: '_InvesteeUnit'
      coicu                                                          as InvesteeConsolidationUnit,

      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      tsl                                                            as AmountInTransactionCurrency,

      @Semantics: { amount : {currencyCode: 'LocalCurrency'} }
      hsl                                                            as AmountInLocalCurrency,

      @Semantics: { amount : {currencyCode: 'GroupCurrency'} }
      ksl                                                            as AmountInGroupCurrency,

      @Semantics: { quantity : {unitOfMeasure : 'BaseUnit'} }
      msl                                                            as QuantityInBaseUnit,

      sgtxt                                                          as DocumentItemText,

      autom                                                          as ConsolidationPostgItemAutoFlag,

      activ                                                          as BusinessTransactionType,
      //TODO bvorg,


      budat                                                          as PostingDate,
      wsdat                                                          as CurrencyTranslationDate,
      refdocnr                                                       as RefConsolidationDocumentNumber,

      @Semantics.fiscal.year: true
      refryear                                                       as ReferenceFiscalYear,

      refdocln                                                       as RefConsolidationPostingItem,
      refdocct                                                       as RefConsolidationDocumentType,
      refactiv                                                       as RefBusinessTransactionType,
      timestamp                                                      as CreationDateTime,
      cpudt                                                          as CreationDate,
      cputm                                                          as CreationTime,
      usnam                                                          as UserID,
      rvsdocnr                                                       as ReverseDocument,
      orndocnr                                                       as ReversedDocument,
      coiac                                                          as InvestmentActivityType,
      coinr                                                          as InvestmentActivity,
      revyear                                                        as ConsolidationDocReversalYear,
      awtyp                                                          as ReferenceDocumentType,
      aworg                                                          as ReferenceDocumentContext,
      logsys                                                         as LogicalSystem,

      /*** Begin Of Additional Fields in Consolidation Journal Entries in S/4 ***/
      @ObjectModel.foreignKey.association: '_GLChartOfAccounts'
      ktopl                                                          as ChartOfAccounts,

      @ObjectModel.foreignKey.association: '_GLAccountInChartOfAccounts'
      racct                                                          as GLAccount,

      zuonr                                                          as AssignmentReference,

      @ObjectModel.foreignKey.association: '_CostCenter'
      rcntr                                                          as CostCenter,

      @ObjectModel.foreignKey.association: '_ProfitCenter'
      prctr                                                          as ProfitCenter,

      @ObjectModel.foreignKey.association: '_ProfitCenterForElim'
      prctr_eliminated                                               as ConsolidationPrftCtrForElim,

      @ObjectModel.foreignKey.association: '_FunctionalArea'
      rfarea                                                         as FunctionalArea,

      @ObjectModel.foreignKey.association: '_BusinessArea'
      rbusa                                                          as BusinessArea,

      @ObjectModel.foreignKey.association: '_ControllingArea'
      kokrs                                                          as ControllingArea,

      @ObjectModel.foreignKey.association: '_Segment'
      segment                                                        as Segment,

      @ObjectModel.foreignKey.association: '_SegmentForElim'
      segment_eliminated                                             as ConsolidationSegmentForElim,

      @ObjectModel.foreignKey.association: '_PartnerCostCenter'
      scntr                                                          as PartnerCostCenter,

      @ObjectModel.foreignKey.association: '_PartnerProfitCenter'
      pprctr                                                         as PartnerProfitCenter,

      @ObjectModel.foreignKey.association: '_PartnerFunctionalArea'
      sfarea                                                         as PartnerFunctionalArea,

      @ObjectModel.foreignKey.association: '_PartnerBusinessArea'
      sbusa                                                          as PartnerBusinessArea,

      @ObjectModel.foreignKey.association: '_PartnerCompany'
      rassc                                                          as PartnerCompany,

      @ObjectModel.foreignKey.association: '_PartnerSegment'
      psegment                                                       as PartnerSegment,

      @ObjectModel.foreignKey.association: '_InternalOrder'
      aufnr                                                          as OrderID,

      @ObjectModel.foreignKey.association: '_Customer'
      kunnr                                                          as Customer,

      @ObjectModel.foreignKey.association: '_Supplier'
      lifnr                                                          as Supplier,

      @ObjectModel.foreignKey.association: '_Material'
      matnr                                                          as Material, //do not use any longer, use Product


      @ObjectModel.foreignKey.association: '_MaterialGroup'
      matkl_mm                                                       as MaterialGroup,

      @ObjectModel.foreignKey.association: '_Plant'
      werks                                                          as Plant,

      @ObjectModel.foreignKey.association: '_FinancialTransactionType'
      rmvct                                                          as FinancialTransactionType,

      @ObjectModel.foreignKey.association: '_WBSElementInternalID'
      cast ( ps_psp_pnr as ps_s4_pspnr preserving type )             as WBSElementInternalID,

      @ObjectModel.foreignKey.association: '_WBSElement'
      ps_posid                                                       as WBSElementExternalID,

      @ObjectModel.foreignKey.association: '_Project'
      ps_pspid                                                       as Project,

      @ObjectModel.foreignKey.association: '_BillingDocumentType'
      fkart                                                          as BillingDocumentType,
      @ObjectModel.foreignKey.association: '_SalesOrganization'
      vkorg                                                          as SalesOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      vtweg                                                          as DistributionChannel,
      @ObjectModel.foreignKey.association: '_Division'
      spart                                                          as OrganizationDivision,
      @ObjectModel.foreignKey.association: '_SoldMaterial'
      matnr_copa                                                     as SoldMaterial,
      @ObjectModel.foreignKey.association: '_SoldProduct'
      matnr_copa                                                     as SoldProduct,
      @ObjectModel.foreignKey.association: '_SoldProductGroup'
      matkl                                                          as SoldProductGroup,
      @ObjectModel.foreignKey.association: '_CustomerGroup'
      kdgrp                                                          as CustomerGroup,
      @ObjectModel.foreignKey.association: '_Country'
      land1                                                          as CustomerSupplierCountry,
      @ObjectModel.foreignKey.association: '_Industry'
      brsch                                                          as CustomerSupplierIndustry,
      @ObjectModel.foreignKey.association: '_SalesDistrict'
      bzirk                                                          as SalesDistrict,
      @ObjectModel.foreignKey.association: '_BillToParty'
      kunre                                                          as BillToParty,
      @ObjectModel.foreignKey.association: '_ShipToParty'
      kunwe                                                          as ShipToParty,
      konzs                                                          as CustomerSupplierCorporateGroup,
      CnsldtnJrnlEntryItemOrigin                                     as CnsldtnJrnlEntryItemOrigin,
      FinancialPlanningReqTransSqnc                                  as FinancialPlanningReqTransSqnc,
      FinancialPlanningDataPacket                                    as FinancialPlanningDataPacket,
      FinancialPlanningEntryItem                                     as FinancialPlanningEntryItem,
      rldnr_fin                                                      as Ledger,

      //Additional Fileds: Adhoc Item

      @ObjectModel.foreignKey.association: '_AdhocItem'
      @Analytics.internalName: #LOCAL
      adhocitem                                                      as CnsldtnAdhocItem,
      @ObjectModel.foreignKey.association: '_AdhocSet'
      @Analytics.internalName: #LOCAL
      adhocset                                                       as CnsldtnAdhocSet,
      @ObjectModel.foreignKey.association: '_AdhocSetItem'
      @Analytics.internalName: #LOCAL
      adhocsetitem                                                   as CnsldtnAdhocSetItem,

      //Additional Fields - ICMR

      rcode                                                          as MatchingReasonCode,
      orig_type                                                      as OriginType,
      orig_ref                                                       as OriginReference,

      // Associations

      _Ledger,

      _Dimension,

      _Version,

      _Company,

      _CnsldtnUnit,

      _CnsldtnUnitForElimination,

      _CnsldtnGroup,

      _ChartOfAccounts,

      _FinStmntItm,

      _GLAccountInChartOfAccounts,

      _GLAccountInCompanyCode,

      _GLChartOfAccounts,

      _PartnerUnit,

      _CompanyCode,

      _SubItemCategory,

      _SubItem,

      _DebitCreditCode,

      _DocumentType,

      _PostingLevel,

      _InvesteeUnit,

      _Apportionment,

      _CrcyCnvrsnDiffType,

      _TransactionCurrency,

      _LocalCurrency,

      _GroupCurrency,

      _BaseUnit,

      _InternalOrder,

      _Customer,

      _Supplier,

      _Material,

      _MaterialGroup,

      _Plant,

      _FinancialTransactionType,

      _WBSElement,

      _WBSElementInternalID,

      _Project,

      _CostCenter,

      _ProfitCenter,

      _ProfitCenterForElim,

      _FunctionalArea,

      _BusinessArea,

      _ControllingArea,

      _Segment,

      _SegmentForElim,

      _PartnerCostCenter,

      _PartnerProfitCenter,

      _PartnerFunctionalArea,

      _PartnerBusinessArea,

      _PartnerCompany,

      _PartnerSegment,

      _BillingDocumentType,

      _SalesOrganization,

      _DistributionChannel,

      _Division,

      _SoldMaterial,

      _SoldProduct,

      _SoldProductGroup,

      _CustomerGroup,

      _Country,

      _Industry,

      _SalesDistrict,

      _BillToParty,

      _ShipToParty,

      _AdhocItem,

      _AdhocSet,

      _AdhocSetItem,

      _VersionElement

}