I_CnsldtnDistributionChannel

@AbapCatalog:{
  sqlViewName: 'ICSDISTRICHL'
  }
@Analytics: {
  dataCategory: #DIMENSION,
  internalName: #LOCAL,
  dataExtraction.enabled: true
}
@AccessControl:{
  authorizationCheck: #MANDATORY
  }
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata:{
  allowExtensions:true,
  ignorePropagatedAnnotations: true
  }
@ObjectModel:{
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #C,
    sizeCategory: #S},
  representativeKey: 'DistributionChannel',
  modelingPattern: #ANALYTICAL_DIMENSION,
  supportedCapabilities: [#CDS_MODELING_DATA_SOURCE,
                          #CDS_MODELING_ASSOCIATION_TARGET,
                          #SQL_DATA_SOURCE,
                          #EXTRACTION_DATA_SOURCE,
                          #ANALYTICAL_DIMENSION],
  sapObjectNodeType.name: 'CnsldtnDistributionChannel'
}
@VDM:{
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
  }
@EndUserText.label: 'Cnsldtn Combined Distribution Channel'

// expose only additional master data entity in case of homonymous non-additional master data entity existence


define view I_CnsldtnDistributionChannel
  as select distinct from P_CnsldtnDistributionChannel

  association [0..*] to I_CnsldtnDistributionChannelT as _Text     on $projection.DistributionChannel = _Text.DistributionChannel

  association [1..1] to I_CnsldtnMDSource             as _MDSource on $projection.AdditionalMasterDataSource = _MDSource.AdditionalMasterDataSource

{

      @ObjectModel.text.association: '_Text'
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'I_CnsldtnDistributionChannelVH',
          element: 'DistributionChannel'
        }
      }]
  key cast( DistributionChannel as fincs_distributionchannel preserving type )                      as DistributionChannel,

      @ObjectModel.foreignKey.association: '_MDSource'
      @API.element: {releaseState: #DEPRECATED, successor: 'CnsldtnIsAdditionalMasterData'}
      @VDM.lifecycle: {status: #DEPRECATED, successor: 'CnsldtnIsAdditionalMasterData' }
      cast( max ( AdditionalMasterDataSource ) as fincs_masterdatasource preserving type )          as AdditionalMasterDataSource,

      cast( max ( CnsldtnIsAdditionalMasterData ) as fincs_isadditionalmasterdata preserving type ) as CnsldtnIsAdditionalMasterData,


      /* associations */
      _MDSource,
      _Text
}
where
  DistributionChannel is not initial //required to avoid access to corrupt database entries

group by
  DistributionChannel;
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_CNSLDTNDISTRIBUTIONCHANNEL"
],
"ASSOCIATED":
[
"I_CNSLDTNDISTRIBUTIONCHANNELT",
"I_CNSLDTNMDSOURCE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/