I_GroupReportingFSItem

@AbapCatalog:{
  sqlViewName: 'ICCFSITEM',
  preserveKey: true,
  buffering:{
    status: #ACTIVE,
    type: #FULL }
  }
@AccessControl:{
  authorizationCheck: #CHECK,
  privilegedAssociations: ['_FinStmntItmHierNode','_ConsChartOfAccountsText']
  }
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata:{
  allowExtensions:true,
  ignorePropagatedAnnotations: true
  }
@ObjectModel:{
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #B,
    sizeCategory: #L},
  representativeKey: 'FinancialStatementItem',
  modelingPattern: #ANALYTICAL_DIMENSION,
  supportedCapabilities: [#CDS_MODELING_DATA_SOURCE,
                          #CDS_MODELING_ASSOCIATION_TARGET,
                          #SQL_DATA_SOURCE,
                          #ANALYTICAL_DIMENSION]
}
@Analytics: {
  dataCategory: #DIMENSION
}
@VDM.viewType: #BASIC
@EndUserText.label: 'Financial Statement Item'

/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ]  } */
define view I_GroupReportingFSItem
  as select from fincs_fsitem

  association [0..*] to I_CnsldtnChartOfAccountsT      as _ConsChartOfAccountsText on  $projection.ConsolidationChartOfAccounts = _ConsChartOfAccountsText.ConsolidationChartOfAccounts

  association [0..*] to I_CnsldtnFinStmntItemText      as _Text                    on  $projection.ConsolidationChartOfAccounts = _Text.ConsolidationChartOfAccounts
                                                                                   and $projection.FinancialStatementItem       = _Text.FinancialStatementItem

  association [0..*] to I_CnsldtnFinStmntItemLongText  as _LongText                on  $projection.ConsolidationChartOfAccounts = _LongText.ConsolidationChartOfAccounts
                                                                                   and $projection.FinancialStatementItem       = _LongText.FinancialStatementItem

  association [0..*] to I_GroupReportingFSItemHierNode as _FinStmntItmHierNode     on  $projection.ConsolidationChartOfAccounts = _FinStmntItmHierNode.ConsolidationChartOfAccounts
                                                                                   and $projection.FinancialStatementItem       = _FinStmntItmHierNode.FinancialStatementItem

  association [0..1] to I_CnsldtnFinStmntItemType      as _FinStmntItmType         on  $projection.FinancialStatementItemType = _FinStmntItmType.ConsolidationFSItemType

  association [0..1] to I_BreakdownCategory            as _BreakdownCat            on  $projection.ConsolidationChartOfAccounts = _BreakdownCat.ConsolidationChartOfAccounts
                                                                                   and $projection.BreakdownCategory            = _BreakdownCat.BreakdownCategory

  association [1..1] to I_CnsldtnChartOfAccounts       as _ConsChartOfAccounts     on  $projection.ConsolidationChartOfAccounts = _ConsChartOfAccounts.ConsolidationChartOfAccounts

{

      @ObjectModel.text.association: '_ConsChartOfAccountsText' //STS - annotation not required as it is not the representative key

      @ObjectModel.foreignKey.association: '_ConsChartOfAccounts'
  key itclg                                  as ConsolidationChartOfAccounts,


      @ObjectModel.text.association: '_Text'
      @ObjectModel.hierarchy.association: '_FinStmntItmHierNode'
  key cast(item as fc_item preserving type ) as FinancialStatementItem,

      @ObjectModel.foreignKey.association: '_FinStmntItmType'
      itclass                                as FinancialStatementItemType,

      @ObjectModel.foreignKey.association: '_BreakdownCat'
      itbrkdwn                               as BreakdownCategory,

      itcitem                                as IsConsolidationItem,

      itblkd                                 as FinancialStatementItemIsBlkd,


      _ConsChartOfAccounts,
      _FinStmntItmType,
      _BreakdownCat,
      _FinStmntItmHierNode,

      @ObjectModel.association.boundFields.dataMatchesSourceAndTargetTypes:true
      _Text,
      _LongText,

      @Consumption.hidden: true
      _ConsChartOfAccountsText

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FINCS_FSITEM"
],
"ASSOCIATED":
[
"I_BREAKDOWNCATEGORY",
"I_CNSLDTNCHARTOFACCOUNTS",
"I_CNSLDTNCHARTOFACCOUNTST",
"I_CNSLDTNFINSTMNTITEMLONGTEXT",
"I_CNSLDTNFINSTMNTITEMTEXT",
"I_CNSLDTNFINSTMNTITEMTYPE",
"I_GROUPREPORTINGFSITEMHIERNODE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/