I_ReservationDocumentHeader

@AbapCatalog: {
                sqlViewName: 'IRESVNDOCHDR',
                preserveKey: true,
                compiler.compareFilter: true
              }
@AccessControl: {
                  authorizationCheck: #CHECK,
                  personalData.blocking: #BLOCKED_DATA_EXCLUDED
                }
@EndUserText.label: 'Reservation Document Header'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
                usageType: {
                             sizeCategory: #M,
                             serviceQuality: #A,
                             dataClass:#TRANSACTIONAL
                            },
                compositionRoot: true,
                semanticKey: ['Reservation'],
                representativeKey: 'Reservation',
                modelingPattern: #ANALYTICAL_DIMENSION,
                supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE]
}
@VDM: {
        viewType: #BASIC,
        lifecycle.contract.type: #PUBLIC_LOCAL_API
      } 
@Analytics.dataCategory: #DIMENSION
@Metadata: {
             ignorePropagatedAnnotations:true,
             allowExtensions: true
           }
           
define view I_ReservationDocumentHeader
  as select from I_ReservationHeader
  association [0..1] to I_CostCenter              as _CostCenter              on  $projection.CostCenter      =  _CostCenter.CostCenter
                                                                              and $projection.ControllingArea =  _CostCenter.ControllingArea
                                                                              and $projection.ReservationDate <= _CostCenter.ValidityEndDate
                                                                              and $projection.ReservationDate >= _CostCenter.ValidityStartDate

  association [1..*] to I_ReservationDocumentItem as _ReservationDocumentItem on  $projection.Reservation = _ReservationDocumentItem.Reservation
  association [0..1] to I_WBSElementByInternalKey as _WBSElementByInternalKey on  $projection.WBSElementInternalID = _WBSElementByInternalKey.WBSElementInternalID
  association [0..1] to I_WBSElementBasicData     as _WBSElementBasicData     on  $projection.WBSElementInternalID = _WBSElementBasicData.WBSElementInternalID
  association [0..1] to I_ReservationCreationCode as _ReservationCreationCode on $projection.ReservationCreationCode = _ReservationCreationCode.ReservationCreationCode
{

  key Reservation,
  
      ReservationCreationCode,
      
      ReservationOrigin,
      
      @ObjectModel.foreignKey.association: '_Order'
      OrderID,

      @ObjectModel.foreignKey.association: '_GoodsMovementType'
      GoodsMovementType,

      @ObjectModel.foreignKey.association: '_CostCenter'
      CostCenter,
      
      ProfitCenter,
      @API.element.releaseState: #DECOMMISSIONED
      @API.element.successor: 'ProfitabilitySegment_2'
//      @VDM.lifecycle.status: #DEPRECATED

//      @VDM.lifecycle.successor: 'ProfitabilitySegment_2'

      ProfitabilitySegment,
      ProfitabilitySegment_2, 
      @ObjectModel.foreignKey.association: '_ControllingArea'
      ControllingArea,

      GoodsRecipientName,

      @Semantics.businessDate.at: true
      ReservationDate,
      IsCheckedAgainstFactoryCal,

      @ObjectModel.foreignKey.association: '_Customer'
      Customer,
      WBSElementInternalID,
//      _WBSElementByInternalKey.WBSElement,

      SalesOrder,
      SalesOrderItem,
      SalesOrderScheduleLine,
      AssetNumber,
      AssetSubNumber,
      NetworkNumberForAcctAssgmt,
      IssuingOrReceivingPlant,
      IssuingOrReceivingStorageLoc,
      ResvnVerificationCompanyCode,
      UserID,
      CreationDateTime,
      LastChangedByUser,
      LastChangeDateTime,

      _CostCenter,
      _ProfitCenter,      
      _ControllingArea,
      _VerificationCompanyCode,
      _Order,
      _GoodsMovementType,
      _Customer,
     _WBSElementByInternalKey,
     _WBSElementBasicData,
     _ReservationCreationCode,
       
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _ReservationDocumentItem
      
            
}

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_RESERVATIONHEADER"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTER",
"I_CUSTOMER",
"I_GOODSMOVEMENTTYPE",
"I_LOGISTICSORDER",
"I_PROFITCENTER",
"I_RESERVATIONCREATIONCODE",
"I_RESERVATIONDOCUMENTITEM",
"I_WBSELEMENTBASICDATA",
"I_WBSELEMENTBYINTERNALKEY"
],
"BASE":
[
"I_RESERVATIONHEADER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/